'Shutdownlib


?win32
   Import "-lkernel32"
   Import "-ladvapi32"
?

'-- INITIALISIERUNG --
Extern "Win32"
   Function OpenProcessToken (ProcessHandle:Int, DesiredAccess:Int, TokenHandle:Byte Ptr)
   Function LookupPrivilegeValue (lpSystemName$z, lpName$z, lpLuid:Byte Ptr) = "LookupPrivilegeValueA@12"
   Function AdjustTokenPrivileges (TokenHandle:Int, DisableAllPrivileges:Int, NewState:Byte Ptr,BufferLength:Int, PreviousState:Byte Ptr, ReturnLength:Byte Ptr)
   Function GetVersion ()
   Function GetCurrentProcess ()
   Function SetSystemPowerState (fSuspend:Int, fForce:Int)
   Function ExitWindowsEx (uFlags:Int,dwReserved:Int=0)
   Function GetLastError ()
End Extern


Private
   Function EnableShutdownPrivileges:Int ()
         ?win32
            Const TOKEN_ADJUST_PRIVILEGES:Int = $20
            Const TOKEN_QUERY:Int = $8
            Const SE_PRIVILEGE_ENABLED:Int = $2
            Local tokenPrivilege:Int[4]
            If LookupPrivilegeValue(Null, "SeShutdownPrivilege", Byte Ptr(tokenPrivilege)+4)
               Local hProc:Int = GetCurrentProcess() ' -1
               Local hToken:Int
               If OpenProcessToken(hProc, TOKEN_ADJUST_PRIVILEGES | TOKEN_QUERY, Varptr(hToken))
                  tokenPrivilege[0] = 1
                  tokenPrivilege[3] = SE_PRIVILEGE_ENABLED
                  If AdjustTokenPrivileges(hToken, False, Byte Ptr(tokenPrivilege), Null, Null, Null)
                     Return True
                  EndIf
               EndIf
            EndIf
         ?
      End Function
Public


'Rechner in Hibernation versetzen
Function ForceHibernation ()
      ?debug
         WriteStdout("Hibernate") ; End
      ?win32
         If EnableShutdownPrivileges()
            SetSystemPowerState(True, False)
         EndIf
      ?
   End Function


'Rechner in StandBy versetzen
Function ForceStandby ()
      ?debug
         WriteStdout("Standby") ; End
      ?win32
         If EnableShutdownPrivileges()
            SetSystemPowerState(False, False)
         EndIf
      ?
   End Function


'Benutzer ausloggen
Function ForceLogOff ()
      ?debug
         WriteStdout("LogOff") ; End
      ?win32
         If EnableShutdownPrivileges()
            ExitWindowsEx $0 | $4 * False
         EndIf
      ?
   End Function


'Rechner herunterfahren
Function ForceShutdown ()
      ?debug
         WriteStdout("Shutdown") ; End
      ?win32
         If EnableShutdownPrivileges()
            ExitWindowsEx $8 | $4 * False
         EndIf
      ?
   End Function


'Rechner neu starten
Function ForceRestart ()
      ?debug
         WriteStdout("Restart") ; End
      ?win32
         If EnableShutdownPrivileges()
            ExitWindowsEx $2 | $4 * False
         EndIf
      ?
   End Function