SuperStrict

Framework BRL.Blitz
Import BRL.Stream

Local t : TTestStream

t = New TTestStream
t.WriteLine("ABCDEFGHIJKLMNOPQRSTUVW")
t.WriteLine("XYZ01234567890abcdefghi")
t.WriteLong(55566677)
t.WriteLong(55566677)
t.WriteLong(55566677)
t.WriteLine("Hello, world!")

DebugLog t.ReadLine()
DebugLog t.ReadLine()
DebugLog t.ReadLong()
DebugLog t.ReadLong()
DebugLog t.ReadLong()
DebugLog t.ReadLine()


Type TTestStream Extends TStream
   Field buffer     : Byte Ptr
   Field capacity   : Int
   Field bufferSize : Int
   Field position   : Int

   Method New()
      capacity   = 16
      buffer     = MemAlloc(capacity)
      bufferSize = 0
      position   = 0
   End Method
   
   Method Delete()
      MemFree(buffer)
      buffer     = Null
      capacity   = 0
      bufferSize = 0
      position   = 0
   End Method
   
   Method Read:Int(buf:Byte Ptr, size:Int)
      Local newCapacity : Int
      
      If size > bufferSize Then size = bufferSize
      
      newCapacity = capacity
      While newCapacity > bufferSize - size And ..
            newCapacity > 16
         newCapacity :Shr 1
      Wend
      If newCapacity < bufferSize - size Then newCapacity :Shl 1
      
      MemCopy(buf, buffer + position, size)
      bufferSize :- size
      position :+ size
      
      If newCapacity <> capacity Then
         Local temp : Byte Ptr
         
         temp = MemAlloc(newCapacity)
         MemCopy(temp, buffer + position, bufferSize)
         MemFree(buffer)
         
         buffer = temp
         capacity = newCapacity
         position = 0
      EndIf
      
      Return size
   End Method

   Method Write:Int(buf:Byte Ptr, size:Int)
      Local newCapacity : Int
   
      newCapacity = capacity
      While newCapacity < bufferSize + size
         newCapacity :Shl 1
      Wend
      If newCapacity <> capacity Then
         buffer = MemExtend(buffer, capacity, newCapacity)
         capacity = newCapacity
      EndIf
      
      MemCopy(buffer + bufferSize, buf, size)
      bufferSize :+ size
      
      Return size
   End Method

   Method Eof:Int()
      Return bufferSize = 0
   End Method
   
   Method Size:Int()
      Return bufferSize
   End Method

   Method Flush()
      MemFree(buffer)
      capacity   = 16
      buffer     = MemAlloc(capacity)
      bufferSize = 0
      position   = 0
   End Method

   Method Close()
      Flush()
   End Method
End Type

msg:String = Client.ReadLine()