Graphics3D 1024,768,32,1
SetBuffer BackBuffer()
HidePointer()
SeedRnd MilliSecs()

Const k_cam    = 1
Const k_grund    = 2
Const k_obj      = 3

Collisions k_cam, k_grund, 2, 3
Collisions k_cam, k_obj, 2, 3
Collisions k_obj, k_grund, 2, 3

;Camera
cam          = CreatePivot()
Global camera    = CreateCamera(cam)
PositionEntity cam,0,5,0
PositionEntity camera,0,5,0
CameraClsColor camera,10,10,10
EntityType cam,k_cam
EntityRadius cam,2,2
;Beide Funktionen werden für´s Nachtsichtgerät benötigt!
CreateBloomCam(camera,256);512)
CreateBlurCam(camera,1.6,1.985,1.995,.7,1)

;es werde Licht
AmbientLight 50,50,50
lit = CreateLight(2)
MoveEntity lit,13,55,10
PointEntity lit,camera
LightColor lit,255,255,255

;Grund
cub = CreatePlane()
EntityType cub,k_grund
EntityFX cub,1
EntityColor cub,10,10,10

;Umweltobjekte
Dim cube(30)

facia = LoadTexture("facia_0.jpg")

For l = 0 To 30
cube(l) = CreateCube()
ScaleEntity cube(l),Rand(3,9),Rand(5,9),Rand(3,9)
EntityType cube(l),k_obj
PositionEntity cube(l),Rnd(-150,150),9,Rnd(-150,150)
EntityRadius cube(l),5,5
EntityColor cube(l),50,50,50
;EntityFX cube(l),1+2
EntityTexture cube(l),facia
Next




hod = 0
;--- Hauptschleife ---
While Not(KeyHit(1))

;Taste 1: Wireframe
If KeyHit(2) Then wire = 1 - wire
WireFrame wire

;Taste Strg: Ducken
If KeyDown(29) Then
PositionEntity camera,0,1,0
Else
PositionEntity camera,0,5,0
End If

;Taste Tab: Nachtsicht an/aus
If KeyHit(15) Then nVo = 1-nVo

;Taste: 2: Zwischen hell und dunkel schalten
If KeyHit(3) Then hod = 1-hod

;Bewegung usw. (alles nicht so wichtig, gehört aber zur Testebene)
TranslateEntity cam,0,-1,0

x_rot# = MouseYSpeed()/3
y_rot# = -1*(MouseXSpeed()/3)
MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
TurnEntity cam,0,y_rot#,0
TurnEntity camera,x_rot#,0,0

If KeyDown(17) Then MoveEntity cam,0,0,.5
If KeyDown(30) Then MoveEntity cam,-.5,0,0
If KeyDown(31) Then MoveEntity cam,0,0,-.5
If KeyDown(32) Then MoveEntity cam,.5,0,0

If hod = 1 Then
CameraClsColor camera,150,150,150
EntityColor cub,200,200,200
Else
CameraClsColor camera,10,10,10
EntityColor cub,10,10,10
End If

For l = 0 To 30
TranslateEntity cube(l),0,-.1,0
If hod = 1 Then
EntityColor cube(l),255,255,255
Else
EntityColor cube(l),10,10,10
End If
Next


;Das hier ist der entscheidene Punkt!
;-----------------------
UpdateBlur(1024,768,0)
UpdateBloom(nVo)
Update_NightVision(nVo)
;-----------------------


;Renderworld, bla, bla
UpdateWorld
RenderWorld
Text 0,0,TrisRendered()

Flip
Wend
End




Function Update_NightVision(on)
If on <> 0 Then
Set_Gamma(-50,50,-50)
UpdateBlur(1028,768,1)
Else
Set_Gamma(0,0,0)
End If
End Function

Function Set_Gamma(red, green, blue)
   For k=0 To 255
      SetGamma k,k,k,k+red,k+green,k+blue
   Next
   UpdateGamma
End Function


Type blur
   Field spr
   Field tex
   Field art#
   Field blend
End Type

Type bloom
   Field spr
   Field tex
End Type



Function CreateBlurCam(camera,Strk,scx#,scy#,alpha#,blend,blend_2=1)

blur.Blur = New Blur

blur\tex = CreateTexture(GraphicsWidth(),GraphicsHeight(),256)
blur\art = strk
blur\spr = CreateSprite(camera)
PositionEntity blur\spr,0,-.5,blur\art
EntityOrder blur\spr,-1
ScaleSprite blur\spr,scx,scy
EntityTexture blur\spr,blur\tex,0,1
EntityAlpha blur\spr,alpha
TextureBlend blur\tex,blend
blur\blend = blend_2
EntityBlend blur\spr,blur_blend

End Function

Function CreateBloomCam(camera,wh#=64)

bloom.Bloom = New Bloom

bloom\tex = CreateTexture(wh,wh,256)
bloom\spr = CreateSprite(camera)
PositionEntity bloom\spr,0,0,1.7
EntityOrder bloom\spr,-2
ScaleSprite bloom\spr,2,2
EntityTexture bloom\spr,bloom\tex
EntityAlpha bloom\spr,.5
TextureBlend bloom\tex,5
EntityBlend bloom\spr,1+2

End Function



Function UpdateBlur(ghei, gwid, blur_on)
For blur.Blur = Each Blur
If blur_on = 1 Then
ShowEntity blur\spr
CopyRect 0,0,ghei,gwid,0,0,FrontBuffer(),TextureBuffer(blur\tex)
Else
HideEntity blur\spr
End If
Next
End Function






Function UpdateBloom(on)
For bloom.Bloom = Each Bloom

If on <> 0 Then
   

HideEntity bloom\spr
CameraViewport camera,0,0,TextureWidth(bloom\tex),TextureHeight(bloom\tex)
RenderWorld
CopyRect 0,0,TextureWidth(bloom\tex),TextureHeight(bloom\tex),0,0,BackBuffer(),TextureBuffer(bloom\tex)
CameraViewport camera,0,0,1024,768
ShowEntity bloom\spr


Else
HideEntity bloom\spr
End If

Next
End Function