; just a tiny Telnet-Client
; (c) 2003 by walski
; rInput by Darkmaster (copied from the blitzbasic.com Code-Archive/ User Input)

Const screen_width = 400
Const screen_height = 300
Graphics screen_width,screen_height,16,2

font_width = FontWidth()
font_height = FontHeight()

TelnetHost$ = Input$(\"Telnet Host:\")
TelnetPort = Input(\"Telnet Port:\")
stream = OpenTCPStream(TelnetHost$,TelnetPort)

If stream Then
	While Not Eof(stream)
	temp$ = \"\"
	If ReadAvail(stream)
		temp$ = ReadLine(stream)
		If Len(temp$)*font_width > screen_width Then
			While Len(temp$)*font_width > screen_width
				snd_Temp$ = Mid(temp$,1,Floor(screen_width/font_width)-1) + \"_\"
				Print snd_Temp$
				temp$ = \"_\" + Mid(temp$,Len(snd_Temp$))
			Wend
		EndIf
		Print Temp$
	EndIf
	Viewport 1,screen_height-font_height,screen_width,font_height
	iText$ = rInput$(iText$)
	Cls
	If Right(iText$,1)=Chr(13) Then
		WriteLine stream,Left(iText$,Len(iText$)-1)
		iText$=\"\"
	EndIf
	
	Text 1,screen_height-font_height,\"-> \" + iText$
	Viewport 1,1,screen_width,screen_height-font_height
	Wend
	Print \"Session closed\"
Else
	Print \"Connection Failed\"
EndIf
Print \"Press any key to exit\"
WaitKey()
End

Function rInput$(aString$)
value = GetKey()
length = Len(aString$)
If value = 8 Then value = 0 :If length > 0 Then aString$ = Left$(aString,Length-1)
If value = 13 Then aString$=aString$+Chr(13):Goto ende
If value = 0 Then Goto ende
If value>0 And value<7 Or value>26 And value<32 Or value=9 Then Goto ende
aString$=aString$ + Chr$(value)
.ende
Return aString$
End Function