;GetWindow - Konstanten (GW)
Const GW_HWNDFIRST=0
Const GW_HWNDLAST=1
Const GW_HWNDNEXT=2
Const GW_HWNDPREV=3
Const GW_OWNER=4
Const GW_CHILD=5
;/GetWindow - Konstanten

;ListOpendeWindows - Konstanten (LOP)
Const LOW_ALL=1
Const LOW_CHILDS=2
Const LOW_TITLE=4
Const LOW_CLASS=8
Const LOW_PROC=16
Const LOW_STRUCTURE=32
;/ListOpendeWindows - Konstanten

Global tmp_title_buffer
Global tmp_class_buffer
Global tmp_proc_id


Type openedwindow
   Field hWnd
   Field title$
   Field class$
   Field hProc
   Field Proc_ID
   Field parent
   Field childs
End Type
Global ownd.openedwindow



Function ListOpenedWindows(tmp_hWnd=0,tmp_flags=LOW_ALL Or LOW_TITLE Or LOW_CLASS)
   If (tmp_flags And LOW_ALL) And (tmp_flags And LOW_CHILDS) Then RuntimeError("Cant't mix LOW_ALL and LOW_CHILDS")
   If tmp_hWnd=0 Then tmp_hWnd=low_GetWindow(low_GetDesktopWindow(),GW_CHILD)
   
   For ownd=Each openedwindow
      Delete ownd
   Next
   
   tmp_title_buffer=CreateBank(0) ;Bank für den Fenstertitel erstellen
   tmp_class_buffer=CreateBank(256) ;Bank für die Fensterklasse erstellen
   tmp_proc_id=CreateBank(4) ;Bank für die Prozess-ID erstellen
   ListOpenedWindowsEx(tmp_hWnd,tmp_flags,Null)
   FreeBank tmp_title_buffer ;Bank für den Fenstertitel löschen
   FreeBank tmp_class_buffer ;Bank für die Fensterklasse löschen
   FreeBank tmp_proc_id ;Bank für die Prozess-ID löschen
End Function



Function ListOpenedWindowsEx(tmp_hWnd,tmp_flags,tmp_parent.openedwindow)
   If tmp_flags And LOW_ALL Then tmp_hWnd=low_GetWindow(tmp_hWnd,GW_HWNDFIRST)
   If tmp_flags And LOW_CHILDS Then tmp_hWnd=low_GetWindow(tmp_hWnd,GW_CHILD) : tmp_flags=tmp_flags-LOW_CHILDS+LOW_ALL
   
   While tmp_hWnd<>0
      ownd=New openedwindow
      ownd\hWnd=tmp_hWnd
      
      If tmp_flags And LOW_TITLE Then
         tmp_title_length=low_GetWindowTextLength(tmp_hWnd)+1 ;Fenstertitellänge ermitteln
         ResizeBank(tmp_title_buffer,tmp_title_length)
         low_GetWindowText(tmp_hWnd,tmp_title_buffer,tmp_title_length) ;Fenstertitel ermitteln
         tmp_title$=PeekString(tmp_title_buffer,0) ;Fenstertitel speichern
         ownd\title=tmp_title
      EndIf
      
      If tmp_flags And LOW_CLASS Then
         low_GetClassName(tmp_hWnd,tmp_class_buffer,256) ;Fensterklasse ermitteln
         tmp_class$=PeekString(tmp_class_buffer,0) ;Fensterklasse speichern
         ownd\class=tmp_class
      EndIf
      
      If tmp_flags And LOW_PROC Then
         low_GetWindowThreadProcessId(tmp_hWnd,tmp_proc_id) ;Prozess-ID ermitteln
         tmp_ProcID=PeekInt(tmp_proc_id,0)
         tmp_hProc=low_OpenProcess($F0000 Or $100000 Or $FFF,False,tmp_ProcID) ;Handle des Prozess' ermitteln
         ownd\hProc=tmp_hProc
         ownd\Proc_ID=tmp_Proc_ID
      EndIf
      
      
      If tmp_flags And LOW_STRUCTURE Then
         If tmp_parent<>Null Then
            ResizeBank(tmp_parent\childs,BankSize(tmp_parent\childs)+4)
            PokeInt(tmp_parent\childs,BankSize(tmp_parent\childs)-4,Handle(ownd))
         EndIf
         ownd\parent=Handle(tmp_parent)
         ownd\childs=CreateBank(0)
      EndIf
      
      tmp2_hWnd=low_GetWindow(tmp_hWnd,GW_CHILD)
      If tmp2_hWnd<>0 Then ListOpenedWindowsEx(tmp2_hWnd,tmp_flags,ownd)
      tmp_hWnd=low_GetWindow(tmp_hWnd,GW_HWNDNEXT)
   Wend
End Function



Function PeekString$(tmp_buffer,tmp_pos)
   For i=0 To BankSize(tmp_buffer)-1
      byte=PeekByte(tmp_buffer,tmp_pos)
      If byte<>0
         ret$=ret$+Chr(byte)
      Else
         Return ret$
      EndIf
      tmp_pos=tmp_pos+1
   Next
   RuntimeError "String terminator not found."
End Function

.lib "user32.dll"
low_FindWindowEx%(hWnd%,hWndChild%,lpszClassname$,lpszWindow$) : "FindWindowExA"

low_GetDesktopWindow%() : "GetDesktopWindow"
low_GetWindow%(hWnd%,wCmd%) : "GetWindow"

low_GetWindowText%(hWnd%,lpString*,cch%) : "GetWindowTextA"
low_GetWindowTextLength%(hWnd%) : "GetWindowTextLengthA"
low_GetClassName%(hWnd%,lpClassName*,nMaxCount%) : "GetClassNameA"

low_GetWindowThreadProcessId%(hWnd,lpdwProcessId*) : "GetWindowThreadProcessId"


.lib "kernel32.dll"
low_OpenProcess%(dwDesiredAccess%,bInheritHandle%,dwProcessId%) : "OpenProcess"


.lib " "
ListOpenedWindows(hWnd%,flags%)

Include "ListOpenedWindows(hWnd,flags).bb"

hTask=low_FindWindowEx(0,0,"Shell_TrayWnd","")
ListOpenedWindows(hTask,LOW_CHILDS Or LOW_TITLE Or LOW_CLASS Or LOW_PROC Or LOW_STRUCTURE)

For ownd=Each openedwindow
   number=number+1
   DebugLog "hWnd: "+ownd\hWnd
   DebugLog "Titel: "+ownd\title
   DebugLog "Klasse: "+ownd\class
   DebugLog "hProc: "+ownd\hProc
   DebugLog "Proc-ID: "+ownd\Proc_ID
   DebugLog "Parent: "+ownd\parent
   For i=0 To BankSize(ownd\childs)/4-1
      DebugLog "Child: "+PeekInt(ownd\childs,i*4)
   Next
   DebugLog ""
Next

DebugLog "Ihre Taskleiste besteht aus "+number+" Fenstern und Childs"

WaitKey
End