'------------------------
'   ..::Time Plant::..
'------------------------
'By: ComNik
'Date: 31.08.2009
'------------------------
SuperStrict 

Import BRL.Max2D 
Import BRL.Retro

'// Initialise Window
Local GWIDTH:Int  = 300
Local GHEIGHT:Int = 500
AppTitle="TimePlant"  
Graphics(GWIDTH,GHEIGHT,0,30)

'// Gfx
Global LedGfx:TImage = LoadAnimImage("led.png",32,32,0,2)

'// Level of Detail. - and Performance...
Global ITERATIONS:Int = 3  

'// Rule Class.
Type TRule
	Field A:String '// Search for A...
	Field B:String '// ...and replace with B
End Type

'// Plant Data.
Global HourPlant:TRule = CreateRule("F","F[+F]F[-F]F")   		'// The Hour-Plant Creation-Rule.
Global MinPlant:TRule  = CreateRule("F","F[+F]F[-F]F")  '// The Minute-Plant Creation-Rule.

Global HPlantStepSize:Float = 1.0  '// Hour Plant Step Size.
Global HPlantDelta:Float    = 22.5 '// Hour Plant Delta Value.
Global MPlantStepSize:Float = 1.0  '// Minute Plant Step Size.
Global MPlantDelta:Float    = 22.5 '// Minute Plant Delta Value.

Global DrawHour:Int = GWIDTH - 160
Global DrawMin:Int  = GWIDTH - 190 

'// Clock Data.
Global CurrTime:String,CurrHour:Int,CurrMinute:Int '// Strings to Store the Current Time.
Global StartTime:Int = MilliSecs() - 30000         '// Update-Timer.

'// Leds.
Global HourLeds:Byte[5]
Global MinLeds:Byte[6]

'//Main Loop
SetClsColor(255,255,255)
While Not KeyDown(KEY_ESCAPE) Or AppTerminate()
	Cls 
		'// Every half minute...
		If MilliSecs() - StartTime > 30000
			'// Store Current Time.
			CurrTime   = CurrentTime()  '// Time.
			CurrHour   = Int(GetHour(CurrTime))  '// Hours.
			CurrMinute = Int(GetMinute(CurrTime))'// Minutes. 
			
			UpdateClock(CurrHour,CurrMinute)
			'// Update Timer.
			StartTime = MilliSecs()
		End If 
		'// Draw the Clock.
		DrawClock()
		'//Update Plants.
		UpdateHourPlant()
		UpdateMinutePlant()
		'// Draw the Time Plant.
		ParseSystem(CreateSystem("F",HourPlant),50,GHEIGHT,HPlantStepSize,22.5)
		ParseSystem(CreateSystem("F",MinPlant),200,GHEIGHT,MPlantStepSize,22.5) 
	Flip
Wend
End

'--------------------------
'CREATE > FUNCTIONS
'--------------------------
'// Create new Rule.
Function CreateRule:TRule(A:String,B:String)
	Local Rule:TRule = New TRule
		Rule.A = A
		Rule.B = B
		
	Return Rule
End Function 

'// Create a new DOL-System with a specified number of Generations.
Function CreateSystem:String(Axiom:String,Rule:TRule)
	Local Result:String = Axiom 
	
	For Local i:Int=1 To ITERATIONS 
		Result = Replace(Result,Rule.A,Rule.B)
	Next 
	
	Return Result 
End Function 

'--------------------------
'PLANT > FUNCTIONS
'--------------------------
'// Draw a DOL-System.
Function ParseSystem(System:String,X:Float,Y:Float,StepSize:Float,Delta:Float)
	Local Angle:Float = 90
	Local NewX:Float,NewY:Float 
	Local SavePointer:Int,Rotation:Float[100],PositionX:Float[100],PositionY:Float[100]

	SetColor(0,0,0)

	For Local i:Int=1 To Len(System)
		Select Mid(System,i,1)
			Case "F" '// Draw.
				NewX = X + StepSize*Cos(Angle)
				NewY = Y - StepSize*Sin(Angle)
				
				DrawLine(X,Y,NewX,NewY)
				
				X = NewX
				Y = NewY
			Case "+" '// Increase Angle.
				Angle = Angle + Delta
			Case "-" '// Decrease Angle.
				Angle = Angle - Delta
			Case "["
				Rotation[SavePointer]  = Angle 
				PositionX[SavePointer] = X
				PositionY[SavePointer] = Y
				SavePointer:+ 1 
			Case "]"
				SavePointer:- 1
				Angle       = Rotation[SavePointer]
				X           = PositionX[SavePointer]
				Y           = PositionY[SavePointer]
		End Select
	Next 
	
	SetColor(255,255,255)
End Function 

'// Update the HourPlant-System in relation to Time.
Function UpdateHourPlant()
	Local Tmp:Int = CurrHour/2 
	If Tmp > HPlantStepSize
		HPlantStepSize:+ 0.1
	ElseIf Tmp < HPlantStepSize
		HPlantStepSize = Tmp   
	End If 
End Function 

'// Update the MinutePlant-System in relation to Time.
Function UpdateMinutePlant()
	Local Tmp:Int = CurrMinute/5
	If CurrMinute < 60  
		If Tmp > MPlantStepSize
			MPlantStepSize:+ 0.05
		ElseIf Tmp < MPlantStepSize
			MPlantStepSize = Tmp
		End If
	Else
		If MPlantStepSize > 0
			MPlantStepSize:- 0.05
		End If
	End If  
End Function 
'--------------------------
'CLOCK > FUNCTIONS
'--------------------------
'// Get current Hour.
Function GetHour:String(Time:String)
	Return Left(Time,2)
End Function 

'// Get current Minute.
Function GetMinute:String(Time:String)
	Return Mid(Time,4,2)
End Function 

Function UpdateClock(Hours:String,Minutes:String)
	UpdateHours(Int(Hours))
	UpdateMinutes(Int(Minutes))
End Function

Function DrawClock()
	Local l:Int
	'// Update Leds.
	For l=0 To 4
		DrawImage(LedGfx,DrawHour+l*32,5,HourLeds[l]) 
	Next 
	For l=0 To 5
		DrawImage(LedGfx,DrawMin+l*32,44,MinLeds[l])
	Next 
End Function  

'// Update Hours.
Function UpdateHours(Hour:Int)
	Local j:Int=4,i:Int 
	Local HPower:Int 
	For i=0 To 4 
		HPower = 2^j
		If Hour >= HPower 
			HourLeds[i] = False 
			Hour:- HPower 
		Else
			HourLeds[i] = True 
		End If 
		j:- 1 
	Next  	
End Function 

'// Update Minutes.
Function UpdateMinutes(Minute:Int)
	Local k:Int=5,i:Int 
	Local MPower:Int 

	For i=0 To 5 
		MPower = 2^k  
		If Minute >= MPower  
			MinLeds[i] = False
			Minute:- MPower
		Else
			MinLeds[i] = True 
		End If 
		k:- 1
	Next
End Function