SuperStrict

Framework BRL.System


AppTitle="Lord Stweccy's Sprachenerkenner"
Local letter_d:Float[26]
Local letter_e:Float[26]
Local letter_r:Float[26]
letter_d=[6.51,1.89,3.06,5.08,17.40,1.66,3.01,4.76,7.55,0.27,1.21,3.44,2.53,9.78,2.51,0.79,0.02,7.00,7.27,6.15,4.35,0.67,1.89,0.03,0.04,1.13]
letter_e=[8.2,1.5,2.8,4.3,12.7,2.2,2.0,6.1,7.0,0.2,0.8,4.0,2.4,6.7,7.5,1.9,0.1,6.0,6.3,9.1,2.8,1.0,2.4,0.2,2.0,0.1]

If Len(AppArgs)<2
	Notify "Ziehe eine beliebige Textdatei auf mich und ich sage, dir in welcher Sprache sie vermutlich verfasst wurde (enlisch oder deutsch)"
	End
EndIf


Local file:TStream=ReadFile(AppArgs[1])
If file=Null
	Notify "Die Datei konnte nich gefunden werden!"
	End
EndIf
Local count:Int

While Eof(file)=0
	Local b:Int=ReadByte(file)
	If b>=65 And b<=90' großbuchstaben
		letter_r[b-65]=letter_r[b-65]+1
		count=count+1
	EndIf
	If b>=97 And b<=122' kleinbuchstaben
		letter_r[b-97]=letter_r[b-97]+1
		count=count+1
	EndIf
Wend
CloseFile file
If count=0
	Notify "In dem Text konnten keine verwendbaren Buchstaben gefunden werden!"
	End
EndIf



Local langc:Int

For Local i:Int=0 To 25
	letter_r[i]=letter_r[i]/count*100
	If Abs(letter_r[i]-letter_e[i])>Abs(letter_r[i]-letter_d[i])
		langc=langc+1
	EndIf
Next

If langc>14
	Notify "Der Text ist wahrscheinlich Deutsch"
Else
	Notify "Der Text ist wahrscheinlich Englisch"
EndIf
End