Const HKEY_LOCAL_MACHINE = $80000002
Const KEY_READ = $20019
Const ERROR_NO_MORE_ITEMS = 259

 ; Öffnet das Uninstall-Verzeichnis in der Registry
Local bKey = CreateBank ( 4 )
RegOpenKeyEx ( HKEY_LOCAL_MACHINE, "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall", 0, KEY_READ, bKey )
Global hKey = PeekInt ( bKey, 0 )
FreeBank bKey

 ; Geht alle installierten Programme durch
Local index = 0
Local keyName = CreateBank ( 256 )
Local keySize = CreateBank ( 4 )
Repeat
	PokeInt keySize, 0, 256 
	Local ret = RegEnumKeyEx ( hKey, index, keyName, keySize, 0, 0, 0, 0 )
	If ret = ERROR_NO_MORE_ITEMS Then Exit
	
	Print "----------"
	Print GetProperty ( keyName, "DisplayName" )
	Print GetProperty ( keyName, "Publisher" )
	Print GetProperty ( keyName, "UninstallString" )
	
	index = index + 1
Forever
FreeBank keyName
FreeBank keySize

RegCloseKey ( hKey )

WaitKey

Function GetProperty$ ( keyName, Value$ )
	Local valueNameStr$, i
	Local valueName = CreateBank ( 256 )
	Local valueSize = CreateBank ( 4 )
	PokeInt valueSize, 0, 256 
	
	RegGetValue ( hKey, keyName, Value$, $FFFF, 0, valueName, valueSize )
	valueNameStr$ = ""
	For i = 1 To PeekInt ( valueSize, 0 )
		valueNameStr$ = valueNameStr$ + Chr ( PeekByte ( valueName, i-1 ) )
	Next
	
	FreeBank valueName
	FreeBank valueSize
	
	Return valueNameStr$
End Function