Import Eisvogel.MultiWindow

InitMultiWindow(title:String)

AddMultiWindow:TMWindow(x:Int, y:Int, width:Int, height:Int)

ChangeMultiWindow(mwnd:TMWindow, x:Int, y:Int, width:Int, height:Int)

RemoveMultiWindow(mwnd:TMWindow)

UpdateMultiWindow(redraw:Byte = False)

MultiWindowWidth:Int()
MultiWindowHeight:Int()

SuperStrict

Import eisvogel.multiwindow


InitMultiWindow("Multi-Window - Sample")

Local wnd_mouse:TMWindow = AddMultiWindow(MultiWindowWidth() / 2 - 125, MultiWindowHeight() / 2 - 125, 250, 250)
Local wnd_wh:TMWindow = AddMultiWindow(30, 30, 250, 50)

Local timer:TTimer = CreateTimer(60)

Local mx:Int, my:Int

Repeat
	WaitTimer(timer)
	Cls
	
	DrawRect mx - 124, my - 124, 248, 248
	ChangeMultiWindow(wnd_mouse, mx - 125, my - 125, 250, 250)
	
	DrawText "Multi-Window-Breite: " + MultiWindowWidth(), 40, 40
	DrawText "Multi-Window-Hoehe: " + MultiWindowHeight(), 40, 60
	
	mx = MouseX()
	my = MouseY()
	
	UpdateMultiWindow()
	
	Flip 0
Until KeyHit(KEY_ESCAPE)
End

SuperStrict

Rem
bbdoc:  Multi-Window
End Rem
Module Eisvogel.MultiWindow

ModuleInfo "Version: 1.00"
ModuleInfo "Author: Marc-Peter Eisinger"
ModuleInfo "License: Open Source"
ModuleInfo "Copyright: Eisvogel, Marc-Peter Eisinger 2010"

Import brl.blitz
Import brl.Graphics
Import brl.GLGraphics
Import brl.max2d
Import brl.glmax2d
Import brl.d3d7max2d
Import brl.d3d9max2d


Private

Extern "Win32"
	Function GetSystemMetrics:Int(nIndex:Int)
	Function CreateRectRgn:Int(x1:Int, y1:Int, x2:Int, y2:Int)
	Function CombineRgn:Int(hDestRgn:Int, hSrcRgn1:Int, hSrcRgn2:Int, nCombineMode:Int)
	Function SetWindowRgn:Byte(hWnd:Int, hRgn:Int, bRedraw:Int)
	Function DeleteObject:Byte(hObject:Int)
End Extern


Const SM_CXSCREEN:Byte = 0
Const SM_CYSCREEN:Byte = 1
Const SM_CYCAPTION:Byte = 4
Const SM_CXFIXEDFRAME:Byte = 7
Const SM_CYFIXEDFRAME:Byte = 8

Global MW_hWnd:Int
Global MW_width:Int
Global MW_height:Int
Global MW_offsetx:Int
Global MW_offsety:Int
Global MW_changed:Byte


Public

Type TMWindow Abstract
End Type


Private

Type TMWindow2 Extends TMWindow
	Global list:TList = CreateList()
	
	Field x:Int
	Field y:Int
	Field w:Int
	Field h:Int
	
	Method New()
		ListAddLast(list, Self)
	End Method
End Type

Public



Rem
bbdoc: Initialize Multi-Window.
End Rem
Function InitMultiWindow(title:String)
	'Fensterbreite und -höhe ermitteln
	MW_width = GetSystemMetrics(SM_CXSCREEN)
	MW_height = GetSystemMetrics(SM_CYSCREEN)
	
	'Client-Offsets ermitteln
	MW_offsetx = GetSystemMetrics(SM_CXFIXEDFRAME)
	MW_offsety = GetSystemMetrics(SM_CYFIXEDFRAME) + GetSystemMetrics(SM_CYCAPTION)
	
	'Fenster erstellen und Handle ermitteln
	AppTitle = title
	MW_hWnd = ApphWnd(Graphics(MW_width, MW_height))
	
	'Fenster-Region erstellen und setzten
	Local rgn:Int = CreateRectRgn(0, 0, 0, 0)
	SetWindowRgn(MW_hWnd, rgn, True)
	DeleteObject(rgn)
End Function



Rem
bbdoc: Returns width of Multi-Window.
End Rem
Function MultiWindowWidth:Int()
	Return MW_width
End Function

Rem
bbdoc: Returns height of Multi-Window.
End Rem
Function MultiWindowHeight:Int()
	Return MW_height
End Function



Rem
bbdoc: Adds a rect context to Multi-Window.
End Rem
Function AddMultiWindow:TMWindow(x:Int, y:Int, width:Int, height:Int)
	MW_changed = True
	Local wnd:TMWindow2 = New TMWindow2
	wnd.x = x
	wnd.y = y
	wnd.w = width
	wnd.h = height
	Return wnd
End Function

Rem
bbdoc: Changes a rect context of Multi-Window.
End Rem
Function ChangeMultiWindow(mwnd:TMWindow2, x:Int, y:Int, width:Int, height:Int)
	MW_changed = True
	Local wnd:TMWindow2 = TMWindow2(mwnd)
	wnd.x = x
	wnd.y = y
	wnd.w = width
	wnd.h = height
End Function

Rem
bbdoc: Deletes a context of MultiWindow.
End Rem
Function RemoveMultiWindow(mwnd:TMWindow)
	MW_changed = True
	Local wnd:TMWindow2 = TMWindow2(mwnd)
	ListRemove(TMWindow2.list, wnd)
End Function



Rem
bbdoc: Updates the contexts of Multi-Window.
about: If redraw is true, the window will be updated instantly. Otherwise the window will be updated by the next update comand like Flip.
End Rem
Function UpdateMultiWindow(redraw:Byte = False)
	If Not MW_changed Then Return
	
	'Startregion erstellen
	Local rgn:Int = CreateRectRgn(0, 0, 0, 0)
	
	'Fenster-Regionen einbinden
	For Local wnd:TMWindow2 = EachIn TMWindow2.list
		Local tx:Int = MW_offsetx + wnd.x
		Local ty:Int = MW_offsety + wnd.y
		Local tw:Int = MW_offsetx + wnd.x + wnd.w
		Local th:Int = MW_offsety + wnd.y + wnd.h
		If tx < MW_offsetx Then tx = MW_offsetx
		If tx > MW_offsetx + MW_width Then tx = MW_offsetx + MW_width
		If ty < MW_offsety Then ty = MW_offsety
		If ty > MW_offsety + MW_height Then ty = MW_offsety + MW_height
		If tw > MW_offsetx + MW_width Then tw = MW_offsetx + MW_width
		If tw < MW_offsetx Then tw = MW_offsetx
		If th > MW_offsety + MW_height Then th = MW_offsety + MW_height
		If th < MW_offsety Then th = MW_offsety
		Local wnd_rgn:Int = CreateRectRgn(tx, ty, tw, th)
		CombineRgn(rgn, rgn, wnd_rgn, 2)
		DeleteObject(wnd_rgn)
	Next
	
	'Fenster-Region setzten
	SetWindowRgn(MW_hWnd, rgn, redraw)
	DeleteObject(rgn)
End Function



Private

Function ApphWnd:Int(g:TGraphics)
	If g = Null Then Return Null
	
	Local GraphicsDevice:TGraphics
	If g.Driver() <> GLGraphicsDriver() Then
		GraphicsDevice = TMax2DGraphics(g)._graphics
	Else
		GraphicsDevice = g
	EndIf
	
	Select g.Driver()
		Case GLGraphicsDriver(), GLMax2DDriver()
			Return Int Ptr(TGLGraphics(GraphicsDevice)._context)[8]
		Case D3D7Max2DDriver()
			Return TD3D7Graphics(GraphicsDevice)._hWnd
		Case D3D9Max2DDriver()
			Return TD3D9Graphics(GraphicsDevice)._hWnd
	End Select
End Function