Rem
   bbdoc:TScreen, manages resolutions
End Rem
Type TScreen
   Field width:Int
   Field height:Int

   Field virtualOffset:Int[2]
   Field virtualSize:Int[2]
   Field virtualScaledSize:Int[2]
   Field physicalSize:Int[2]
   Field bar_color:Byte[3]
   Field bar_draw:Byte
   Field gfx:TGraphics
   
   Field basic_color:Byte[3]
   Field basic_alpha:Float
   Field basic_rotation:Float
   Field basic_blend:Byte
   
   Field layerList:TList = New TList
   Field layer_priorityDirty:Byte
   
   Method addRenderLayer(rl:TRenderLayer)
      Assert rl, "TScreen.addRenderLayer(rl=NULL)"
      rl.m_screenLink = layerList.AddLast(rl)
      rl.screen = Self
      Self.setLayer_PriorityDirty()
   End Method

   
   Method setVirtualSize(width:Int, height:Int)
      virtualSize[0] = width
      virtualSize[1] = height
   End Method
   
   Method setPhysicalSize(width:Int, height:Int)
      physicalSize[0] = width
      physicalSize[1] = height
   End Method
   
   Method SetBar_draw(on:Byte = True)
      bar_draw = on
   End Method
   
   Method setBar_Color(r:Byte = 0, g:Byte = 0, b:Byte = 0)
      bar_color[0] = r
      bar_color[1] = g
      bar_color[2] = b
   End Method
   
   Method setBasic_color(r:Byte = 255, g:Byte = 255, b:Byte = 255)
      basic_color[0] = r
      basic_color[1] = g
      basic_color[2] = b
   End Method
   
   Method setBasic_alpha(a:Float = 1)
      basic_alpha = a
   End Method
   
   Method setBasic_rotation(angle:Float = 0)
      basic_rotation = angle
   End Method
   
   Method setBasic_blend(mode:Byte = ALPHABLEND)
      basic_blend = mode
   End Method
   
   Method setLayer_PriorityDirty()
      layer_priorityDirty = True
   End Method
   
   Method init()
      calcScreensize()
      restartGraphics()
      SetBar_draw()
      setBar_Color()
      setBasic_alpha()
      setBasic_blend()
      setBasic_color()
      setBasic_rotation()
   End Method
   
   Method restartGraphics()
      remove_graphics()
      gfx = Graphics(physicalSize[0], physicalSize[1])
      SetVirtualResolution(virtualScaledSize[0], virtualScaledSize[1])
      SetOrigin(virtualOffset[0], virtualOffset[1])
   End Method
   
   Method render()
      startRender()
      If layer_priorityDirty Self.layerList.Sort()
      For Local l:TRenderLayer = EachIn layerList
         applyBasicRenderSettings()
         l.render()
      Next
      finishRender()
   End Method
   
   Method startRender()
      Cls
      applyBasicRenderSettings()
   End Method
   
   Method finishRender()
      If bar_draw renderBars()
      Flip
   End Method
   
   Method applyBasicRenderSettings()
      SetColor basic_color[0], basic_color[1], basic_color[2]
      SetAlpha basic_alpha
      SetRotation basic_rotation
      SetBlend basic_blend
   End Method
   
   Method renderBars()
      SetOrigin(0, 0)
      SetColor bar_color[0], bar_color[1], bar_color[2]
      'left bar
      DrawRect 0, 0, virtualOffset[0], virtualScaledSize[1]
      'right bar
      DrawRect virtualScaledSize[0] - virtualOffset[0], 0, virtualOffset[0], virtualScaledSize[1]
      'upper bar
      DrawRect 0, 0, virtualScaledSize[0], virtualOffset[1]
      'lower bar
      DrawRect 0, virtualScaledSize[1] - virtualOffset[1], virtualScaledSize[0], virtualOffset[1]
      SetOrigin(virtualOffset[0], virtualOffset[1])
   End Method
   
   Method calcScreensize()
      Local scale:Float = Max(Float(virtualSize[0]) / physicalSize[0], Float(virtualSize[1]) / physicalSize[1])
      virtualScaledSize[0] = physicalSize[0] * scale
      virtualScaledSize[1] = physicalSize[1] * scale
      
      virtualOffset[0] = (virtualScaledSize[0] - virtualSize[0]) / 2
      virtualOffset[1] = (virtualScaledSize[1] - virtualSize[1]) / 2
      
      width = virtualSize[0]
      height = virtualSize[1]
   End Method
   
   Method remove()
      remove_graphics()
      remove_renderLayers()
   End Method
   
   Method remove_graphics()
      If gfx = Null Return
      CloseGraphics(gfx)
      gfx = Null
   End Method
   
   Method remove_renderLayers()
      For Local rl:TRenderLayer = EachIn Self.layerList
         rl.remove()
      Next
   End Method
End Type