Graphics 575,80,32,2

SetBuffer BackBuffer()

Global SW%=GraphicsWidth()
Global SH%=GraphicsHeight()

Const startflakes%=0      ; start amount of flakes
Const totalflakes%=50000   ; maximum amount of flakes
Const snowchance#=100      ; chance in % for new flakes
Const chanceflakes#=100      ; randomize amount of new flakes (1...x)

Type snow
   
   Field x#,y#
   Field col%
   Field dirx#,diry#
   
End Type

CreateSnow(startflakes)

logo=LoadImage("header.png") : Global lbuffer=ImageBuffer(logo)
matte=LoadImage("matte.png") : Global mbuffer=ImageBuffer(matte)

Dim SNOW%(SW,SH)
LockBuffer mbuffer
For y=0 To SH-1
   For x=0 To SW-1
      r=(ReadPixelFast(x,y,mbuffer) And $ff0000)/$10000
      If r<>0 Then SNOW(x,y)=1 Else SNOW(x,y)=0
   Next
Next
UnlockBuffer mbuffer


fbuffer=FrontBuffer()

timer=CreateTimer(60)

While Not KeyHit(1)
   
   Cls
   
   DrawImage logo,0,0
   
   LockBuffer fbuffer
   
   AppTitle UpdateSnow(fbuffer)+" Flocken"
   
   UnlockBuffer fbuffer
   
   Flip 0
   
   WaitTimer timer
   
Wend

End

Function UpdateSnow(buffer%)
   
   Local counter%=0
   
   LockBuffer buffer
   
   For s.snow = Each snow
      
      recycle=False
      
      ; count flakes
      counter=counter+1
      
      ; add horizontal movement
      s\x=s\x+Rnd(-1,1)
      
      ; add vertical movement
      s\y=s\y+s\diry
      
      ; flake reached screen bottom
      If s\y>SH-1 Then RecycleFlake(s)
      If s\y<0 Then RecycleFlake(s)
      
      ; flake hit snow
      If s\y>=0 And s\x>=0 And s\x<SW And s\y<SH Then
         
         fx=Int(s\x)
         fy=Int(s\y)
         
         dist%=Rand(1,2)
         
         If fx<dist Then fx=(SW-dist)+fx
         If fx>(SW-dist) Then fx=fx-(SW-dist-1)
         
         If SNOW(fx,fy)<>0 Then
            
            fx=fx+(SNOW(fx-dist,fy+1)-SNOW(fx+dist,fy+1))
            
            If fx<dist Then fx=(SW-dist)+fx
            If fx>(SW-dist) Then fx=fx-(SW-dist-1)
            
            If fy<1 Then fy=1
            If fy>SH-2 Then fy=SH-2
            
            If SNOW(fx,fy)<>0 Then
               
               SNOW(fx,fy-1)=(SNOW(fx-dist,fy)+SNOW(fx+dist,fy)+SNOW(fx,fy-1)+SNOW(fx,fy+1))*Rnd(0.1,0.25)
               
               RecycleFlake(s)
               LockBuffer lbuffer
               rgb=s\col*$10000+s\col*$100+s\col
               WritePixelFast fx,fy,rgb,lbuffer
               UnlockBuffer lbuffer
               
            EndIf
         EndIf
         
      EndIf
      
      ; draw pixel if onscreen
      rgb=s\col*$10000+s\col*$100+s\col
      If s\y>=0 And s\y<SH And s\x>=0 And s\x<SW Then
         
         WritePixelFast Int(s\x),Int(s\y),rgb,buffer
         
      EndIf
      
   Next
   
   ; create new flakes up to maximum amount
   c=Rand(1,chanceflakes)
   If counter+c<=totalflakes And Rnd(1)>(1-(snowchance/100.0)) Then
      For i=1 To c
         CreateNewFlake()
      Next
   EndIf
   
   UnlockBuffer buffer
   
   Return counter
   
End Function

Function RecycleFlake(s.snow)
   
   s\x=Rnd(0,SW-1)
   s\y=Rnd(-SH,-1)
   s\col=Rand(192,255)
   s\dirx=Rnd(-1,1)
   s\diry=Rnd(0.5,2)
   
End Function

; creates the initial flakes
Function CreateSnow(flakes%=1)
   
   Local i%
   
   For i=1 To flakes
      
      CreateNewFlake()
      
   Next
   
End Function

; creates an additional flake
Function CreateNewFlake()
   
   s.snow = New snow
   s\x=Rnd(0,SW-1)
   s\y=Rnd(-SH,0)
   s\col=Rand(192,255)
   s\dirx=Rnd(-1,1)
   s\diry=Rnd(0.5,1)
   
End Function

fx=fx+(SNOW(fx-d1,fy+1)-SNOW(fx+d1,fy+1))