'KI Basis-Type
Type BaseKI Abstract
   Field Monster:BaseMonster

   'Events die vom Monstertype aufgerufen werden
   Method OnDeath() Abstract
End Type


'Monster Basis-Type
Type BaseMonster Abstract
   Field X:Int, Y:Int
   Field Health:Int, MaxHealth:Int
   Field Death:Int
   
   'Die aktuelle KI für das Monster
   Field KI:BaseKI
   
   'Update-Methode die für alle Monster gilt, sofern sie nicht überschrieben wird
   Method Update()
      If Health <= 0 And Not Death Then
         Death = True
         If KI <> Null Then KI.OnDeath()
      EndIf
   End Method
   
   'Methode um das Monster zu bewegen
   Method Move(xval:Int, yval:Int)
      X :+ xval
      Y :+ yval
   End Method
End Type


'Ein erstes Monster ^^
Type Fledermaus Extends BaseMonster

   'Zum erstellen einer Fledermaus und zuordnen einer KI
   Function Create:Fledermaus(X:Int, Y:Int, Health:Int, KI:BaseKI)
      Local f:Fledermaus = New Fledermaus
      f.X = X
      f.Y = Y
      f.Health = Health
      f.MaxHealth = Health
      f.KI = KI
      f.KI.Monster = f '<-- Monster für die KI setzen
      Return f
   End Function
End Type


'Eine KI zu dem Monster, lässt sich dann natürlich für mehrere Benutzen
Type EasyKI Extends BaseKI

   'Wird aufgerufen wenn die Fledermaus tot ist ^^
   Method OnDeath()
      Monster.Move(1,1)
      Print "Juhu, ich bin tot"
   End Method
End Type


Graphics 800, 600, 0

Local KI_1:EasyKI = New EasyKI
Local f:Fledermaus = Fledermaus.Create(10, 10, 100, KI_1)

Repeat
Cls

   If KeyHit(KEY_SPACE) Then f.Health :- 100
   f.Update()

Flip
Until KeyHit(KEY_ESCAPE)

EndGraphics
End