Type TFuncClass
	Method Func() Abstract
End Type

Type Test1 Extends TFuncClass
	Method Func()
		Print "dies ist ein test" 
	End Method
End Type
Local VarTest1:Test1 = New Test1

Type Test2 Extends TFuncClass
	Method Func()
		Print "dies ist ein anderer test" 
	End Method
End Type
Local VarTest2:Test2 = New Test2

Local FuncClassList:TList = CreateList()
ListAddLast(FuncClassList, VarTest1)
ListAddLast(FuncClassList, VarTest2)

For Local FuncClass:TFuncClass = EachIn FuncClassList
	FuncClass.Func()
Next

Type TFunc
	Field FuncPtr:Object()
	
	Function Create:TFunc( _FuncPtr:Object() )
		Local tmp:TFunc = New TFunc
		tmp.FuncPtr = _FuncPtr
		Return tmp
	End Function 
End Type

Local List:TList = CreateList( )
Local Test1:TFunc = TFunc.Create( func1 )
	List.AddLast( Test1 )

Local Test2:TFunc = TFunc.Create( func2 )
	List.AddLast( Test2 )
	
	
For Local tmp:TFunc = EachIn List
	tmp.FuncPtr( )
Next 

Function func1:Object( )
	Print "Funktion 1"
End Function 

Function func2:Object( )
	Print "Funktion 2"
End Function

Import BRL.Blitz
Import BRL.Map

Type TFPtrWrapper
	
	Field _rgNameSpaces:TMap
	Field _NullNameSpace:TNameSpace
	Field _CurrentNameSpace:TNameSpace
	
'Constructors & Destructor
	Function Create:TFPtrWrapper()
		Return New TFPtrWrapper.Init()
	End Function
	
	Method Init:TFPtrWrapper()
		Self._rgNameSpaces=CreateMap()
		Self._NullNameSpace=TNameSpace.Create("")
		Self._CurrentNameSpace=Self._NullNameSpace
		Self.FinishNameSpace()
		Return Self
	End Method
	
'Interfacing
	Method RegisterNameSpace(rgchName:String)
		Self._CurrentNameSpace=TNameSpace.Create(rgchName)
	End Method
	
	Method FinishNameSpace()
		Self._rgNameSpaces.Insert(Self._CurrentNameSpace.Name().ToLower(),Self._CurrentNameSpace)
		Self._CurrentNameSpace=Self._NullNameSpace
	End Method
	
	Method RestoreNameSpace(rgchName:String)
		Self._CurrentNameSpace=TNameSpace(Self._rgNameSpaces.ValueForKey(rgchName.ToLower()))
	End Method
	
	Method LookUpNameSpace:TNameSpace(rgchName:String)
		Local Obj:Object=Self._rgNameSpaces.ValueForKey(rgchName.ToLower())
		Return TNameSpace(Obj)
	End Method
	
	Method HasNameSpace:Byte(rgchName:String)
		Return Self._rgNameSpaces.Contains(rgchName.ToLower())
	End Method
	
	Method AddFPtr(FPtr:TFPtr)
		Self._CurrentNameSpace.AddFPtr(FPtr)
	End Method
	
	Method GetFPtr:TFPtr(rgchName:String)
		Local rgch:String[]=rgchName.Split("::")
		Local NameSpace:TNameSpace,FPtr:TFPtr
		NameSpace=Self.LookUpNameSpace(rgch[0])
		If NameSpace=Null Then RuntimeError "Could not find namespace "+rgch[0]
		FPtr=NameSpace.GetPtr(rgch[1])
		If FPtr=Null Then RuntimeError "Could not find FPtr "+rgch[1]
		Return FPtr
	End Method
	
	Method List()
		Local NameSpace:TNameSpace
		Local FPtr:TFPtr
		Print ""
		Print "FPtrWrapper lists all namespaces:"
		For NameSpace=EachIn Self._rgNameSpaces.Values()
			Print "--> Namespace: "+NameSpace.Name()
			For FPtr=EachIn NameSpace._rgFPtr.Values()
				Print "   --> FPtr: "+FPtr.Name()
			Next
		Next
		Print "Done!"
		Print ""
	End Method
	
End Type

Type TNameSpace
	
	Field _rgchName:String
	Field _rgFPtr:TMap
	
'Constructors & Destructor
	Function Create:TNameSpace(rgchName:String)
		Return New TNameSpace.Init(rgchName)
	End Function
	
	Method Init:TNameSpace(rgchName:String)
		Self._rgFPtr=CreateMap()
		Self._rgchName=rgchName
		Return Self
	End Method
	
'Interfacing
	Method AddFPtr(FPtr:TFptr)
		Self._rgFPtr.Insert(FPtr.Name().ToLower(),FPtr)
	End Method
	
	Method GetPtr:TFPtr(rgchName:String)
		Return TFPtr(Self._rgFPtr.ValueForKey(rgchName.ToLower()))
	End Method
	
	Method FreePtr(rgchName:String)
		Self._rgFPtr.Remove(rgchName.ToLower())
	End Method
	
'Getters & Setters
	Method Name:String()
		Return Self._rgchName
	End Method
	
End Type

Type TFPtr Abstract
	
	Const C_cType:Byte=5
	Const C_sType_VoidVoid:Byte=0
	Const C_sType_VoidObj:Byte=1
	Const C_sType_ObjVoid:Byte=2
	Const C_sType_ObjObj:Byte=3
	Const C_sType_Void2Obj:Byte=4
	
	Field _rgchName:String
	Field _sType:Byte

'Getters & Setters
	Method Name:String()
		Return Self._rgchName
	End Method
	
'	Method Execute() Abstract

	Method GetType:Byte()
		Return Self._sType
	End Method
	
End Type

Type TVoidVoidPtr Extends TFPtr
	
	Field _Ptr()
	
'Constructors & Destructor
	Method New()
		Self._sType=TFptr.C_sType_VoidVoid
	End Method
	
'Interfacing
	Method Execute()
		Self._Ptr()
	End Method
	
End Type

Type TVoidObjPtr Extends TFPtr
	
	Field _Ptr(Obj:Object)
	
'Constructors & Destructor
	Method New()
		Self._sType=TFPtr.C_sType_VoidObj
	End Method
	
'Interfacing
	Method Execute(Obj:Object)
		Self._Ptr(Obj)
	End Method
	
End Type

Type TObjVoidPtr Extends TFPtr
	
	Field _Ptr:Object()
	
'Constructors & Destructor
	Method New()
		Self._sType=TFPtr.C_sType_ObjVoid
	End Method
	
'Interfacing
	Method Execute:Object()
		Return Self._Ptr()
	End Method
	
End Type

Type TObjObjPtr Extends TFPtr
	
	Field _Ptr:Object(Obj:Object)
	
'Constructors & Destructor
	Method New()
		Self._sType=TFPtr.C_sType_ObjObj
	End Method
	
'Interfacing
	Method Execute:Object(Obj:Object)
		Return Self._Ptr(Obj)
	End Method
	
End Type

Type TVoid2ObjPtr Extends TFPtr
	
	Field _Ptr(Obj:Object,Obj2:Object)
	
'Constructors & Destructor
	Method New()
		Self._sType=TFPtr.C_sType_Void2Obj
	End Method
	
'Interfacing
	Method Execute(Obj:Object,Obj2:Object)
		Self._Ptr(Obj,Obj2)
	End Method
	
End Type

SuperStrict

Local pPtr:Byte Ptr'Hält alle Typen von Funktionen

pPtr=Fnc1

Local FPtr1:Object(i:Int)=pPtr'Vor dem Aufruf muss gecastet werden
FPtr1(2)

pPtr=Fnc2

Local FPtr2(r:Float,p:Byte Ptr)=pPtr
FPtr2(3,Null)

Function Fnc1:Object(i:Int)
	Print "Fnc1: Object(Int)"
End Function
Function Fnc2(r:Float,p:Byte Ptr)
	Print "Fnc2: (Float,Byte Ptr)"
End Function

SuperStrict

Local pPtr:Byte Ptr'Hält alle Typen von Funktionen

pPtr=Fnc1

Local FPtr1:Object(i:Int)=pPtr'Vor dem Aufruf muss gecastet werden
FPtr1(2)

pPtr=Fnc2

'Anstatt einen korrekten Funktionspointer zu erstellen und zuzuweisen, weisen wir dem alten Pointer eine Funktion zu, die andere Parameter und einen anderen Rückgabewert besitzt. BlitzMax beschwert sich nicht. Aufrufen können wir die Funktion auch, allerdings wird es dann mit den Parametern lustig (in diesem Beispiel beschwert sich BM darüber, dass der Byte Ptr auf 'Null' verweist und damit nicht anzeigbar ist. Kommentieren wir in der betreffenden Zeile alles nach dem ersten Plus (einschließlich) aus, dann ergibt das auch einen lustigen Wert.) Wie gesagt, man muss aufpassen, BM frisst die Zuweisung und den Aufruf, allerdings werden die Parameterwerte anders, da sich die Variablentypen unterscheiden.
FPtr1=pPtr
FPtr1(1)

Function Fnc1:Object(i:Int)
	Print "Fnc1: Object(Int)"
End Function
Function Fnc2(r:Float,p:Byte Ptr)
	Print "Fnc2: (Float,Byte Ptr)"
	Print r+";"+p[0]
End Function