Graphics 800, 600, 32, 3
warten = CreateTimer(2)
sende_stream = CreateUDPStream(8001)
empfangs_stream = CreateUDPStream(8000)

send_msg$ = Input("Gib deine Nachricht ein: ")
send_ip_x$ = Input("Partner-IP: ")
send_ip = INT_IP(send_ip_x$)
Print send_ip

Repeat
   ip = RecvUDPMsg(empfangs_stream)
   If ip <> 0 Then
      Color 0, 255, 0
      Print ReadLine(empfangs_stream)
   Else
      Color 255, 0, 0
      Print "Keine Nachricht emfpangen!"
   EndIf
   WriteLine(sende_stream, send_msg$ + MilliSecs())
   SendUDPMsg sende_stream, send_ip
   
   If KeyHit(1) Then End
   WaitTimer(warten)
Forever

Function INT_IP(IP$)
   a1 = Int(Left(IP$, Instr(IP$, ".") - 1)) : IP$ = Right(IP$, Len(IP$) - Instr(IP$, "."))
   a2 = Int(Left(IP$, Instr(IP$, ".") - 1)) : IP$ = Right(IP$, Len(IP$) - Instr(IP$, "."))
   a3 = Int(Left(IP$, Instr(IP$, ".") - 1)) : IP$ = Right(IP$, Len(IP$) - Instr(IP$, "."))
   a4 = Int(IP$)
   Return (a1 Shl 24) + (a2 Shl 16) + (a3 Shl 8 ) + a4
End Function

Graphics 400, 300, 0, 2
SetBuffer BackBuffer()
Global TIMER = CreateTimer(30)

; IP und Port des Gegenübers
Global partnerIp, partnerPort

Type TMessage
   Field txt$
   Field col
End Type

Const STATE_SETUP = 0
Const STATE_JOIN = 1
Const STATE_GAME = 2
Global state = STATE_SETUP

Global Stream
Global inputText$, inputTextTemp$

; Hauptschleife
While Not KeyDown(1)
   Select state
   Case STATE_SETUP
      Setup
   Case STATE_JOIN
      Join
   Case STATE_GAME
      Game
   End Select
   
   FlushKeys()
   Flip 0
   WaitTimer TIMER
   Cls
Wend
End

Function Setup()
   If KeyHit(2)
      ; Server erstellen
      Stream = CreateUDPStream(9000)   ; fixer Port
      Message("Server erstellt", $AAAAAA)
      state = STATE_GAME
   ElseIf KeyHit(3)
      state = STATE_JOIN
   EndIf
   
   Text 0,0, "1: Server"
   Text 0,20, "2: Client"
End Function

Function Join()
   If Input()
      ; lokalen Stream erstellen
      Stream = CreateUDPStream()   ; variabler Port
      ; Serververbindung aufbauen
      partnerIp = StrToIntIP(inputText)   ; IP und
      partnerPort = 9000               ; Port des Servers sind bekannt
      ; Anmelden
      WriteByte Stream, $00
      SendUDPMsg Stream, partnerIp,partnerPort
      Message("Verbindungsaufbau", $AAAAAA)
      state = STATE_GAME
   EndIf
   
   Text 0,0, "IP des Servers eingeben:"
   Text 0,20, inputTextTemp
End Function

Function Game()
   Local ip = RecvUDPMsg(Stream)
   If ip
      Local msgType = ReadByte(Stream)
      Select msgType
      ; Verbindungsanfrage
      Case $00
         ; erst hier erfährt der Server IP und Port des Clienten
         partnerIp = ip
         partnerPort = UDPMsgPort(Stream)
         WriteByte Stream, $01
         SendUDPMsg Stream, partnerIp, partnerPort
         Message("Client verbunden", $AAAAAA)
      ; Verbindungsaufbau
      Case $01
         Message("Verbindung aufgebaut", $AAAAAA)
      ; Nachricht
      Case $10
         Message(ReadString(Stream), $00FF00)
      End Select
   EndIf
   
   If Input()
      Message(inputText, $0080FF)
      WriteByte(Stream,$10)
      WriteString(Stream,inputText)
      SendUDPMsg Stream, partnerIp, partnerPort
   EndIf
   
   DrawMessages
   
   Color 255,255,255
   Text 0, 260, "Nachricht:"
   Text 0, 280, inputTextTemp
End Function

; leicht erweiterte Inputfunktion
Function Input()
   Local char = GetKey()
   If char = 8
      If Len(inputTextTemp)>1
         inputTextTemp = Left(inputTextTemp, Len(inputTextTemp)-1)
      Else
         inputTextTemp=""
      EndIf
   ElseIf char>31
      inputTextTemp = inputTextTemp +Chr(char)
   ElseIf char=13
      inputText = inputTextTemp
      inputTextTemp = ""
      Return True
   EndIf
End Function

Function Message(pMessage$, pColor)
   Local msg.TMessage = New TMessage
   msg\txt = pMessage
   msg\col = pColor
End Function

Function DrawMessages()
   Local y = 240
   Local msg.TMessage = Last TMessage
   Repeat
      Color 0,0,msg\col
      Text 0,y, msg\txt
      If y < 0
         Delete msg
      EndIf
      y = y -20
      msg = Before msg
   Until msg = Null
End Function

Function StrToIntIP(pIP$)
   Local b1 = Int(Left(pIP$,Instr(pIP$,".")-1)):pIP$=Right(pIP$,Len(pIP$)-Instr(pIP$,"."))
   Local b2 = Int(Left(pIP$,Instr(pIP$,".")-1)):pIP$=Right(pIP$,Len(pIP$)-Instr(pIP$,"."))
   Local b3 = Int(Left(pIP$,Instr(pIP$,".")-1)):pIP$=Right(pIP$,Len(pIP$)-Instr(pIP$,"."))
   Local b4 = Int(pIP$)
   Return (b1 Shl 24) + (b2 Shl 16) + (b3 Shl 8 ) +b4
End Function