SuperStrict

'Test Gegner erstellen
Tcreatehook.Create("defaultenemy")
Tcreatehook.Create("enemy2")

'und auf Funktion prüfen
Tworkflowhook.allwork()
Tworkflowhook.allrender()



rem
	Ankerpunkt für die create Funktion
endrem
Type Tcreatehook
	'diese liste enthält alle createhooks mit Name und funktionspointer
	Global list:TList = CreateList()

	'Name und funktionspointer
	Field _name:String
	Field _create:Int()
	
	'erstellt ein neues createhook -> speichert den Namen und den funktionspointer des Gegnertypen -> speichert diesen in der globalen Liste
	Function register(myname:String, create_x:Int())
		Local re:Tcreatehook = New Tcreatehook
		
		re._name = myname
		re._create = create_x
		
		re.list.AddLast(re)
	End Function
	
	'wenn man diese Funktion aufruft wird der Name des Gegnertypen in der liste gesucht und bei Fund wird die create funktion für Gegnertypen aktiviert
	Function Create(name:String)
		For Local re:Tcreatehook = EachIn list
			If re._name = name Then re._create()
		Next
	End Function

End Type


rem
	Ankerpunkt für die Routine aufgaben wie das neu berechnen der Bewegung und das rendern der Gegner
endrem
Type Tworkflowhook
	'diese liste enthält alle Gegner die aktiv im Spiel sind
	Global list:TList = CreateList()
	
	'Halter für den einzelnen Gegner (auch der extendet Gegner)
	Field _enemy:Trootenemy
	
	'erstellt ein neues workflowhook -> wandelt alle Gegnertypen in rootenemy um (auch die extendet Gegner) -> speichert diese in die globale Gegner liste
	Function register:Tworkflowhook(obj:Object)
		Local nm:Tworkflowhook = New Tworkflowhook
		
		nm._enemy = Trootenemy(obj)
		
		list.AddLast(nm)
		Return nm
	End Function
	
	'Methode um Gegner wieder aus dem Spiel zu entfernen
	Method unregister()
		list.Remove(Self)
	End Method
	
	'alle Gegner durchgehen und die methode work() aufrufen
	Function allwork()
		For Local mm:Tworkflowhook = EachIn list
			mm._enemy.work()
		Next
	End Function
	
	'alle Gegner durchgehen und die methode render() aufrufen
	Function allrender()
		For Local mm:Tworkflowhook = EachIn list
			mm._enemy.render()
		Next
	End Function
	
End Type

rem
	Der Standartgegner mit seinen Funktionen und Methoden
endrem
Type Trootenemy
	'den Gegner mit Namen und create Funktion bei createhook registrieren, die globale "dummydata" ist nur dazu da die register Funktion auszuführen
	Global dummydata:Byte = Tcreatehook.register("defaultenemy", Trootenemy.Create)
	'wird ein neuer Gegner erstellt registriert er sich automatisch im workflowhook, die variable myhook besitzt die Methode unregister zum entfernen aus dem workflowhook
	'diese Zeile muss bei neuen Gegnertypen nicht kopiert werden
	Field myhook:Tworkflowhook = Tworkflowhook.register(Self)
	
	'Beispiel fields für Tests
	Field name:String
	Field x:Int
	Field image:Int

	'einen neuen Gegner erstellen und werte zuweisen
	Function Create()
		Local newenemy:Trootenemy = New Trootenemy
		
		newenemy.image = 1234
		newenemy.name = "defaultenemy"
		
		Print "defaultenemy" + ": " + "create" + " is called"
	End Function
	
	'abarbeiten der Bewegung und bei zutreffender Bedingung den Gegner löschen
	Method work()
		x:+1
		If x > 10 Then myhook.unregister()
		Print name + ": " + "work" + " is called"
	End Method

	'ausgeben der Bewegung
	Method render()
		Print name + ": " + "render" + " is called"
		Print name + ": " + "moved to " + x
		Print name + ": " + "uses picture " + image
	End Method
End Type

rem
	Ein neuer Gegnertyp
endrem
Type Tenemy2 Extends Trootenemy '<- BEACHTEN!
	'ein neuer Gegnertyp braucht mindestens Tcreatehook.register und eine neue create Funktion (damit auch die richtigen Types erstellt werden)
	'zu beachten ist das man nicht versuchen sollte Globals zu überschreiben da sonst die Globals aus Trootenemy verwendet werden.
	
	'den Gegner mit Namen und create Funktion bei createhook registrieren, die globale "dummydata" ist nur dazu da die register Funktion auszuführen
	Global dummydata:Byte = Tcreatehook.register("enemy2", Tenemy2.Create)
	
	'einen neuen Gegner erstellen und werte zuweisen
	Function Create()
		Local newenemy:Tenemy2 = New Tenemy2
		
		newenemy.image = 9876
		newenemy.name = "enemy2"
		
		Print "enemy2" + ": " + "create" + " is called"
	End Function
	
	
	'dieser Gegner besitzt nun als Beispiel ein weiteres Field
	Field boost:Int = 2
	
	'und eine modifizierte work Methode
	Method work()
		x:+1 + boost
		If x > 10 Then myhook.unregister()
		Print name + ": " + "work" + " is called"
	End Method
	
	'zum rendern wird die Methode aus Trootenemy verwendet.

End Type

Type Tenemy3 Extends Trootenemy
	Global dummydata:Byte = Tcreatehook.register("enemy3", Tenemy3.Create)
	Function Create()
		Local newenemy:Tenemy3 = New Tenemy3
		
		newenemy.image = 5555
		newenemy.name = "enemy3"
		
		Print "enemy3" + ": " + "create" + " is called"
	End Function
End Type

Type TCharacterKind
  Global list:TList = New TList
  Method New()
    Self.list.addLast Self
  End Method

  Field moveSpeed%, lookAngle%, lookRange%
  Field image:TImage
  'Alles was man braucht als Funktionspointer:
  Field Draw(character:TCharacter)
  Field Load:TCharacter(stream:TStream)
  Field Save(stream:TStream, character:TCharacter)
End Type

Type TCharacter
  Field kind:TCharacterKind, data:Object
  Field x%, y%, dir%
  Field items:TList = New TList
  Function Load:TCharacter(stream:TStream)
    Local kind:TCharacterKind = TCharacterKind(TCharacterKind.list.valueAtIndex(ReadInt(stream)))
    Return kind.Load(stream)
  End Function
  Method Save(stream:TStream)
    Local index%
    For Local kind:TCharacterKind = EachIn Self.kind.list
      If kind = Self.kind Then Exit
      index :+ 1
    Next
    WriteInt stream, index
    Self.kind.Save stream, Self
  End Method
End Type

Private
Global character:TCharacterKind = New TCharacterKind
character.image = LoadImage("xyz.ext")
character.moveSpeed = 2
character.lookAngle = 90
character.loogRange = 50
Function Draw(ch:TCharacter)
  SetRotation ch.dir
  DrawImage character.image, ch.x, ch.y
End Function
Function DoLoad:TCharacter(stream:TStream)
  '...
End Function
Function Save(stream:TStream, ch:TCharacter)
 '...
End Function
character.Draw = Draw
character.Load = DoLoad
character.Save = Save
Public
Global myCharacter:TCharacterKind = character

character.kind.draw character

character.draw