SuperStrict

' Bestimmen, den OpenGL treiber zu nutzen:
SetGraphicsDriver(GLMax2DDriver())

' Graphics fenster initialisieren:
Graphics(800, 600)

' Test bild anlegen (wir brauchen eine Pixmap, um sie einfacher als Textur zu verwenden :) )
Local sourceBild:TPixmap = CreatePixmap(50, 50, 6)

sourceBild.ClearPixels($ff000000) '-> schwarz

For Local x:Int = 0 Until 50 Step 2
For Local y:Int = 0 Until 50 Step 2
	sourceBild.WritePixel(x, y, $ffff0000) ' nur zu testzwecken: Rote farbe einfügen.
Next
Next

' Nun zur eigentlichen Textur:
Global testTextur:Int = GLTexFromPixmap(sourceBild) ' -> Anmerkung: Wir erhalten einen integer-index unserer textur!

Global bild:TImage = LoadImage(sourceBild) 'ein kleiner beweis, das normale blitzmax befehle noch funzen =)

' hilfsvar zum umschalten:
Local toggle:Int = 0

While Not KeyHit(KEY_ESCAPE)
	Cls
	
	'Umschalten des "Toggles":
	If KeyHit(KEY_ENTER) Then toggle = 1 - toggle
	
	
	If toggle = 0 Then 'Toggle fall 1: Normales DrawImage()
		DrawImage(bild, 50, 50)
	Else 'Toggle fall 2: OpenGL direkt.
	
	
	'	glEnable(GL_TEXTURE_2D) ' wir müssen einen 'state' aktivieren: GL_TEXTURE_2D - sonst können wir mit OGL befehlen keine Texturen zeichnen!
		'Anmerkung: Anscheinend aktiviert der OGL treiber von Blitzmax automatisch diesen state. Ich lasse ihn zur sauberkeit mal drinnen, aber auskommentiert.
		
		
		glBindTexture(GL_TEXTURE_2D, testTextur) ' hier brauchen wir die textur (der integer-index) -> Textur ist gebunden, wir können sie verwenden. 
		
		glBegin(GL_TRIANGLES) ' Triangle (Polygon) zeichnen,
			
			glTexCoord2f(0.0, 0.0) ' U/V koordinaten vom ersten vertex
			glVertex2i(50, 50) ' X-Y koordinate auf dem Bildschirm (erster vertex)
			
			glTexCoord2f(1.0, 0.0) ' U/V koordinaten vom zweiten vertex
			glVertex2i(50 + sourceBild.width, 50) ' X-Y koordinate auf dem Bildschirm (zweiter vertex)
			
			glTexCoord2f(0.5, 1.0) ' U/V koordinate vom dritten vertexe
			glVertex2i(50 + (sourceBild.width / 2), 50 + sourceBild.height) 'X-Y koordinate auf dem Bildschirm (dritter vertex)
			
		glEnd() 'Wichtig! auf jedes glBegin muss ein glEnd folgen, sonst gibts ein unkontrolliertes verhalten mit den grafiken.
		
		'und weil wir sauber sind: State wieder deaktivieren.
	'	glDisable(GL_TEXTURE_2D)
	End If

	Flip 1
Wend

'Letzter schritt: Aufräumen. Texturplatz wieder freigeben, nur zur sicherheit :)
glDeleteTextures(1, testTextur) ' 1 heißt 'eine' texutr löschen, ausgehend TEXTUR-INDEX (testTextur also.)

If Driver.islost Return