[GELÖST] Bunte Lichter - Mischen und anständig darstellen?

Übersicht BlitzMax, BlitzMax NG Allgemein

Neue Antwort erstellen

M0rgenstern

Betreff: [GELÖST] Bunte Lichter - Mischen und anständig darstellen?

 BeitragSo, Apr 01, 2012 23:58
Antworten mit Zitat
Benutzer-Profile anzeigen
Hallo Leute.
Ich bin gerade dabei den ganzen Code für meine 2D-Lichter und Schatten schön zu schreiben.
Dabei habe ich auch eine Erweiterung eingeführt: Bunte Lichter.
Leider funktioniert das nicht so ganz, wie es soll.
Zum einen werden meine blauen Lichter rot und zum anderen vermischen sich die Farben nicht wie gedacht.
Ansätze zum Mischen der Farben habe ich dort gefunden: https://www.blitzforum.de/foru...1931#41931

Im Prinzip mache ich es genauso. Nur, dass ich nicht für jedes Licht die Pixel überprüfe, sondern für jeden Pixel alle Lichter.
Mein Code sieht demnach folgendermaßen aus (der wichtige Ausschnitt der Funktion. Initialisierung der Pixmap lasse ich einfach hier weg):
BlitzMax: [AUSKLAPPEN] 
'Alle Pixel durchgehen
		For Local iX:Int = 0 Until tpPixmap.width
			For Local iY:Int = 0 Until tpPixmap.height
				Local iARGB:Int = ((128 Shl 24) | (0 Shl 16) | (0 Shl 8) | 0)
				
				iARGB = tpPixmap.ReadPixel(iX, iY) 'Pixel auslesen
					
                                'RGB-Farbe aus den Pixelinformationen erstellen.
				Local targbColor:TColorARGB = TColorARGB.ARGBToColor(iArgb)
                                'RGB_Farbe zu HSV umwandeln.
				Local tchsvColor:TColorHSV = TColorHSV.ColorARGBToColorHSV(targbColor)
						
                                'fAmbienceBrightness ist ein Wert zwischen 0.0 und 1.0, der angibt, 
                                'wie dunkel es an Stellen ohne Licht ist.
				Local fRatio:Float = fAmbienceBrightness
				
                                'Farbwerte zwischenspeichern.
				Local OldR:Int = targbColor.Red(), OldG:Int = targbColor.Green(), OldB:Int = targbColor.Blue()
				
                                'Alle Lichter durchgehen.
				For Local li:TLight = EachIn tlAllLights
					Local fLightRatio:Float 'Lichtstärke (zwischen 0.0 und 1.0)
                                        'Distanz zwischen der Lichtquelle und dem Pixel
					Local fDistance:Float = Pythagoras(ix, iy, li.Position().X(), li.Position().Y())
                                        'Stärke des Lichts an der Stelle
					Local LightStrength:Float = li.Range() * ((li.Range() / fDistance) * 10)
                                        'Quadratische Distanz
					Local fDistQuad:Float = (iX - li.Position().X()) * (iX - li.Position().X()) + (iY - li.Position().Y()) * (iY - li.Position().Y()) 
					
					If(li.MapAt(iX, iY) = 0) Then 'Wenn der Pixel erreichbar ist
                                                'Stärke des Lichts berechnen.
						fLightRatio = Min(li.Brightness(), LightStrength / fDistQuad) 
                                                'Lichtstärke darf nicht über 1.0 liegen.
						fLightRatio = Min(1.0, fLightRatio)
  
                                                'Farbwerte zwischenspeichern
						Local r:Int = li.Tinct().Red() * (fLightRatio)'Float((li.Range() - Sqr(fDistQuad)) / Float(li.Range()))
     					        Local g:Int = li.Tinct().Green() * (fLightRatio)'Float((li.Range() - Sqr(fDistQuad)) / Float(li.Range()))
      					        Local b:Int = li.Tinct().Blue() * (fLightRatio)'Float((li.Range() - Sqr(fDistQuad)) / Float(li.Range()))
						
                                                'Werte müssen größer 0 sein.
                                                r = Max(0, r)
                                                g = Max(0, g)
                                                b = Max(0, b)
						
                                                'Farbwerte zu den bisherigen Werten addieren.
                                                OldR = r + OldR
                                                OldG = g + OldG
                                                OldB = b + OldB
						
                                                'Die Werte dürfen nicht größer als 255 sein.
                                                OldR = Min(255, OldR)
                                                OldG = Min(255, OldG)
						OldB = Min(255, OldB)
					Else
                                                'Kann der Pixel nicht von dem Licht erreicht werden, so wird er auch nicht beleuchtet.
						fLightRatio = 0.0
					EndIf
					
                                        'Heliigkeit für den Pixel addieren.
					fRatio = fRatio + fLightRatio
				Next
				
                                'alte Werte beachten
				fRatio = fRatio + tchsvColor.BrightnessValue() 

                                'Zu grosse bzw. zu kleine Werte nicht beachten.
				fRatio = Min(fRatio, 1.0) 	
				fRatio = Max(fRatio, 0.0)
								
                                'Helligkeit der Farbe einstellen
				tchsvColor.SetBrightnessValue(fRatio)
							
                                'HSV zu RGB umwandeln.
				targbColor = TColorARGB.ColorHSVToColorARGB(tchsvColor)
				
				'Neu berechnete Farbe einsetzen.			
				targbColor.SetRed(OldR)
				targbColor.SetGreen(OldG)
				targbColor.SetBlue(OldB)
				
                                'Farbe umwandeln und Helligkeit setzen (nur zur Sicherheit)
				Local tchsvNewColor:TColorHSV = TColorHSV.ColorARGBToColorHSV(targbColor)
				tchsvNewColor.SetBrightnessValue(tchsvColor.BrightnessValue())
				
                                'Farbe in RGB umwandeln
				targbColor = TColorARGB.ColorHSVToColorARGB(tchsvNewColor)
				
                                'In Pixmap schreiben
				tpPixmap.WritePixel(iX, iY, targbColor.ConvertToARGB())
			Next
		Next


Ich war der Meinung, dass das so funktionieren könnte.
Aber dieser Screenshot beweist etwas anderes:
user posted image

Dort kann man die angesprochenen Probleme gut erkennen.
Dort, wo die Lichter noch relativ stark sind, funktioniert das Mischen noch relativ gut (unten im Bild, wo grün und Blau aufeinander treffen).
An anderen Stellen dafür umso schlechter (rechts im Bild, das grün und das rot).
Diese schlechten Übergänge oben oder in der Mitte (dort wo das Licht so fetzenförmig ineinander greift) nehem ich bei dem Mischen mal aus, da hier auch die Farben falsch sind. Wie man an der Lichtquelle sieht, sollte das Licht eigentlich blau sein.
Aber leider wird es aus irgendeinem Grund ab einer bestimmten Entfernung einfach Rot.

Weiß vielleicht jemand, was ich falsch mache? Oder kann mir jemand sagen, wie ich es eher machen sollte?
Weiß echt keinen Rat mehr. Habe auch schon versucht, die Farbwerte durch die Anzahl der genutzten Lichter zu teilen. Aber das Ergebnis ist nicht besser.

Wäre wirklich super, wenn mir jemand weiterhelfen könnte.

Lg, M0rgenstern
  • Zuletzt bearbeitet von M0rgenstern am Di, Apr 03, 2012 10:55, insgesamt einmal bearbeitet

blackgecko

 BeitragMo, Apr 02, 2012 0:36
Antworten mit Zitat
Benutzer-Profile anzeigen
Meine erste Vermutung:
Code: [AUSKLAPPEN]
'Farbwerte zwischenspeichern.
Local OldR:Int = targbColor.Red(), OldG:Int = targbColor.Green(), OldB:Int = targbColor.Blue()

Du setzt bei jedem Render-Vorgang die aktuelle Pixelfarbe als Startfarbe. Wenn du jetzt ein paar mal hintereinander renderst, gibts möglicherweise seltsame Vermischungen, weil die eben gerade erst errechnete Farbe immer wieder hinzu addiert wird.
Versuch also mal OldR/G/B mit 0 zu initialisieren.
So long and thanks for all the fish.
Fedora 17 | Windows 7 || BlitzPlus | BlitzMax
Rechtschreibflame GO!!! Deppenapostroph | SeidSeit | Deppenakzent | DassDas | Deppenleerzeichen | TodTot | enzigste.info - Ja, ich sammel die.

M0rgenstern

 BeitragMo, Apr 02, 2012 10:06
Antworten mit Zitat
Benutzer-Profile anzeigen
Hey blackgecko:
Im Prinzip ist targbColor.Red() immer 0.
Ich render das ganze nämlich nur einmal und schreibe es dann final auf die Pixmap. Und die Pixmap initialisiere ich komplett in schwarz. Und jeder Pixel wird ja nur einmal bearbeitet.
Aber ich habe es jetzt einfach mal direkt mit 0 als Startfarbe für Oldr,OldG und OldB versucht: Das Ergebnis ist das gleiche.

Lg, M0rgenstern

ZaP

Betreff: Re: Bunte Lichter - Mischen und anständig darstellen?

 BeitragMo, Apr 02, 2012 10:41
Antworten mit Zitat
Benutzer-Profile anzeigen
M0rgenstern hat Folgendes geschrieben:

BlitzMax: [AUSKLAPPEN] 

                                'Farbe in RGB umwandeln
				targbColor = TColorARGB.ColorHSVToColorARGB(tchsvNewColor)
				
                                'In Pixmap schreiben
				tpPixmap.WritePixel(iX, iY, targbColor.ConvertToARGB())
			Next
		Next



Liegt hier vielleicht der Fehler? Das sieht für mich aus, als wandelst Du dort HSV nach RGB um, und dann beim Pixmap schreiben nochmal, aber targbColor ist doch zu dem Zeitpunkt schon im RGB Format, oder?
Starfare: Worklog, Website (download)

M0rgenstern

 BeitragMo, Apr 02, 2012 11:00
Antworten mit Zitat
Benutzer-Profile anzeigen
Hey ZaP.
Das sieht nur so aus^^

Kurze Erklärung hierzu:
BlitzMax: [AUSKLAPPEN] 
targbColor = TColorARGB.ColorHSVToColorARGB(tchsvNewColor)

targbColor hat den Typ TColorARGB. Mit der Zeile dort wird vom HSV-System in das (A)RGB-System umgewandelt.
Die Klasse habe ich mir geschrieben, um Farben und Farbinformationen besser zu nutzen. Dadurch muss ich einem Objekt nicht jeweils für rot, grün und blau eine eigene Variable geben (oder ein Array) sondern nur eine Variable dieses Typs. Dann kann ich mit targbColor.Red() auf den Rotanteil zugreifen. Das gleiche gilt dann für Alpha, Blau und Grün.

BlitzMax: [AUSKLAPPEN] 
tpPixmap.WritePixel(iX, iY, targbColor.ConvertToARGB())

Diese Zeile schreibt ja an entsprechender Stelle die Farbinformationen in die Pixmap.
Aber man kann der Pixmap ja nicht einfach einen Rot-Anteil, einen Grün-Anteil und einen Blau-Anteil geben, sondern muss diese ganzen Anteile zu einem 32-Bit Wert zusammenfassen. (Mit den Bitbefehlen, also shl)
Und genau das macht targbColor.ConvertToARGB(). Es rechnet die einzelnen Farbinformationen, die es beinhaltet, mit shl zu einem 32-Bit Wert um und gibt diesen Wert zurück. Ich konvertiere also nicht ins RGB-Format sondern berechne aus den Farbinformationen den 32-Bit Wert.

Lg, M0rgenstern

Edit:
Also, ich habe den Fehler jetzt prinzipiell gefunden.
Undzwar liegt er dort:
BlitzMax: [AUSKLAPPEN] 
 'Farbe umwandeln und Helligkeit setzen (nur zur Sicherheit)
				Local tchsvNewColor:TColorHSV = TColorHSV.ColorARGBToColorHSV(targbColor)
				tchsvNewColor.SetBrightnessValue(tchsvColor.BrightnessValue())
				
                                'Farbe in RGB umwandeln
				targbColor = TColorARGB.ColorHSVToColorARGB(tchsvNewColor)
				
                                'In Pixmap schreiben
				tpPixmap.WritePixel(iX, iY, targbColor.ConvertToARGB())

Durch das nochmalige umwandeln in HSV und das neue setzen des Helligkeitswertes wurde im Prinzip die Farbe komplett überschrieben. Das liegt ja an dem Algorithmus mit dem umgewandelt wird (http://de.wikipedia.org/wiki/H...RGB_in_HSV).

Wie gesagt. Das ganze funktioniert jetzt wie es soll. Leider gibt es ein Problem:
Wenn man eine Mindesthelligkeit einstellt, dann wird diese ja nicht beachtet, da ja dort, wo keine Lichter sind die Farbe auf (0,0,0) gesetzt wird.
Weiß jemand, wie ich das anders machen könnte? Ich müsste ja im Prinzip die Farbe direkt mit der Helligkeit verrechnen. Leider weiß ich nicht wie. Lg, M0rgenstern

Edit2:
Das Problem ist gelöst.
Ich habe einfach OldR/OldG/OldB mit folgenden Werten initalisiert:
BlitzMax: [AUSKLAPPEN] 
Local fRatio:Float = fAmbienceBrightness
				
				Local OldR:Int = fRatio * 255
				Local OldG:Int = fRatio * 255
				Local OldB:Int = fRatio * 255

Dadurch wird die Pixmap von Anfang an entsprechend aufgehellt, falls fAmbienceBrightness > 0.0 ist.

Das ganze sieht jetzt so aus:
user posted image

Auf dem Bild gibt es jetzt noch seltsame Farben. Das grau zum Beispiel. Aber das liegt daran, dass die Farbwen der Lichter zufällig bestimmt werden. Wenn man die Lichter in einem Editor setzt, dann ist das ja nochmal was anderes.

Lg, M0rgenstern

Neue Antwort erstellen


Übersicht BlitzMax, BlitzMax NG Allgemein

Nach Oben

Gehe zu:

Powered by phpBB © 2001 - 2006, phpBB Group