SuperStrict 

Const POINTS_VALUE:Int = 20


Type TLine
	Field pointx:Float[]
	Field pointy:Float[]
	Field points:Int 
	Field maxabs:Float 

	Method New( )
		points = POINTS_VALUE
		pointx = New Float[points]
		pointy = New Float[points]
	End Method

	Method Create:TLine( x:Float, y:Float, x2:Float, y2:Float )
		Local abx:Float = x2 - x
		Local aby:Float = y2 - y
		Local ab:Float = Sqr( abx*abx + aby*aby )
		Local abx_step:Float = abx / Float( points )
		Local aby_step:Float = aby / Float( points )
		Local ab_step:Float = Sqr( abx_step*abx_step + aby_step*aby_step )
		Local index:Int = 0		
		For Local i:Float = 0 To ab / ab_step
			pointx[index] = x + abx_step * i
			pointy[index] = y + aby_step * i
			index :+ 1
			If index >= points Then Exit
		Next 
		maxabs = ab_step
		Return Self 
	End Method 

	Method Draw( )
		For Local i:Int = 1 To points-1
			DrawLine( pointx[i-1], pointy[i-1], pointx[i], pointy[i] )
		Next 
	End Method
	
	Method DragPoint:Int( mx:Float, my:Float )
		Local n:Float = 99999999.9
		Local n_i:Int = -1
		For Local i:Int = 0 To points-1
			Local abx:Float = pointx[i] - mx
			Local aby:Float = pointy[i] - my
			Local ab:Float = Sqr( abx*abx + aby*aby )
			If ab < n Then 
				n_i = i
				n = ab
			EndIf
		Next 
		Return n_i
	End Method  

	Method SetPoint( index:Int, x:Float, y:Float, up:Byte=True )
		If index > 0 And index < points Then 
			pointx[index] = x
			pointy[index] = y
			If up Then Update( index )
		EndIf 
	End Method 
	
	Method GetPointX:Float( index:Int )
		If index > 0 And index < points Then Return pointx[index]
		Return 0
	End Method 
	Method GetPointY:Float( index:Int )
		If index > 0 And index < points Then Return pointy[index]
		Return 0
	End Method 

	Method Update( index:Int )
		Local i:Int
		For i = index To 0 Step -1
			Local x1:Float = GetPointX( i )
			Local y1:Float = GetPointY( i )
			Local x2:Float = GetPointX( i-1 )
			Local y2:Float = GetPointY( i-1 )
			Local abx:Float = x2 - x1
			Local aby:Float = y2 - y1
			Local ab:Float = Sqr( abx*abx + aby*aby )
			Local fak:Float = maxabs / ab
			SetPoint( i-1, x1 + abx * fak, y1 + aby * fak, False )
		Next 
		For I = index To points-1 Step 1
			Local x1:Float = GetPointX( i )
			Local y1:Float = GetPointY( i )
			Local x2:Float = GetPointX( i+1 )
			Local y2:Float = GetPointY( i+1 )
			Local abx:Float = x2 - x1
			Local aby:Float = y2 - y1
			Local ab:Float = Sqr( abx*abx + aby*aby )
			Local fak:Float = maxabs / ab
			SetPoint( i+1, x1 + abx * fak, y1 + aby * fak, False )
		Next 
	End Method
End Type



Graphics 800, 600
Local timer:TTimer = CreateTimer( 60 )
Local mHit:Byte, point:Int

Local line:TLine = (New TLine).Create( 400, 100, 400, 300 )


Repeat
	If MouseHit( 1 ) Then 
		point = line.DragPoint( MouseX(), MouseY() )
		If point > -1 Then 
			mHit = True
		EndIf
	EndIf
	If mHit = True Then 
		line.SetPoint( point, MouseX(), MouseY() )
		If Not MouseDown( 1 ) Then mHit = False
	EndIf 
	line.Draw( )	
	Flip 0
	Cls
	WaitTimer( timer )
Until KeyHit( KEY_ESCAPE ) Or AppTerminate( )
End