SuperStrict
Rem
	
	TTranslator
	i18n : i(nternationalisatio)n
	
	Nötige Module:
		Import brl.map
		Import brl.filesystem
		Import brl.linkedlist (debug)
endrem

Framework brl.standardio
Import brl.map
Import brl.linkedlist
Import brl.filesystem


'* Erstelle eine neue Instanz, die $<key>$ mit <value> ersetzt:
Global i18n:TTranslator = TTranslator.Create(["$", "$"])

'* Lade die deutschen keywords:
i18n.Add("i18n/de.txt", ["{", "}"])
Texte()
     
'* Vergiss die deutschen keywords
i18n.Clear()
'* Lade die englischen keywords:
i18n.Add("i18n/en.txt", ["{", "}"])
Texte()

?Debug
	'* Was passiert, wenn man die deutsche Übersetzung darüber lädt?
	i18n.Add("i18n/de.txt", ["{", "}"])
	'* Beide files wurden geladen...
	Print("~n".join(i18n.GetFilesLoaded()))
	'* Aber die Übersetzungstabelle sieht so aus:
	Print("~n".join(i18n.GetPairsLoaded()))
	Print()
?

Input(i18n.Do("$key$"))
End

Function Texte()
	'* Ersetze die in $ stehenden keywords und zeige das Ergebnis
	Print(i18n.Do("Jeder Key"))
	Print(i18n.Do("wie z.B. $Hello$"))
	Print(i18n.Do("wird einfach ersetzt!"))
	Print(i18n.Do("case sensitiv! => $HELLO$"))
	Print(i18n.Do("Also: $Fun$"))
	Print(i18n.Do("[$New$], [$End$]"))
	Print()
End Function

Type TTranslator
	Field Limit:String[]
	Field Data:TMap
	?Debug
		Field files:TList
	?
	
	'* Erstellt eine neue Instanz:
	Function Create:TTranslator(_limit:String[])
		Local t:TTranslator = New TTranslator
		t.Limit = _limit
		t.Data = New TMap
		?Debug
			t.files = New TList
		?
		Return t
	End Function
	
	'* Löscht das Wörterbuch 
	Method Clear()
		Self.Data.Clear()	
		?Debug
			Self.files.Clear()
		?
	End Method
	
	?Debug
	'* Debugausgabe von geladenen Übersetzungs files
	Method GetFilesLoaded:String[] ()
		Local arr:String[]
		For Local s:String = EachIn Self.files
			arr:+[s]
		Next
		Return arr
	End Method
	
	'* Debugausgabe von geladenen Key Value paaren
	Method GetPairsLoaded:String[] ()
		Local arr:String[]
		For Local s:String = EachIn Self.Data.Keys()
			arr:+[s + " => " + String(Self.Data.ValueForKey(s))]
		Next
		Return arr
	End Method
	?
	
	'* Füge ein neues file mit Übersetzungen hinzu, ein paar pro zeile, eingeschlossen in _limit
	Method Add(_file:String, _limit:String[])
		Local stream:TStream = OpenFile(_file)
		If Not(stream) Then RuntimeError("TTranslator Add : can't open file ~q" + _file + "~q")
		?Debug
			Self.files.AddLast(_file)
		?
		While Not(stream.Eof())
		
			Local pair:String[] = TTranslator.GetSubStrings(stream.ReadLine(), _limit[0], _limit[1])
			If pair.Length <> 2 Then Continue
			
			Self.Data.Insert(pair[0], pair[1])
				
		Wend
	End Method
	
	'* Ersetze in _source alle Keys (und delimiter) mit ihren Values 
	Method Do:String(_source:String)
		If _source.Find(Self.Limit[0]) <> - 1 Or _source.Find(Self.Limit[1]) <> - 1 Then
			Local parts:String[] = TTranslator.GetSubStrings(_source, Self.Limit[0], Self.Limit[1])
			For Local i:Int = 0 Until parts.Length
				If Self.Data.Contains(parts[i]) Then
					Local val:String = String(Self.Data.ValueForKey(parts[i]))
					_source = _source.Replace(Self.Limit[0] + parts[i] + Self.Limit[1], val)
				EndIf
			Next
		EndIf
		Return _source
	End Method
	
	'* Hilfsfunktion um substrings aus delimitern heraus zu bekommen
	Function GetSubStrings:String[] (_source:String, _start:String, _end:String = "")
		If _end = "" Then _end = _start
		Local out:String[], i:Int = 0
		
		Repeat
			Local pos1:Int = _source.Find(_start, i)
			Local pos2:Int = _source.Find(_end, pos1 + _start.Length)
			If pos1 = -1 Or pos2 = -1 Then Exit
			i = pos2 + _end.Length
			out:+[_source[pos1 + _start.Length..pos2]]
		Until i > _source.Length
		
		Return out
	End Function

End Type