Include "../ExampleShared.bb"

Type Cubes
   Field Cube
   Field Time
End Type

Global fpSpawnCubeAtRandom = 0
Function SpawnCubeAtRandom()
   If Not fpSpawnCubeAtRandom Then
      fpSpawnCubeAtRandom = BlitzPointer_GetFunctionPointer()
      Return 0
   EndIf
   Local Cube.Cubes = New Cubes
   Cube\Cube = CreateCube(Example_SceneRoot)
   Cube\Time = MilliSecs()
   PositionEntity Cube\Cube, Rnd(-100, 100), Rnd(-100, 100), Rnd(-100, 100)
End Function
SpawnCubeAtRandom()

Global fpSpawnCubeAtPosition = 0
Function SpawnCubeAtPosition%(X#, Y#, Z#)
   If Not fpSpawnCubeAtPosition Then
      fpSpawnCubeAtPosition = BlitzPointer_GetFunctionPointer()
      Return 0
   EndIf
   Local Cube.Cubes = New Cubes
   Cube\Cube = CreateCube(Example_SceneRoot)
   Cube\Time = MilliSecs()
   PositionEntity Cube\Cube, X, Y, Z
End Function
SpawnCubeAtPosition(0, 0, 0)

Local A% = 36
SteamAPI_Init()
ExampleInit()
While Not KeyHit(1)
   Local Cube.Cubes
   For Cube = Each Cubes
      Local OX#, OY#, OZ#, Prc#
      OX = EntityX(Cube\Cube, True)
      OY = EntityY(Cube\Cube, True)
      OZ = EntityZ(Cube\Cube, True)
      Prc = (MilliSecs() - Cube\Time) / 10000.0
      
      PositionEntity Cube\Cube, OX * (1.0 - Prc), OY * (1.0 - Prc), OZ * (1.0 - Prc), True
      If Prc > 1.0 Then
         FreeEntity Cube\Cube
         Delete Cube
      EndIf
   Next
   
   ExampleUpdate()
   
   Text   0, 0, "Keys:"
   Text   0,15, "  1  Native Call to SpawnCubeAtRandom:" + KeyDown(2)
   Text   0,30, "  2  Native Call to SpawnCubeAtPosition:" + KeyDown(3)
   Text   0,45, "  3  Pointer Call to SpawnCubeAtRandom:" + KeyDown(4)
   Text   0,60, "  4  Pointer Call to SpawnCubeAtPosition:" + KeyDown(5)
   Text   0,75, "Pointers:"
   Text   0,90, "  SpawnCubeAtRandom"
   Text   0,105, "  SpawnCubeAtPosition"
   Text 200,90, "0x" + Replace(RSet(Hex(fpSpawnCubeAtRandom), 8), " ", "0")
   Text 200,105, "0x" + Replace(RSet(Hex(fpSpawnCubeAtPosition), 8), " ", "0")
   
   If KeyDown(2) Then SpawnCubeAtRandom()
   If KeyDown(3) Then SpawnCubeAtPosition(EntityX(Example_Camera, True), EntityY(Example_Camera, True), EntityZ(Example_Camera, True))
   If KeyDown(4) Then BlitzPointer_CallFunctionV(fpSpawnCubeAtRandom)
   If KeyDown(5) Then BlitzPointer_CallFunctionVFFF(fpSpawnCubeAtPosition, EntityX(Example_Camera, True), EntityY(Example_Camera, True), EntityZ(Example_Camera, True))
   
   ExampleLoop()
Wend
SteamAPI_Shutdown()
End

; Now that we have learned how to use functions, let's go for something really
;  advanced - Callbacks! We can use these to practically fake a OOP language.

Include "Example_Shared.bb"
ExampleInit()

; Let's create a Type to hold our generic object that only contains callback and
;  a pointer to the type object. This allows us to have a generic interface that
;  takes BObject and whatever type-object the user wants and returns weether or
;  not the BObject should be destroyed.
Type BObject
   Field DataCallback
   Field DataValue%
End Type

; Our Update loop looks like this, there's not much to do - after all we have
;  the callbacks to do the dirty work for us.
Function BObjectUpdate()
   Local Obj.BObject
   For Obj.BObject = Each BObject
      ; Check if the Callback and Value is set.
      If Obj\DataCallback <> 0 And Obj\DataValue <> 0 Then
         ; Our Callback tells us when we need to dispose of an object.
         If BlitzPointer_CallFunctionIII(Obj\DataCallback, Int(Obj), Obj\DataValue)
            Delete Obj
         EndIf
      Else
         Delete Obj
      EndIf
   Next
End Function


Type BCube
   Field Entity
   Field PosX#, PosY#, PosZ#
   Field Time
End Type

; Our Callback for BCube - relatively simple.
Global fpBCubeCallback = 0
Function BCubeCallback%(Obj.BObject, Cube.BCube)
   If fpBCubeCallback = 0 Then
      fpBCubeCallback = BlitzPointer_GetFunctionPointer()
      Return
   EndIf
   If Obj = Null Or Cube = Null Then Return
   
   Local Prc# = 1.0 - ((MilliSecs() - Cube\Time) / 5000.0)
   ;Cube\PosX = Cube\PosX * (1 + Prc)
   ;Cube\PosY = Cube\PosY * (1 + Prc)
   ;Cube\PosZ = Cube\PosZ * (1 + Prc)
   PositionEntity Cube\Entity, Cube\PosX * (Prc) * Cos(Prc * 90), Cube\PosY * Prc * Cos(Prc * 720), Cube\PosZ * (Prc) * Cos(Prc * 90)
   
   If Prc < 0.0 Then
      FreeEntity Cube\Entity
      Delete Cube
      Return True
   EndIf
End Function
BCubeCallback(Null, Null)

Function BCubeCreate.BObject(X#, Y#, Z#)
   Local Obj.BObject = New BObject
   Obj\DataCallback = fpBCubeCallback
   Local Cube.BCube = New BCube
   Cube\Entity = CreateSphere(2)
   Cube\PosX = X
   Cube\PosY = Y
   Cube\PosZ = Z
   Cube\Time = MilliSecs()
   Obj\DataValue = Int(Cube)
   
   Return Obj
End Function

While Not KeyHit(1)
   BObjectUpdate()
   
   ExampleUpdate()
   
   ; Space to create objects.
   If KeyHit(57) Then
      Local X#, Y#
      Local tX#, tY#, tZ#
      
      Local Radius# = 50
      For Y = 0 To 90 Step 9
         tY = Sin(Y)
         
         For X = -180 To 180 Step 18
            tX = (Cos(X) * Cos(Y))
            tZ = (Sin(X) * Cos(Y))
            
            BCubeCreate(tX * Radius, tY * Radius, tZ * Radius)
         Next
      Next
   EndIf
   
   ExampleLoop()
Wend