Rem
     Autor: Marius Otto
     Datum: 23.08.2014
End Rem
Const WHEELDURCH:Double = 1			' Angabe in m

Type TGear
	Field Translation:Double
	
	Function Create:TGear(Translation:Double)
		Local ReturnMe:TGear = New TGear
		ReturnMe.Translation = Translation
		Return ReturnMe
	End Function
End Type

Type TGearBox
	Field Gears:TGear[]
	Field MomGear:Int			' -1 = R, 0 = N, Rest MomGear = Gang
	
	Function Create:TGearBox(Gears:TGear[])
		Local ReturnMe:TGearBox = New TGearBox
		ReturnMe.Gears = Gears
		ReturnMe.MomGear = 0
		Return ReturnMe
	End Function
	
	Method GetOutputValues:Float(MomRPM:Float, MomTorque:Double, OutRPM:Float Var, OutTorque:Float Var)
		If(MomGear < -1 Or MomGear > (Self.Gears.length - 2))
			OutRPM = 0
			OutTorque = 0
		Else
			OutRPM = MomRPM * Self.Gears[(MomGear + 1)].Translation
			
			If(Self.Gears[(MomGear + 1)].Translation <> 0)
				OutTorque = MomTorque / Self.Gears[(MomGear + 1)].Translation
			Else
				OutTorque = 0
			EndIf
		EndIf		
	End Method
	
	Method NextGear()
		If(Self.MomGear >= (Self.Gears.length - 2))
			Self.MomGear = (Self.Gears.length - 2)
		Else
			Self.MomGear = Self.MomGear + 1
		EndIf
	End Method
	
	Method PrevGear()
		If(Self.MomGear <= -1)
			Self.MomGear = -1
		Else
			Self.MomGear = Self.MomGear - 1
		EndIf
	End Method
	
	Method SetGear(Gear:Int)
		If(Gear >= -1 And Gear <= (Self.Gears.length - 2))
			Self.MomGear = Gear
		EndIf
	End Method
End Type

Type TEngine
	Field MaxRPM:Float
	Field HorsePower:Float
	
	Function Create:TEngine(MaxRPM:Float, HorsePower:Float)
		Local ReturnMe:TEngine = New TEngine
		ReturnMe.MaxRPM = MaxRPM
		ReturnMe.HorsePower = HorsePower
		Return ReturnMe
	End Function
	
	Method GetTorque:Double(MomRPM:Double)
		If(MomRPM > MaxRPM Or MomRPM <= 0)
			Return 0
		Else
			MomRPM = MomRPM - 1
			Return (Self.HorsePower * 100) / (2 * Pi * ((MaxRPM - MomRPM) / 60))
		EndIf
	End Method
End Type

Type TVehicleDrive
	Field Engine:TEngine
	Field GearBox:TGearBox
	Field MassKg:Float
	
	Function Create:TVehicleDrive(Engine:TEngine, GearBox:TGearBox, MassKg:Float)
		Local ReturnMe:TVehicleDrive = New TVehicleDrive
		ReturnMe.Engine = Engine
		ReturnMe.GearBox = GearBox
		ReturnMe.MassKg = MassKg
		Return ReturnMe
	End Function
	
	Method GetSpeed:Float(MomRPM:Float, Gear:Int, MomSpeed:Float = 0)
		If(MomRPM >= 0 And MomRPM <= (Self.Engine.MaxRPM) And Gear >= -1 And Gear <= (Self.GearBox.Gears.length - 2))
			Local ForceNeeded:Float
			If(MomSpeed <> 0)
				If(Gear = -1)
					ForceNeeded = Self.MassKg / ((MomSpeed * 5) ^ 2)
				Else
					ForceNeeded = Self.MassKg / ((MomSpeed * 5) ^ 2)
				EndIf
			Else
				ForceNeeded = Self.MassKg
			EndIf
			
			Local TorqueGearBox:Float
			Local RPMGearBox:Float
			Self.GearBox.SetGear(Gear)
			Self.GearBox.GetOutputValues(MomRPM, Self.Engine.GetTorque(MomRPM), RPMGearBox, TorqueGearBox)
			
			Local ForceMom:Float = TorqueGearBox * (2 * Pi * (WHEELDURCH / 2))

			If(Self.GearBox.MomGear = -1)
				ForceMom = ForceMom * (-1)
			EndIf
			
			If(ForceMom < ForceNeeded And ForceMom <> 0)	' Abgebockt?
				Return -1
			EndIf
			
			' Wenn nicht, ist RPMGearBox die Umdrehungszahl der Reifen pro Minute
			Local MomSpeedRet:Float = (Pi * WHEELDURCH) * RPMGearBox		' m / min
			MomSpeedRet = MomSpeedRet / 60 						' m / s
			Return MomSpeedRet
		Else
			Return -1
		EndIf
	End Method
End Type

' ### TEST ###
Local Gears:TGear[] = [TGear.Create(-0.025), TGear.Create(0), TGear.Create(0.025), TGear.Create(0.05), TGear.Create(0.075), TGear.Create(0.1)]
Local TestVehicle:TVehicleDrive = TVehicleDrive.Create(TEngine.Create(4000, 250), TGearBox.Create(Gears), 6000)
Local LastSpeed:Float = 0

For Local x:Int = -1 To (Gears.length - 2) Step 1
	For Local y:Int = 500 To TestVehicle.Engine.MaxRPM Step 500
		Print("Gang: " + x + "; RPM: " + y + "; MomSpeed: " + TestVehicle.GetSpeed(y, x, LastSpeed) + "m/s (" + (TestVehicle.GetSpeed(y, x, LastSpeed) * 3.6) + "km/h)")
		If(TestVehicle.GetSpeed(y, x, LastSpeed) > 0)
			LastSpeed = TestVehicle.GetSpeed(y, x, LastSpeed)
		EndIf
	Next	
	Print("")
Next

End