SuperStrict

Const RHOMBUS_SIZE:Int	= 23
Const RHOMBUS_POSX:Int	= 100
Const RHOMBUS_POSY:Int	= 100

Graphics(400,300)
Global timer:TTimer = CreateTimer(20)

While Not AppTerminate()
	Cls
	Local mx:Int = MouseX()
	Local my:Int = MouseY()
	If PointInRhombus(mx,my, RHOMBUS_POSX,RHOMBUS_POSY, RHOMBUS_SIZE) Then
		SetColor 0,255,0
	Else
		SetColor 255,0,0
	End If
	For Local y:Int = 0 Until RHOMBUS_SIZE
		For Local x:Int = 0 Until RHOMBUS_SIZE
			' fake mouse coordinates
			Local fmx:Int = x +RHOMBUS_POSX
			Local fmy:Int = y +RHOMBUS_POSY
			If PointInRhombus(fmx,fmy, RHOMBUS_POSX,RHOMBUS_POSY, RHOMBUS_SIZE) Then
				Plot(fmx, fmy)
			End If
		Next
	Next
	
	WaitTimer(timer)
	Flip 0
Wend

Rem
checks if point (pPx, pPy) is in rhombus at (pX, pY) to (pX +pSize, pY +pSize)
end rem
Function PointInRhombus:Int(pPx:Int, pPy:Int, pX:Int, pY:Int, pSize:Int)
	' project point to rhombus start
	pPx :- pX
	pPy :- pY
	' out of bounding box
	If pPx < 0 Or pPx > pSize Then
		Return False
	End If
	' out of bounding box
	If pPy < 0 Or pPy > pSize Then
		Return False
	End If
	' cut edges ...
	' y diff from top edge
	Local dy:Int = pPy
	' how much to cut (from left and right)
	Local cx:Int = Abs(pSize/2 -dy)
	' check line on y diff
	If pPx >= cx And pPx < pSize -cx Then
		Return True
	End If
	Return False
End Function