Graphics3D 800,600,16,2
SetBuffer BackBuffer()

;kamera
piv = CreatePivot()
cam = CreateCamera(piv)

MoveEntity cam,0,0,-10
PointEntity cam,piv


;ein hübsches bodenmesh aus sucox code geklaut ;)
mesh = CreateBoden(20,20)

cubes = CreateMesh()
For i = 0 To 50
   cube = CreateCylinder(5)
   ScaleMesh cube,.8,.8,.8
   PositionMesh cube,Rnd(2,18)-10,.5,Rnd(2,18)-10
   RotateMesh cube,Rand(-20,20),Rand(360),Rand(-20,20)
   AddMesh(cube, cubes)
   FreeEntity cube
Next

ScaleMesh mesh,2,2,2
ScaleMesh cubes,2,2,2

meshbrushwhite = CreateBrush(255,255,255)
BrushFX meshbrushwhite,1
meshbrush = CreateBrush(255,255,255)

cubebrushwhite = CreateBrush(255,255,255)
BrushFX cubebrushwhite,1
cubebrush = CreateBrush(255,255,255)


;licht und lichtkamera
Global light = CreateLight(2)
PositionEntity light,19,28,0
LightColor light,10,10,10
AmbientLight 10,10,10

lightcam = CreateCamera(light)
HideEntity lightcam
CameraFogMode lightcam,1
CameraFogRange lightcam,5,50
CameraViewport lightcam,0,0,512,512
PointEntity lightcam,mesh
CameraViewport lightcam,0,0,512,512

EntityParent CreateCube(lightcam),0; man will ja auch sehen, wo das licht ist ;)

;die zwei schattentexturen
stex = CreateTexture(512,512)
TextureBlend stex,2
stex2 = CreateTexture(512,512)
TextureBlend stex2,2

;BrushTexture cubebrush,stex2

;projektion
ProjUV(lightcam,mesh,512)
ProjUV(lightcam,cubes,512)

;den schatten der würfel vorberechnen
EntityColor cubes,10,10,10
EntityFX cubes,1
RenderShadow(lightcam,cam,stex2)
EntityColor cubes,255,255,255
EntityFX cubes,0

;coole, schattenwerfende kugeln ;)
kpiv = CreatePivot()
Global kugel[10]
For i = 0 To 10
   kugel[i] = CreateSphere(8,kpiv)
   ScaleEntity kugel[i],Rnd(2,3),Rnd(2,3),Rnd(2,3)
   RotateEntity kugel[i],Rand(360),Rand(360),Rand(360)
   PositionEntity kugel[i],Rand(-30,30),Rand(-30,30),Rand(-30,30)
Next
ScaleEntity kpiv,.5,.5,.5


;mainloop
While Not KeyHit(1)
   If KeyHit(57) Then wire = 1- wire:WireFrame wire
   
   TurnEntity kpiv,.3,1,.1
   
   PointEntity lightcam,mesh
   PaintSpheres(10,10,10,1)
   PaintEntity mesh,meshbrushwhite
   PaintEntity cubes,cubebrushwhite
   
   RenderShadow(lightcam,cam,stex)
   
   PaintEntity mesh,meshbrush
   PaintEntity cubes,cubebrush
   EntityTexture mesh,stex,0,1
   EntityTexture mesh,stex2,0,2
   EntityTexture cubes,stex
   PaintSpheres(255,255,255,0)
   
   RenderWorld
   
   If KeyHit(2) Then FlushKeys : WaitKey()
   
   TurnEntity piv,KeyDown(200)-KeyDown(208),KeyDown(205)-KeyDown(203),0
   MoveEntity cam,0,0,KeyDown(30)-KeyDown(44)
   RotateEntity piv,EntityPitch(piv),EntityYaw(piv),0
   
   Flip
Wend
End


Function ProjUV(cam,mesh,width#)  ; diese funktion passt die vertexkoordinaten an die projektion der kamera an
   RotateEntity cam,EntityPitch(cam),EntityYaw(cam),0
   For s = 1 To CountSurfaces(mesh)
      sur = GetSurface(mesh,s)
      For ve = 1 To CountVertices(sur)
         x# = VertexX(sur,ve)
         y# = VertexY(sur,ve)
         z# = VertexZ(sur,ve)
         
         TFormPoint x#,y#,z#,mesh,0
         x# = TFormedX#()
         y# = TFormedY#()
         z# = TFormedZ#()
         
         CameraProject(cam,x#,y#,z#)
         u# = ProjectedX#()/width#
         v# = ProjectedY#()/width#
         
         VertexTexCoords sur,ve,u#,v#
      Next
   Next
End Function


Function PaintSpheres(r,g,b,fx) ; färbt die ganzen kugeln ein (hätt' ich die doch bloß mit addmesh zusammengefügt! ;))
   For i = 0 To 10
      EntityColor kugel[i],r,g,b
      EntityFX kugel[i],fx
   Next
End Function


Function RenderShadow(cam,hcam,tex) ; rendert die schattentextur
   ShowEntity cam
   HideEntity hcam
   
   size = TextureWidth(tex)
   
   CameraViewport cam,0,0,size,size
   
   UpdateWorld
   RenderWorld
   
   CopyRect 0,0,size,size,0,0,BackBuffer(),TextureBuffer(tex)
   
   HideEntity cam
   ShowEntity hcam
End Function


Function CreateBoden(xstep = 20, zStep = 20) ; erstellt einen wunderschönen sucox boden ;)
   Local final_mesh = CreateMesh()
   Local final_surface = CreateSurface(final_mesh)
   Local vertex[5]
   
   
   For x = 0 To xstep-1
      For z = 0 To zStep-1     
         vertex[0] = AddVertex(final_surface,x-xstep/2,0,z-zStep/2,0,0)
         vertex[1] = AddVertex(final_surface,x-xstep/2,0,z-zStep/2-1,0,1)
         vertex[2] = AddVertex(final_surface,x-xstep/2+1,0,z-zStep/2-1,1,1)
         
         vertex[3] = AddVertex(final_surface,x-xstep/2,0,z-zStep/2,0,0)
         vertex[4] = AddVertex(final_surface,x-xstep/2+1,0,z-zStep/2,1,0)
         vertex[5] = AddVertex(final_surface,x-xstep/2+1,0,z-zStep/2-1,1,1)
         
         AddTriangle(final_surface, vertex[2], vertex[1], vertex[3])
         AddTriangle(final_surface, vertex[3], vertex[4], vertex[5])
         
         UpdateNormals(final_mesh)
      Next
   Next
   
   Return final_mesh
End Function