; Pfadkorrektur für Wegpunkte

; Gleicht Versätze in einer Koordinatenreihe aus, die einen zusammenhängenden Pfad bilden.
; Damit kann man z.B. Wegpunkte korrigieren, die "aus der Reihe tanzen".

; Die Funktion Ausgabe prüft einen Anfangs und einen Endpunkt des Pfades und verschiebt alle
; Punkte, die sich dazwischen befinden auf eine Linie, die den Anfangs- mit dem Endpunkt verbindet.
; In einer Schleife angewendet, kann man somit auch Kurven bilden.


Dim X#(640)
Dim Y#(640)

Global n
Global Start, Ende

Graphics 640,480,16,2
AppTitle "Pfadkorrektur für Wegpunkte"


; fehlerhaften Bispielpfad generieren

BeispielHorizontal()
BeispielHorizontal2()
;BeispielVertikal()


; Ursprungspfad anzeigen
For i = 1 To n
 Color 255,0,0
 Plot x(i), y(i)
Next


; --- Versatz ausgleichen ---
For temp = 1 To 2 ; genauigkeit
 For i = start To ende Step 20
  Ausgleich(i-20,i+20)
  If start < 0 Then start = 0
 Next

 For i = ende To start Step -20
  Ausgleich(i-20,i+20)
  If start < 0 Then start = 0
 Next
Next
; --- Versatz ausgleichen ---


; Ausgabepfad anzeigen
Color 0,255,0
For i = 1 To n
 Plot x(i), y(i)
Next

WaitKey
End




Function BeispielHorizontal()

 ; Punkteversatz generieren
 For n = 0 To 639
  If n < 320 Then
   y(n) = 250 + n/2 ;+ Rnd(-3,3)
  Else
   y(n) = 250 - n/6 ;+ Rnd(-3,3)
  EndIf
  x(n) = n
 Next

 ; Ausgleichsbereich festlegen
 Start = 150
 Ende = 470

End Function



Function BeispielHorizontal2()

 ; Punkteversatz generieren
 For n = 0 To 639
  If n < 320 Then
   y(n) = 350 + n/8 + Rnd(-5,5)
  Else
   y(n) = 200 - n/6 + Rnd(-5,5)
  EndIf
  x(n) = n
 Next

 ; Ausgleichsbereich festlegen
 Start = 20
 Ende = 600

End Function



Function BeispielVertikal()

 ; Punkteversatz generieren
 For n = 0 To 479
  If n < 240 Then
   x(n) = 200 + n/4
  Else
   x(n) = 300 + n/4
  EndIf
  y(n) = n
 Next

 ; Ausgleichsbereich festlegen
 Start = 140
 Ende = 340

End Function



Function Ausgleich(Start#, Ende#)

 ; Verlaufsrichtung ermitteln
 For ii = 0 To n-1
  For i = 0 To n-1
   If Abs(x(i)-x(ii)) > MaxAbsX Then MaxAbsX = Abs(x(i)-x(ii))
  Next
 Next

 For ii = 0 To n-1
  For i = 0 To n-1
   If Abs(y(i)-y(ii)) > MaxAbsY Then MaxAbsY = Abs(y(i)-y(ii))
  Next
 Next

 If MaxAbsX > MaxAbsY Then Verlauf = 0
 If MaxAbsX < MaxAbsY Then Verlauf = 1

 Color 0,0,0:Rect 0,0,640,60,1
 Color 200,200,200
 Text 5, 5, "Maximaler Abstand X: " + MaxAbsX
 Text 5,15, "Maximaler Abstand Y: " + MaxAbsY
 If Verlauf = 0 Then Text 5, 35, "Horizontaler Verlauf von " + n + " Punkten"
 If Verlauf = 1 Then Text 5, 35, "Vertikaler Verlauf von " + n + " Punkten"
 ; Verlaufsrichtung ermitteln


 ; horizontaler Ausgleich
 If Verlauf = 0 Then

  FirstY = y(Start)
  LastY = y(Ende)

  Color 25,25,25: Rect Start, 0 , Ende-Start, 480, 0

  Abstand = Abs(FirstY-LastY)
  Dauer#  = Ende - Start

  For i = Start To Ende
   Progress# = (i-start) / dauer#
   If FirstY > LastY Then y(i) = y(start) - (Progress * Abstand)
   If FirstY < LastY Then y(i) = y(start) + (Progress * Abstand)
  Next

 EndIf
 ; horizontaler Ausgleich


 ; vertikeler Ausgleich
 If Verlauf = 1 Then

  FirstX = x(Start)
  LastX = x(Ende)

  Color 25,25,25: Rect 0, Start , 640,  Ende-Start, 0

  Abstand = Abs(FirstX-LastX)
  Dauer#  = Ende - Start

  For i = Start To Ende
   Progress# = (i-start#) / dauer#
   If FirstX > LastX Then x(i) = x(start) - (Progress * Abstand)
   If FirstX < LastX Then x(i) = x(start) + (Progress * Abstand)
  Next

 EndIf
 ; vertikeler Ausgleich
End Function