Type V3D
 Field x#
 Field y#
 Field z#
End Type

Function in_triangle(o.V3D,d.V3D, v1.V3D, v2.V3D, v3.V3D, t.V3D)

  ;t ist ByRef !!!
   
  ;o=Beobachter , d=Richtung , v0-v2 Ecken vom Dreieck
 
 
  ;global e1 e2 vt vp vq
 
  Local u#
  Local v#
  Local det#
  Local inv_det#
  Local EPSILON#
 
  EPSILON = 0.0000001
 
  VSUB v2, v1,e1   ;SUB
 
  VSUB v3, v1,e2   ;SUB
 
  VCROSS d, e2,vp   ;CROSS
 
  det = (e1\x * vp\x + e1\y * vp\y + e1\z * vp\z) ;Dotproduct

  If det > -EPSILON And det < EPSILON Then
   Return 0
  End If
 
  inv_det = 1.0 / det
 
  VSUB o, v1,vt ;SUB
 
  u = (vt\x * vp\x + vt\y * vp\y + vt\z * vp\z) * inv_det ;Dotproduct
 
  If u < 0.0 Or u > 1.0 Then
   Return 0
  End If
 
  VCROSS vt, e1,vq ;CROSS
 
  v = VDOT(d, vq) * inv_det ;Dotproduct
 
  If v < 0.0 Or (u + v) > 1.0 Then
   Return 0
  End If
 
  t\z = VDOT(e2, vq) * inv_det ;Dotproduct
 
  Return 1
 
End Function

Function VSUB(v1.V3D, v2.V3D,vout.V3D)
 
 ;-
 
 vout\x = v1\x - v2\x
 vout\y = v1\y - v2\y
 vout\z = v1\z - v2\z

End Function

Function VCROSS(a.V3D,b.V3D,c.V3D)
 
 c\x = a\y * b\z - b\y * a\z
 c\y = a\z * b\x - b\z * a\x
 c\z = a\x * b\y - b\x * a\y
 
End Function

Function VDOT#(a.V3D, b.V3D)
 
 Return (a\x * b\x + a\y * b\y + a\z * b\z)
 
End Function