Graphics 640,480,32,1

Data 2,2 ;Breite und Höhe
Data 255,0,0, 0,128,0 ,0,255,100    ;RGB
Data 255,140,0, 255,0,0 ,0,255,150
Data 255,80,0, 0,128,0 ,0,255,180

;Breite und hoehe einlesen
Read br
Read ho
;Bild erzeugen
bild=CreateImage(br,ho)
SetBuffer ImageBuffer(bild)
;Farbwerte einlesen und punkte ins Bild malen
For count1=0 To br
 For count2=0 To ho
   Read r
   Read g
   Read b
   Color r,g,b
   Plot count1,count2
 Next
Next

;Bilid anzeigen
SetBuffer BackBuffer()
DrawImage bild,0,0
Flip
WaitKey
;Ende :)
End

Global package_exe$ ="c:\xxx.exe"
Global package_pass$="ExtremeHardCheese"
Global package_temp$=SystemProperty$("TEMPDIR")
Global package_data =CreateBank(0)
Global package_byte =CreateBank(0)
Global package_pos  =CreateBank(0)
Global package_count=0
Global package_size =0

Graphics 640,480,16,2

;---ACHTUNG BEISPIEL 1---
;package_addfile("c:\bild1.png")
;package_addfile("c:\bild2.png")
;package_attach()

;---ACHTUNG BEISPIEL 2---
;package_readinfo()
;img1=package_loadimage(1)
;img2=package_loadimage(2)
;DrawBlock img1,0,0
;DrawBlock img2,100,100

WaitKey()
FreeBank package_data
FreeBank package_byte
FreeBank package_pos
End





;---------------------------------------------------------------------
;Diese Funktion fügt eine Media-Datei zum Paket hinzu
;
;name: Beliebiger Dateiname
;---------------------------------------------------------------------
Function package_addfile(name$)
  file=ReadFile(name$)
  If file=0 Then
    RuntimeError name$+" wurde nicht gefunden"

  EndIf

  size=FileSize(name$)
  If size=0 Then
    CloseFile file
    RuntimeError name$+" ist nur 0 Byte groß"
  EndIf

  package_size=package_size+size
  package_count=package_count+1

  ResizeBank package_byte,package_count*4
  PokeInt package_byte,(package_count-1)*4,size

  ResizeBank package_pos,package_count*4
  PokeInt package_pos,(package_count-1)*4,package_size-size

  offset=BankSize(package_data)
  ResizeBank package_data,offset+size
  ReadBytes package_data,file,offset,size

  For n=1 To Len(package_pass$)
    key=Asc(Mid$(package_pass$,n,1))
    keystart=offset+n-1
    keyend=offset+size-1
    keystep=Len(package_pass$)-1
    For i=keystart To keyend
      byte=PeekByte(package_data,i)
      PokeByte package_data,i,byte Xor key
      i=i+keystep
    Next
  Next

  CloseFile file
End Function





;---------------------------------------------------------------------
;Diese Funktion hängt unser Paket an eine EXE-Datei an
;---------------------------------------------------------------------
Function package_attach()
  file=OpenFile(package_exe$)
  If file=0 Then
    RuntimeError package_exe$+" wurde nicht gefunden"
  EndIf

  If package_size=0 Then
    CloseFile file
    RuntimeError "Paket ist nur 0 Byte groß"
  EndIf

  offset=FileSize(package_exe$)
  SeekFile file,offset

  WriteBytes package_data,file,0,package_size
  WriteBytes package_byte,file,0,package_count*4
  WriteBytes package_pos ,file,0,package_count*4
  WriteInt file,package_size
  WriteInt file,package_count
  WriteInt file,$49414242

  CloseFile file
End Function





;---------------------------------------------------------------------
;Diese Funktion lädt Paket-Informationen aus einer EXE-Datei aus
;---------------------------------------------------------------------
Function package_readinfo()
  file=ReadFile(package_exe$)
  If file=0 Then
    RuntimeError package_exe$+" wurde nicht gefunden"
  EndIf

  exesize=FileSize(package_exe$)
  SeekFile file,exesize-4
  signature=ReadInt(file)
  If signature<>$49414242 Then
    RuntimeError package_exe$+" enthält keinen Anhang"
  EndIf

  SeekFile file,exesize-8
  package_count=ReadInt(file)
  ResizeBank package_byte,package_count*4
  ResizeBank package_pos,package_count*4

  SeekFile file,exesize-package_count*8-12
  ReadBytes package_byte,file,0,package_count*4
  ReadBytes package_pos,file,0,package_count*4
  package_size=ReadInt(file)

  CloseFile file
End Function





;---------------------------------------------------------------------
;Diese Funktion "entpackt" eine Datei aus einer EXE
;
;nr:   Nummer des Paketes (ab 1 bis max Dateien)
;kind: Ausgabedateityp    (ohne Pfad/Name - z.B. bmp,png,wav...)
;---------------------------------------------------------------------
Function package_exportfile(nr,kind$)
  If nr<1 Or nr>package_count Then RuntimeError "Paket "+Str$(nr)+" existiert nicht"

  file=ReadFile(package_exe$)
  If file=0 Then
    RuntimeError package_exe$+" wurde nicht gefunden"
  EndIf

  exesize=FileSize(package_exe$)
  pos=PeekInt(package_pos,nr*4-4)
  size=PeekInt(package_byte,nr*4-4)

  SeekFile file,exesize-package_count*8-12-package_size+pos
  ResizeBank package_data,size
  ReadBytes package_data,file,0,size
  CloseFile file

  For n=1 To Len(package_pass$)
    key=Asc(Mid$(package_pass$,n,1))
    keystart=n-1
    keyend=size-1
    keystep=Len(package_pass$)-1
    For i=keystart To keyend
      byte=PeekByte(package_data,i)
      PokeByte package_data,i,byte Xor key
      i=i+keystep
    Next
  Next

  If kind$<>"" Then kind$="."+kind$
  file=WriteFile(package_temp$+"out"+kind$)
  If file=0 Then Return
  WriteBytes package_data,file,0,size
  CloseFile file
End Function





;---------------------------------------------------------------------
;Diese Funktion lädt ein Bild aus einer EXE-Datei
;
;nr:     Nummer des Paketes   (ab 1 bis max Dateien)
;width:  Breite bei AnimImage (optional)
;height: Höhe   bei AnimImage (optional)
;count:  Anzahl bei AnimImage (optional)
;---------------------------------------------------------------------
Function package_loadimage(nr,width=0,height=0,count=0)
  package_exportfile(nr,"")
  If width>0 And height>0 And count>0 Then
    image=LoadAnimImage(package_temp$+"out",width,height,0,count)
  Else
    image=LoadImage(package_temp$+"out")
  EndIf
  DeleteFile package_temp$+"out"
  Return image
End Function

Graphics 800,600
start1 = MilliSecs()
Bild = LoadImage("Bild.jpg")
start2 = MilliSecs()
zeit1 = start2-start1

Bildneu = CreateImage(500,400)
Dim neuefarbe(500,400)

SetBuffer ImageBuffer(Bild)
LockBuffer ImageBuffer(Bild)
For x = 0 To 500
   For y = 0 To 400
      neuefarbe(x,y) = ReadPixelFast(x,y)
   Next
Next
UnlockBuffer ImageBuffer(Bild)

start3 = MilliSecs()
SetBuffer  ImageBuffer(Bildneu)
LockBuffer ImageBuffer(Bildneu)
For x = 0 To 500
   For y = 0 To 400
      WritePixelFast x,y, neuefarbe(x,y)
   Next
Next
UnlockBuffer ImageBuffer(Bildneu)
start4 = MilliSecs()
zeit2 = start4-start3

SetBuffer BackBuffer()
DrawImage Bildneu,0,0
Text 600,10,zeit1+"     -    "+zeit2
Flip

WaitKey