Global hole_sprite=LoadSprite("spr\bullet_hole.bmp") ;Einschuss Löcher :-)
EntityBlend hole_sprite,2
ScaleSprite hole_sprite,40,40
SpriteViewMode hole_sprite,2
HideEntity hole_sprite

.HOLE

Type HoleType
 Field alpha#
 Field sprite
 Field Parent ;Entity evtl. Ziel
End Type
Global Hole.HoleType

Function HoleNew(pe,cx#,cy#,cz#,nx#,ny#,nz#)

 ;---------------------------------------- Max 10 Holes ,wenn mehr dann die ersten löschen

 Local c

 For Hole.HoleType=Each HoleType
  c=c+1
 Next
 If c>10 Then HoleFree First HoleType

 ;----------------------------------------

 Hole.HoleType=New HoleType
 Hole\alpha=1
 Hole\sprite=CopyEntity( hole_sprite )
 PositionEntity Hole\sprite,cx,cy,cz
 AlignToVector Hole\sprite,-nx,-ny,-nz,3,1

 MoveEntity Hole\sprite,0,0,-1
 EntityParent Hole\sprite,pe
 Hole\Parent=pe

End Function

;-------------------------------------------------------------

Function HolesUpdate(timed#)

 For Hole.HoleType =Each HoleType

  Hole\alpha=Hole\alpha-0.0025*(timed#*50.0)
  If Hole\alpha>0.0
    EntityAlpha Hole\sprite,Hole\alpha
  Else
   HoleFree  Hole
  EndIf

 Next

End Function

;-------------------------------------------------------------

Function HoleFree(h.HoleType)

 EntityParent h\sprite,0  ;falls am Ziel hängt !
 FreeEntity h\sprite
 h\sprite=123
 Delete h

End Function