Type TStarField
   Field CenterX:Float
   Field CenterY:Float
   
   Field Rate:Int
   Field Particle_List:TList = New TList
   
   Function Create:TStarField(X# , Y# , Rate:Int)
      Local S:TStarField = New TStarField
      S.CenterX = X
      S.CenterY = Y
      S.Rate = Rate
      Return S
   End Function
   
   Method Update()
      For Local I:Int = 0 To Rate - 1
         Local Speed#
         Select Rand(1 , 3)
            Case 1
               Speed = Rnd(0.5,1.5)
            Case 2
               Speed = Rnd(1.5,2.5)
            Case 3
               Speed = Rnd(2.5,3.5)
         End Select
         Particle_List.AddLast(TParticle.Create(CenterX , CenterY , Speed , Rand(0 , 360) , Rnd(0.0 , 0.003) ) )
      Next
      
      For Local P:TParticle = EachIn Particle_List
         If P.Update() = False Then
            Particle_List.Remove(P)
            'Print "Remove"
         EndIf
      Next
   End Method
End Type

Type TParticle
   Field X:Float
   Field Y:Float
   
   Field Speed:Float
   Field Angle:Float
   Field Scale:Float
   Field Cur_Scale:Float = 0.1
   
   Function Create:TParticle(x# , y# , s# , a:Int , sc#)
      Local P:TParticle = New TParticle
      P.X = X
      P.Y = Y
      P.Speed = S
      P.Angle = A
      P.Scale = sc
      Return P
   End Function
   
   Method Update:Byte()
      X = X + Cos(Angle) * Speed
      Y = Y + Sin(angle) * Speed
      Cur_Scale:+ Scale
      
      SetScale cur_Scale , Cur_Scale
      DrawOval X , Y , 5 , 5
      SetScale 1.0 , 1.0
      
      If X < 0 Or X > GraphicsWidth() Or Y < 0 Or Y > GraphicsHeight() Then
            Return False
      EndIf
      
      Return True
   End Method
End Type

Graphics 800 , 600 , 0 , 60

Local S:TStarField = TStarField.Create(400,300,3)

While Not KeyHit(KEY_ESCAPE)
   Cls
   S.Update()
   
   DrawText "Count : " + S.Particle_List.Count(),20,20
   Flip
Wend