POST /forum/login.php HTTP/1.1
Host: www.blitzforum.de
Content-Type: application/x-www-form-urlencoded
Content-Length: 32

username=SYSThern&password=*****

GET /wiki/Http HTTP/1.1
Host: de.wikipedia.org
User-Agent: Mozilla/5.0 (Windows; U; Windows NT 5.1; de; rv:1.9.2) Gecko/20100115 Firefox/3.6 (.NET CLR 3.5.30729)
Accept: text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8
Accept-Language: de-de,de;q=0.8,en-us;q=0.5,en;q=0.3
Accept-Encoding: gzip,deflate
Accept-Charset: ISO-8859-1,utf-8;q=0.7,*;q=0.7
Keep-Alive: 115
Connection: keep-alive
Referer: http://www.blitzforum.de/forum/posting.php?mode=reply&t=34411
If-Modified-Since: Fri, 02 Apr 2010 09:11:50 GMT
Cache-Control: max-age=0

AppTitle "BlitzForum.de - Login"

Global Username$ = Input("Username: ")
Global Password$ = Input("Passwort: ")

Print "Einloggen..."

QueryLogin()

Print "Weiterleitung..."

LocationRedirect()


Print "------"
Print "ENDE"
WaitKey()
End

Global POST_DATA$
Global Location$
Global tcp, tcp_data$

Type TCookie
   Field SData$
End Type



Function QueryLogin()
   POST_DATA$ = "username="+Username+"&password="+Password+"&redirect=&login=Login"
   
   tcp=OpenTCPStream("blitzforum.de",80)
   
   WriteLine tcp,"POST http://www.blitzforum.de/forum/login.php"+" HTTP/1.1"
   WriteLine tcp,"HOST: www.blitzforum.de"
   WriteLine tcp,"Content-Type: application/x-www-form-urlencoded"
   WriteLine tcp,"Content-Length: "+Len(POST_DATA)
   WriteLine tcp,""
   WriteLine tcp,POST_DATA
   
   
   ; Antwort auswerten
   
   While Not Eof(tcp)
      tcp_data$=ReadLine$( tcp )

      ; Falls Passwort richtig, wird weitergeleitet zu der im Header angegeben Location
      GetLocation( tcp_data )

      ; Cookies speichern
      GetCookie%( tcp_data )

      ; Falls Passwort oder Benutzername falsch, schickt phpBB gleich die Fehlermeldung
      If Instr( tcp_data ,"inaktiven Benutzernamen") Then
         Print "Du hast einen falschen oder inaktiven Benutzernamen oder ein falsches Passwort eingegeben."
         WaitKey()
         CloseTCPStream tcp
         End
      EndIf
      
   Wend
   
   CloseTCPStream tcp
End Function


Function LocationRedirect()

   ; phpBB schickt vier Cookies, wobei die letzten zwei die ersten zwei überschreiben.
   ; Deshalb sind nur die letzten beiden interessant:
   Local TC1.TCookie = Before Last TCookie
   Local TC2.TCookie = Last TCookie
   
   tcp=OpenTCPStream("blitzforum.de",80)
   
   WriteLine tcp,"GET "+Location$+" HTTP/1.1"
   WriteLine tcp,"Host: www.blitzforum.de"
   WriteLine tcp, "Cookie: "+TC1\SData+TC2\SData
   WriteLine tcp,""
   
   While Not Eof(tcp)
      tcp_data$=ReadLine$( tcp )
      If Instr( tcp_data ,"Eingeloggt als") Then Print "Eingeloggt!"
   Wend
   CloseTCPStream tcp
End Function


Function GetLocation( input_txt$ )
   If Instr(input_txt$, "Location:") Then
      Location$= Mid$(input_txt,11)
   EndIf
End Function

Function GetCookie( input_txt$ )
   If Instr(input_txt$, "Set-Cookie:") Then
      Local LC.TCookie = New TCookie
      LC\SData = Mid$(input_txt,13,Instr(input_txt$,";",1)-12)
   EndIf
End Function