Type TEnemy 'Gegnerklasse
	Global tlAllEnemies:TList = New TList 'Liste mit allen Gegnern
	Field v2dPosition:TVector2D 'Position
	Field v2dSpeed:TVector2D 'Allgemeine Geschwindigkeit
	Field v2dCurrentSpeed:TVector2D 'Aktuell festgelegte Geschwindigkeit
	Field v2dSize:TVector2D 'Größe des Rechtecks
	Field tsMovingScript:TScript 'Zugehöriges Script zum Bewegen
	
	Method New()
		tlAllEnemies.AddLast(Self) 'In die Liste einfügen
	End Method
	
	Function Create:TEnemy() 'Konstruktor
		Local Enemy:TEnemy = New TEnemy
		'Eigenschaften festlegen
		Enemy.v2dPosition = TVector2D.Create(GraphicsWidth() / 2, GraphicsHeight() / 2)
		Enemy.v2dSize = TVector2D.Create(20, 20)
		Enemy.v2dSpeed = TVector2D.Create(1.5, 1.5)
		Enemy.v2dCurrentSpeed = TVector2D.Create(Enemy.v2dSpeed.Get_X(), Enemy.v2dSpeed.Get_Y())
		
		Enemy.tsMovingScript = TScript(TScript.tlAllScripts.First()) 'Testweise das erste Script in der Liste
		
		Return Enemy
	End Function
	
	Method Move() 'Für die Bewegung
		v2dCurrentSpeed = tsMovingScript.InterpretScript(v2dSpeed) 'Das Script ausführen und entsprechend die Richtung festlegen
		v2dPosition = TVector2D.Add(v2dPosition, v2dCurrentSpeed) 'Bewegung: Vektoren addieren
	End Method
	
	Method Draw() 'Rechteck zeichnen
		DrawRect(v2dPosition.Get_X(), v2dPosition.Get_Y(), v2dSize.Get_X(), v2dSize.Get_Y())
	End Method
End Type

Type TFileLine 'Klasse für Zeilen in einer Datei
	Global tlAllLines:TList = New TList 'Alle gelesenen Zeilen
	Field sLine:String 'Inhalt der Zeile
	
	Method New()
		tlAllLines.AddLast(Self) 'In die Liste einfügen
	End Method
	
	Function Create:TFileLine(sLine:String) 'Konstruktor
		Local Line:TFileLine = New TFileLine
		Line.sLine = sLine 'Inhalt festlegen
		Return Line
	End Function
	
	Function ReadFileOut(sFileName:String) 'Eine komplette Datei auslesen
		Local tsFile:TStream
		
		If FileType(sFileName) = 1 Then 'Falls vorhanden...
			tsFile = ReadFile(sFileName) '...Datei öffnen
			While Not Eof(tsFile) 'Alle Zeilen durchgehen
				TFileLine.Create(ReadLine(tsFile)) 'Und eine neue Instanz anlegen
			Wend
			CloseFile(tsFile) 'Datei schließen
		EndIf
	End Function
	
	Function PrintAll() 'Alle Zeilen im Debugger ausgeben
		For Local Line:TFileLine = EachIn tlAllLines
			DebugLog(Line.sLine)
		Next
	End Function
End Type

Type TScriptLine 'Klasse für die Zeilen im Script
	Global tlAllScriptLines:TList = New TList 'Alle geladenen Zeilen
	Field sLine:String 'Die komplette Zeile
	Field sDirective:String 'Nur die Anweisung (links von ":")
	Field iParameter:Int 'Nur der Parameter (rechts von ":")
	
	Method New()
		tlAllScriptLines.AddLast(Self) 'In die Liste einfügen
	End Method
	
	Function Create:TScriptLine(sLine:String, sDirective:String, iParameter:Int) 'Konstruktor
		Local ScriptLine:TScriptLine = New TScriptline
		'Eigenschaften festlegen
		ScriptLine.iParameter = iParameter
		ScriptLine.sDirective = sDirective
		ScriptLine.sLine = sLine
		
		Return ScriptLine
	End Function
	
	Method PrintLine() 'Die Daten einer Zeile im Debugger ausgeben
		DebugLog("Line: " + sLine)
		DebugLog("Directive: " + sDirective)
		DebugLog("Parameter: " + iParameter)
	End Method
	
	Function MakeScriptLines() 'Anhand der ausgelesenen Datei Scriptzeilen erstellen
		Local iPos:Int, sRight:String, sLeft:String 'Ein paar Variablen
		
		For Local Line:TFileLine = EachIn TFileLine.tlAllLines 'Für jede gelesene Zeile
			If Line.sLine <> "" And Line.sLine <> " " Then 'Wenn es keine leere Zeile ist
				If Line.sLine = "/S" Or Line.sLine = "/E" Then 'Wenn die Zeile den Anfang oder das Ende eines Scripts anzeigt
					TScriptLine.Create(Line.sLine, Line.sLine, 0) 'Dann gibt es auch keine speziellen Parameter
				Else
					iPos = Instr(Line.sLine, ":") 'Position des ":"
					sLeft = Left(Line.sLine, iPos - 1) 'Die linke Seite, also die Anweisung
					sRight = Right(Line.sLine, Len(Line.sLine) - iPos) 'Die rechte Seite, also der Parameter
					TScriptLine.Create(Line.sLine, sLeft, Int(sRight)) 'Scriptzeile erstellen
				EndIf
			EndIf
		Next
		
	End Function
	
	Function PrintAll() 'Alle Scriptzeilen ausgeben
		Local i:Int = 1
		For Local ScriptLine:TScriptLine = EachIn tlAllScriptLines
			DebugLog("Line-Nr.: " + i)
			ScriptLine.PrintLine()
			DebugLog("")
			i = i + 1
		Next
	End Function

End Type

Type TScript 'Klasse für die Scripte
	Global tlAllScripts:TList = New TList 'Alle erstellten Scripte
	Field tlLines:TList 'Liste aller Scriptzeilen, die zum Script gehören
	Field tCurrentLine:TScriptLine 'Momentan bearbeitete Scriptzeile
	Field iCurrentParameter:Int 'Parameter, der runtergezählt wird
	Field iInterpretingTime:Int 'Zeit nach der das Script weiter verarbeitet werden soll
	Field iLastInterpreting:Int 'Zeit der letzten Interpretation
	
	Method New()
		tlAllScripts.AddLast(Self) 'In die Liste einfügen
	End Method
	
	Function Create:TScript() 'Konstruktor
		Local Script:TScript = New TScript
		
		Script.tlLines = New TList 'Liste anlegen
		Script.tCurrentLine = Null 'Erstmal keine Zeile, da noch nichts zugeordnet wurde
		Script.iCurrentParameter = 0
		Script.iInterpretingTime = 10000 '10 Sekunden, damit es nicht zu schnell geht
		Script.iLastInterpreting = 0
		
		Return Script
	End Function
	
	Function MakeScripts() 'Scripte anhand der geladenen Scriptzeilen erstellen
		Local Script:TScript
		For Local ScriptLine:TScriptLine = EachIn TScriptLine.tlAllScriptLines 'Alle Zeilen durchgehen
			If ScriptLine.sLine = "/S" Then Script = TScript.Create() 'Wenn die Startanweisung gelesen wird, wird ein neues Script erstellt
			Script.tlLines.AddLast(ScriptLine) 'Die Zeile zu den Zeilen des Scripts hinzufügen
			Script.tCurrentLine = TScriptLine(Script.tlLines.First()) 'Bearbeitete Linie auf die erste Zeile setzen
		Next
	End Function
	
	Method PrintScriptLines() 'Die Zeilen eines Scripts im Debugger ausgeben
		For Local ScriptLine:TScriptLine = EachIn tlLines
			ScriptLine.PrintLine() 'Einfach die Methode aufrufen
			DebugLog("")
		Next
	End Method
	
	Method ExecuteScript() 'Das SCript ausführen
		Local Link:TLink
		
		If iCurrentParameter <= 1 Then 'Wenn der aktuelle Parameter <= 1 ist wird die nächste Zeile bearbeitet
			'Nächste Zeile über die Links finden:
			Link = tlLines.FindLink(tCurrentLine)
			Link = Link.NextLink()
			tCurrentLine = TScriptLine(Link.Value())
			
			If tCurrentLine.sLine = "/E" Then 'Wenn der Inhalt der Zeile die Anweisung fürs Ende des Scripts ist
				tCurrentLine = TScriptLine(tlLines.First()) 'Wieder die erste Zeile nehmen
				Link = tlLines.FindLink(tCurrentLine)
				Link = Link.NextLink()
				tCurrentLine = TScriptLine(Link.Value()) 'Und dann auf die Zeile nach der ersten Zeile setzen
			EndIf
			iCurrentParameter = tCurrentLine.iParameter 'Den Parameter aufs Maximum setzen
		Else
			iCurrentParameter = iCurrentParameter - 1 'Ansonsten einfach den Parameter runterzählen
		EndIf
		
	End Method
	
	Method InterpretScript:TVector2D(v2dVec:TVector2D) 'Die aktuelle Zeile interpretieren
		If (MilliSecs() > (iLastInterpreting + iInterpretingTime)) Then 'Wenn die Zeit schon vergangen ist
			ExecuteScript() 'Das Script ausführen
			Select tCurrentLine.sDirective 'Die momentane Anweisung suchen
				Case "F" 'Vorwärts (also nach unten)
					'X-Geschwindigkeit auf 0 setzen und Y-Geschwindigkeit auf einen negativen Wert setzen
					If v2dVec.Get_Y() < 0 Then
						Return TVector2D.Create(0, -v2dVec.Get_Y())
					Else
						Return TVector2D.Create(0, Abs(v2dVec.Get_Y()))
					EndIf
				Case "B" 'Rückwärts (also nach oben)
					'X-Geschwindigkeit auf 0 setzen und Y-Geschwindigkeit auf einen positiven Wert setzen
					If v2dVec.Get_Y() < 0 Then
						Return TVector2D.Create(0, v2dVec.Get_Y())
					Else
						Return TVector2D.Create(0, -v2dVec.Get_Y())
					EndIf
				Case "L" 'Links
					'Y-Geschwindigkeit auf 0 setzen und X-Geschwindigkeit auf einen negativen Wert setzen
					If v2dVec.Get_X() < 0 Then
						Return TVector2D.Create(v2dVec.Get_X(), 0)
					Else
						Return TVector2D.Create(-v2dVec.Get_X(), 0)
					End If
				Case "R" 'Rechts
					'Y-Geschwindigkeit auf 0 setzen und X-Geschwindigkeit auf einen positiven Wert setzen
					If v2dVec.Get_X() < 0 Then
						Return TVector2D.Create(-v2dVec.Get_X(), 0)
					Else
						Return TVector2D.Create(Abs(v2dVec.Get_X()), 0)
					End If	
			End Select
			Return TVector2D.Zero() 'Wenn nichts gefunden wurde zumindest den Nullvektor zurückgeben
			iLastInterpreting = MilliSecs() 'Die Zeit wieder neu setzen
		EndIf
	End Method
End Type

Winkel = ATan2( Script_Parameter_Y, Script_Parameter_X )
Radius = Sqr( Script_Parameter_X^2 + Script_Parameter_Y^2 ) ;Wobei ich hier die ^2 auschreiben würde, ist einfach schneller

GegnerX = BezugspunktX + Cos( Winkel + WinkelSchrittZahl  ) * Radius
GegnerY = BezugspunktY + Sin( Winkel + WinkelSchrittZahl ) * Radius

				If bTurning Then
					Local fAngle:Float = (ATan2(iaparameterlist[1] - v2dReferencePoint.Get_Y(), iaParameterlist[0] - v2dReferencePoint.Get_X()) + 360) Mod 360
					Local fRadius:Float = Sqr(iaParameterList[0] * iaParameterList[0] + iaParameterList[1] * iaParameterList[1])
					Return TVector2D.Create(v2dReferencePoint.Get_X() + Cos(fAngle + piCounter) * fRadius, v2dReferencePoint.Get_Y() + Sin(fAngle + piCounter) * fRadius)		
				Else
					'(ATan2(Point2.y - Point1.y, Point2.x - Point1.x) + 360)
					v2dReferencePoint = TVector2D.Create(pVecPosition.Get_X() + iaParameterList[0], pVecPosition.Get_Y() + iaParameterList[1])
					DebugLog("Referenz-X|Y: " + v2dReferencePoint.Get_X() + " | " + v2dReferencePoint.Get_Y())
					DebugLog("Vektor-X|Y: " + pVecPosition.Get_X() + " | " + pVecPosition.Get_Y())
					bTurning = True
					Local fAngle:Float = (ATan2(iaparameterlist[1] - v2dReferencePoint.Get_Y(), iaParameterlist[0] - v2dReferencePoint.Get_X()) + 360) Mod 360
					Local fRadius:Float = Sqr(iaParameterList[0] * iaParameterList[0] + iaParameterList[1] * iaParameterList[1])
					Return TVector2D.Create(v2dReferencePoint.Get_X() + Cos(fAngle + piCounter) * fRadius, v2dReferencePoint.Get_Y() + Sin(fAngle + piCounter) * fRadius)
				EndIf

SuperStrict
Framework brl.GLMax2D
Import brl.Timer
Import brl.PolledInput
Import brl.KeyCodes

Graphics 800,600
Local timer:TTimer=CreateTimer(60)

Local objX:Float,objY:Float
Local turnX:Float,turnY:Float

Const SPEED:Float=1.0

Repeat
	Cls
	'Zeichnen
	DrawOval objX-5,objY-5,10,10
	Plot turnX,turnY
	'Positionieren
	If MouseHit(MOUSE_LEFT)
		objX=MouseX()
		objY=MouseY()
	EndIf
	If MouseHit(MOUSE_RIGHT)
		turnX=MouseX()
		turnY=MouseY()
	EndIf
	
	'Drehen um den Punkt
	objX:-turnX
	objY:-turnY
	
	Local oldX:Float=objX
	Local oldY:Float=objY
	
	Local radius:Float=Sqr(objX*objX+objY*objY) 'für eine gleichmäßige Geschwindigkeit notwendig
	Local deltaW:Float=(SPEED/radius)*180.0/Pi 'Berechnung im Bogenmaß: v=r*w -> w=v/r
	
	objX=Cos(deltaW)*oldX-Sin(deltaW)*oldY
	objY=Cos(deltaW)*oldY+Sin(deltaW)*oldX
	
	objX:+turnX
	objY:+turnY
	
	If KeyDown(KEY_SPACE) Then Delay 500
	WaitTimer timer
	Flip 0
Until KeyHit(KEY_ESCAPE)