SuperStrict

Framework MaxGUI.Drivers
Import BRL.EventQueue
Import Holzchopf.MaxGuiLayout

' Layout fürs Fenster, da es am oberen linken Fensterrand beginnen soll, wird es an (0,0) erstellt
Local lmWindow:TMaxGuiLayout = TMaxGuiLayout.Create(0,0,200,0)
' Und da machen wir auch gleich ein Fenster draus
lmWindow.Window("Beispiel 1", 0,0,Null, WINDOW_TITLEBAR | WINDOW_CENTER | WINDOW_RESIZABLE)
' Dem Fenster-Layout wird eine Zeile angefügt
lmWindow.AddBottom(0)
lmWindow.sub[0,0].Panel("Title",, PANEL_GROUP)	' mit einem panel
lmWindow.sub[0,0].SetMargin(2,2)
lmWindow.sub[0,0].Inner(0,20).TextField()		' und einem text field drin
lmWindow.sub[0,0].FitToContents()				' die Zeile wird dem text field angepasst
' In eine neue Zeile...
lmWindow.AddBottom(0)
lmWindow.sub[0,1].Panel("Description",, PANEL_GROUP)	' ... kommt ein panel
lmWindow.sub[0,1].SetMargin(2,2)
lmWindow.sub[0,1].Inner(0,80).TextArea()			' mit einer text area
lmWindow.sub[0,1].FitToContents()					' und wird wieder an den inhalt angepasst
' Die unterste Zeile...
lmWindow.AddBottom(0)
lmWindow.sub[0,2].Split([80,0,80],[25],True)				' ... wird nochmal aufgespaltet
lmWindow.sub[0,2].sub[0,0].Button("OK",, BUTTON_OK)		' kriegt einen OK-
lmWindow.sub[0,2].sub[2,0].Button("Cancel",, BUTTON_CANCEL)	' und Cancel-button
lmWindow.sub[0,2].FitToContents()
' Das Fenster wird an die Grösse der Inhalte angepasst
lmWindow.FitToContents()
' Das Layout wird fixiert. Die 1 im zweiten Parameter bedeutet: Die Zeile mit index 1 wird beim
' Vergrössern des Fensters skaliert
lmWindow.LockLayout(0,1)
' Die unterste Zeile wird so fixiert, dass das mittlere, leere Feld skaliert wird
lmWindow.sub[0,2].LockLayout(1,0)

' Hauptschleife
Repeat
	WaitEvent()
	Print CurrentEvent.ToString()
	' Typisches Gedöhns
	Select EventID()
	Case EVENT_WINDOWCLOSE
		End
	End Select
Forever