Graphics 640,480
SetBuffer BackBuffer()

Type schuss ; Das Type anlegen
 Field x,y
End Type

Repeat ; Die Hauptschleife
Cls
; Die Alienblaster 6001 auf den Bildschirm pinseln
Color 0,255,0
Rect MouseX(),MouseY(),10,35,1
 
; Hier der erste wichtige Teil
If MouseHit(1) ; Wenn linke Maustaste betätigt
 s.schuss=new schuss ; Eine neue Instanz anlegen
 ; s ist hier eine Variable die auf die Instanz verweist
 ; Man kann auch jede andere Variable verwenden, zu
 ; beachten ist nur das diese Variable nur noch für
 ; das Type verwendet werden kann!
 s\x=MouseX() ; Wir weisen dem Eintrag die Position der Maus zu
 ; Die Variable bezeichnet das Type, nach dem Backslash
 ; folgt das Feld
 s\y=MouseY() ; Bei Y verfahren wir ebenso
EndIf

Color 255,255,0
For s.schuss=Each schuss ; Unter Verwendung der Variable
 ; gehen wir alle vorhandenen Einträge des Types durch
 Oval s\x,s\y,10,10,1 ; Für jeden Eintrag pinsln wir
 ; einen Schuss auf den Bildschirm
 s\y=s\y-3 ; Die Position verändern
 If s\y<0 ; wenn der Schuss den Bildschirm verlässt...
  Delete s.schuss ; ...löschen wir selbigen
  ; Hier ist auch eine beliebte Fehlerquelle:
  ; Nach dem löschen kann auf diesen Eintrag nicht mehr zugegriffen werden!
  ; Daher ist diese Prüfung möglichst immer am Ende der Schleife
  ; durchzuführen
 EndIf
Next

Flip
Until KeyHit(1)
End