strict
graphics 800,600,0
global mann:TIMAGE = loadimage ("mann.png")
global x:int, y:int

while not keyhit (key_escape)
 cls
 if keydown (key_up)
  y :- 1
 elseif keydown (key_down)
  y :+ 1
 elseif keydown (key_left)
  x :- 1
 elseif keydown (key_right)
  x :+ 1
 endif
 drawimage mann, x, y
 flip
wend

Rem
Kleine Bmax Demo by Suco-X
Diese Demo soll ein bisschen den Umgang mit Bmax und der OOP zeigen.
Natürlich ist die Struktur eines kompletten Games mit der OOP noch um einiges komplexer.
Ich habe mich aber auf das nötigste beschränkt. Natürlich kann ich auch nicht garantieren
das dieses die beste Lösung ist.
end rem


Strict

Framework BRL.glmax2d
Import BRL.basic
Import BRL.bmploader




'Basis Klasse für die Grundddaten die jedes Objekt dieser Demo benötigt.
'Diese Klasse kann man in alle seine Spiele übernehmen. Also einmal Arbeit gemacht und gut ist.
'Die "_" vor den Variablen haben den Zweck das sich die Variablenamen nicht mit den anderen
'Klassen Variablennamen überschneiden.
Type TObjektBase

   Field _x:Float, _y:Float
   Field _Image:TImage
   Field _Frame:Int
   Field _Width:Int,_Height:Int
   Field _r:Byte = 255, _g:Byte = 255, _b:Byte = 255
   Field _Blend:Int = MASKBLEND
   Field _Rotation:Float
   Field _ScaleX:Float=1.0, _ScaleY:Float=1.0
   
   Method Render()
      ResetStates()
      self.SetStates()
      DrawImageRect self._Image, self._x, self._y, self._Width, self._Height, self._Frame
   End Method
   
   
   Method SetStates()
      SetRotation self._Rotation
      SetBlend self._blend
      SetColor self._r, self._g, self._b
      SetScale self._ScaleX,self._ScaleY
   End Method
   
   
   Method SetObjektColor(r:Byte, g:Byte, b:Byte)
      self._r = r
      self._g = g
      self._b = b
   End Method
   
   
   Method SetObjektImage(Image:TImage)
      self._Image = Image
      
      If self._Width   = 0 And self._Height = 0
         self._Width  = self._Image.Width
         self._Height = self._Image.Height
      EndIf
      
   End Method
   
   
   Method SetObjektPosition(x:Float, y:Float)
      self._x = x
      self._y = y
   End Method
   
   Method AddObjektPosition(ValueX:Float, ValueY:Float)
      self._x:+ValueX
      self._y:+ValueY
   End Method
   
   
   Method SetObjektFrame(Frame:Int)
      self._Frame = Frame
   End Method
   
   
   Method SetObjektSize(Width:Int, Height:Int)
      self._Width  = Width
      self._Height = Height
   End Method
   
   Method SetObjektBlend(Blend:Int)
      self._Blend = Blend
   End Method
   
   
   Method SetObjektRotation(Rotation:Float)
      self._Rotation = Rotation
   End Method
   
   
   Method AddObjektRotation(Value:Float)
      self._Rotation:+Value
   End Method
   
   
   Method SetObjektScale(ScaleX:Float, ScaleY:Float)
      self._ScaleX = ScaleX
      self._ScaleY = ScaleY
   End Method
   
   
   
   Method GetObjektX:Float()
      Return self._x
   End Method
   
   Method GetObjektY:Float()
      Return self._y
   End Method
   
   Method GetObjektWidth()
      Return self._Width
   End Method
   
   Method GetObjektHeight()
      Return self._Height
   End Method
   
End Type





'Kleine Timer Klasse
Type TTimer
   
   Field Time:Int
   Field Timer:Int
   
   Function GetInstance:TTimer(Time:Int)
      Local TempObject:TTimer = New TTimer
      TempObject.Time = Time
      TempObject.Timer = MilliSecs()
      Return TempObject
   End Function
   
   Method IsReleased()
      If MilliSecs()-self.Timer=>self.Time
         self.Timer = MilliSecs()
         Return True
      EndIf
      
      Return False
   End Method


End Type











'Asteroid Klasse

TAsteroid.ObjectList = New TList

Type TAsteroid Extends TObjektBase
   
   'Globale Objektlist. Hier werden alle Handles gespeichert und beim Updaten/Render wieder aufgerufen
   Global ObjectList:TList
   
   Field Speed:Float
   
   'Instanz erhalten
   Function GetInstance:TAsteroid()
      Return New TAsteroid
   End Function
   
   
   'Alles Updaten und Rendern
   Function UpdateAndRenderAll()
      For Local TempObject:TAsteroid = EachIn self.ObjectList
         TempObject.Update()
         TempObject.Render()
      Next
   End Function
   
   'Beim Konstruktor wird das Handle(self) in die ObjectList eingefügt
   Method New()
      self.ObjectList.AddLast(Self)
   End Method
   
   

   Method Remove()
      self.ObjectList.Remove(Self)
   End Method
   
   
   'Update Method
   Method Update()
   
      self.AddObjektPosition(-(GameSpeed*self.Speed),0.0)
      self.AddObjektRotation((GameSpeed*self.Speed))
      
      If self.GetObjektX()=<0-(self.GetObjektWidth()/2)
         self.Remove()
      EndIf
      
   End Method
   
   
End Type



'Nach dem gleichen Prinzip laufen alle folgenden Klassen




'Ship Klasse für die billigen Schiffe die so komisch rumfliegen ;)

TShip.ObjectList = New TList

Type TShip Extends TObjektBase

   Global ObjectList:TList
   
   Field Speed:Float
   Field Sinus:Float

   Function GetInstance:TShip()
      Return New TShip
   End Function
   
   
   Function UpdateAndRenderAll()
      For Local TempObject:TShip= EachIn self.ObjectList
         TempObject.Update()
         TempObject.Render()
      Next
   End Function
   
   Method New()
      self.ObjectList.AddLast(Self)
   End Method
   
   Method Remove()
      self.ObjectList.Remove(Self)
   End Method
   
   
   Method Update()
      self.Sinus:+(self.Speed/2)
      self.AddObjektPosition(-(GameSpeed*self.Speed),Sin((GameSpeed*self.Sinus))*((GameSpeed*(self.Speed/3))))
      
      If self.GetObjektX()=<0-(self.GetObjektWidth())
         self.Remove()
      EndIf
      
   End Method
   
   
End Type






'Stern Klasse. Hier wird die Render Method aus TObjektBase überschrieben

TStar.ObjectList = New TList

Type TStar Extends TObjektBase

   Global ObjectList:TList
   
   Field Speed:Float


   Function GetInstance:TStar()
      Return New TStar
   End Function
   
   
   Function UpdateAndRenderAll()
      For Local TempObject:TStar= EachIn self.ObjectList
         TempObject.Update()
         TempObject.Render()
      Next
   End Function
   
   Method New()
      self.ObjectList.AddLast(Self)
   End Method
   
   Method Remove()
      self.ObjectList.Remove(Self)
   End Method
   
   
   Method Update()
   
      self.AddObjektPosition(-(GameSpeed*self.Speed),0.0)
      
      If self.GetObjektX()=<0
         self.Remove()
      EndIf
      
   End Method
   
   
   Method Render()
      self.SetStates()
      DrawOval self.GetObjektX(), self.GetObjektY(),self.GetObjektWidth(), self.GetObjektHeight()
   End Method
   
End Type







'Errechnet die Spielgeschwindigkeit anhand der dauer eines schleifendurchlaufs
Function GetGameSpeed:Float(Hz:Int)
   Global _LoopTime:Int
   Local Speed:Float
   
   speed = MilliSecs()-_LoopTime
   speed = (Speed/1000.0)*Hz
   _LoopTime = MilliSecs()
   Return Speed
End Function




'FPS Funktion.
Function GetFPS()
   Global _FPS:Int, _TFPS:Int, _LoopTime:Int
   
   _TFPS:+1
   
   If MilliSecs()-_LoopTime=>1000
      _FPS = _TFPS
      _TFPS = 0
      _LoopTime = MilliSecs()
   EndIf
   
   Return _FPS
End Function



'Setzt die globalen Rendereigenschaften wieder auf ihre Standardwerte
Function ResetStates()
   SetColor 255,255,255
   SetRotation 0.0
   SetScale 1.0,1.0
   SetAlpha 1.0
   SetBlend MASKBLEND
End Function



Graphics 1024,768,32

SeedRnd(MilliSecs())


'Vsync aus. Sowas wie Flip 0
bglSetSwapInterval(0)



'Images
AutoMidHandle True

Local asteroid1_img:Timage = LoadImage("asteroid1.bmp")

AutoMidHandle False

Local ship1_img:TImage = LoadImage("ship1.bmp")



'Globale Variable für die Spielgeschwindigkeit(Unabhängig von FPS)
Global GameSpeed:Float = 0.0



'Timer

Local AsteroidTimer:TTimer = TTimer.GetInstance(300)
Local ShipTimer:TTimer = TTimer.GetInstance(200)
Local StarTimer:TTimer = TTimer.GetInstance(40)




Repeat
Cls

GameSpeed = GetGameSpeed(60)


'Kleine Demo. Objekte werden erstellt.
If AsteroidTimer.IsReleased()
   Local TempAsteroid:TAsteroid = TAsteroid.GetInstance()
   Local TempScale:Float = rnd(0.5,1.7)
   TempAsteroid.SetObjektImage(asteroid1_img)
   TempAsteroid.SetObjektColor(255,200+Rand(0,55),200+Rand(0,255))
   TempAsteroid.SetObjektPosition(GraphicsWidth(),rnd(0,GraphicsHeight()))
   TempAsteroid.SetObjektScale(TempScale,TempScale)
   TempAsteroid.Speed = rnd(1.0,5.0)
EndIf


If ShipTimer.IsReleased()
   Local TempShip:TShip= TShip.GetInstance()
   TempShip.SetObjektImage(ship1_img)
   TempShip.SetObjektPosition(GraphicsWidth(),rnd(0,(GraphicsHeight()-ship1_img.height)))
   TempShip.SetObjektRotation(-90)
   TempShip.Speed = rnd(1.0,9.0)
EndIf


If StarTimer.IsReleased()
   Local TempStar:TStar = TStar.GetInstance()
   Local TempSpeed:Float = rnd(1.0,6.0)
   
   TempStar.SetObjektSize(Rand(2,5),Rand(2,5))
   TempStar.SetObjektColor(TempSpeed*(255.0/6.0),TempSpeed*(255.0/6.0),TempSpeed*(255.0/6.0))
   TempStar.SetObjektPosition(GraphicsWidth(),rnd(0,GraphicsHeight()))
   TempStar.Speed = TempSpeed

EndIf


'Alle Objekte werden gerendert und geupdated

TStar.UpdateAndRenderAll()
TAsteroid.UpdateAndRenderAll()
TShip.UpdateAndRenderAll()


'Fps Anzeige
ResetStates()
DrawText GetFPS(),10,10

Flip
FlushMem()
Until KeyHit(KEY_ESCAPE)