Graphics 640,480,32,1
SetBuffer FrontBuffer()

mp3name$=Input$("name der mp3: ")

Global BASS_CMD$ = ""
Global BASS_NME$ = "blitzbass"
Const BASS_2048   = $80000002
If Not BASS_Init(0,44100,0,0) Print "Initalisierung fehlgeschlagen!":Delay 2000:End
Global Bass_Handle = BASS_StreamCreateFile(0,mp3name$,0,0,BASS_SAMPLE_LOOP)
If Not Bass_Handle Print "die datei exesitiert nicht":BASS_Stop():BASS_Free():Delay 2000:End
If Not BASS_Start() Print "bassstart fehlgeschlagen!":BASS_Free():Delay 2000:End
If Not BASS_StreamPlay(Bass_Handle,1,BASS_SAMPLE_LOOP) Print "Abspielen fehlgeschlagen!":BASS_Stop():BASS_Free():Delay 2000:End

SetBuffer BackBuffer()

Global hzstau[321];Frequenzstau: Wahrgenommene 'gleichmässige' Verteilung aller Frequenzen.
Global hzhebe[321];Fraquenzanhebung: Hoche Frequenzen wegen kleinerer Amplitude auch sichtbar anheben.
Global presse[321];Audiocompressor: Geringe Amplitude etwas zur höheren stauchen. Wie Gamma in Grafik.
Global altpos[319];Alte Position: Aus der Differenz wird dann ein spezieller Farbwert berechnet.

y1%=0
y2#=0
y3%=0

;Dekobalken
For q=0 To 199
 Color q/4,q/4,q/2
 Line 0,199-q,640,199-q
 Line 0,400+q,640,400+q
Next

;Hintergrundbild fangen
bild=CreateImage(640,480)
GrabImage bild,0,0

;Vorbereitung
For q=0 To 321
 hzstau[q]=Int(2+(q*q)/140)*4
 hzhebe[q]=Int(q*q+800)/16
 presse[q]=Int(q/Exp(q/320)*12)
Next




;Hauptschleife
While Not KeyDown(1)

 DrawBlock bild,0,0

 SDBank=BASS_ChannelGetData(Bass_Handle,BASS_2048)

 y2=0
 For q=0 To 319
  y1=PeekFloat(sdbank,hzstau[q])*hzhebe[q]
  y1=y1+PeekFloat(sdbank,hzstau[q+1])*hzhebe[q]
  y1=y1+PeekFloat(sdbank,hzstau[q+2])*hzhebe[q]
  y2=y2+(y1-y2)/10
  If y2>255 y2=255

  R=255-q/1.25;Farbwert: Links Rot, rechts nicht
  G=presse[y2]/2;Farbwert: Lautstärke macht Grün
  B=q/1.25;Farbwert: Links nichts, rechts Blau
  R=R+Abs(altpos[q]-y2)*(q)/160;Macht rechts große Lautstärkedifferenzen zu Weiß
  B=B+Abs(altpos[q]-y2)*(319-q)/40;Macht links große Lautstärkedifferenzen zu Weiß

  If R>255 R=255
  If G>255 G=255
  If B>255 B=255
  If R<0 R=0
  If G<0 G=0
  If B<0 B=0

  y3=presse[y2]/10
  altpos[q]=y2

  Color R,G,B
  ;Rect q*2,80-y3/4,2,1+y3
  Rect q*2,400-y3/1.5,2,1+y3
 Next

 Flip
Wend

Bass_Stop()
Bass_Free()
End


;---BASS-Funktionen--- -- - -  -   -


Function BASS_Init(iDevice,iFreq,iFlags,hWnd)
 Local mBankIn,iResult
 mBankIn = CreateBank(16)
 PokeInt mBankIn,0,iDevice
 PokeInt mBankIn,4,iFreq
 PokeInt mBankIn,8,iFlags
 PokeInt mBankIn,12,hWnd
 iResult = CallDLL(BASS_NME,BASS_CMD + "BASS_Init_Wrap",mBankIn)
 FreeBank mBankIn
 Return iResult
End Function


Function BASS_StreamCreateFile(bMem,smp3name$,iOffset,iLength,iFlags)
 Local mBankIn,iStreamHandle,iBankSize
 iBankSize = Len(smp3name$) + 17
 mBankIn = CreateBank(iBankSize)
 PokeInt mBankIn,0,bMem
 PokeInt mBankIn,4,iOffset
 PokeInt mBankIn,8,iLength
 PokeInt mBankIn,12,iFlags
 BASSPokeString mBankIn,smp3name$,16
 iStreamHandle = CallDLL(BASS_NME,BASS_CMD + "BASS_StreamCreateFile_Wrap",mBankIn)
 FreeBank mBankIn
 Return iStreamHandle
End Function


Function BASS_StreamPlay(iStreamHandle,bFlush = False,iFlags = 0)
 Local mBankIn,iResult
 mBankIn = CreateBank(12)
 PokeInt mBankIn,0,iStreamHandle
 PokeInt mBankIn,4,bFlush
 PokeInt mBankIn,8,iFlags
 iResult = CallDLL(BASS_NME,BASS_CMD + "BASS_StreamPlay_Wrap",mBankIn)
 FreeBank mBankIn
 Return iResult
End Function


Function BASS_ChannelGetData(iHandle,iBufferSize)
 Local mBankIn,iResult
 mBankIn = CreateBank(8)
 PokeInt mBankIn,0,iHandle
 PokeInt mBankIn,4,iBufferSize
 mBankOut = CreateBank(4100)
 iResult = CallDLL(BASS_NME,BASS_CMD + "BASS_ChannelGetData_Wrap",mBankIn,mBankOut)
 FreeBank mBankIn
 Return mBankOut
End Function


Function BASS_Start()
 Return CallDLL(BASS_NME,BASS_CMD + "BASS_Start_Wrap")
End Function


Function BASS_Pause()
   Return CallDLL(BASS_NME,BASS_CMD + "BASS_Pause_Wrap")
End Function


Function BASS_Stop()
 Return CallDLL(BASS_NME,BASS_CMD + "BASS_Stop_Wrap")
End Function


Function BASS_Free()
 Return CallDLL(BASS_NME,BASS_CMD + "BASS_Free_Wrap")
End Function


Function BASSPokeString(mBankAddr,sStringOut$,iBufferOffset = 0)
 For n = 1 To Len(sStringOut$)
  PokeByte mBankAddr,iBufferOffset,Asc(Mid$(sStringOut$,n,1))
  iBufferOffset = iBufferOffset + 1
 Next
 PokeByte mBankAddr,iBufferOffset,0
End Function