Strict

Const GFX_X:Int = 1280
Const GFX_Y:Int = 1024

Global Time_mod:Float
Global Time_LastUpdate:Int
Global Time_Now:Int
Global Time_MS:Int

Global GAME_FLIGHTSPEED:Float
Global GAME_OVER:Byte

Graphics GFX_X,GFX_Y


Type TRocket
   Field Image:TImage
   Field X:Float
   Field Y:Float
   
   Field Rotation:Float
   Field Speed:Float
   Field Acceleration:Float
   
   Method New()
      Self.Image = LoadImage("Rocket.PNG")
      MidHandleImage Self.Image
      Self.Acceleration = 10
      Self.X = GFX_X/2
      Self.Y = GFX_Y/2
      Self.Speed = GAME_FLIGHTSPEED
   End Method
   
   Method Draw()
      SetRotation Self.Rotation
      DrawImage Self.Image,Self.X,Self.Y
      SetRotation 0
   End Method
   
   Method Steering()
      If KeyDown(KEY_LEFT) Self.Rotation:- 50.0 * Time_mod
      If KeyDown(KEY_Right) Self.Rotation:+ 50.0 * Time_mod
      If KeyDown(KEY_UP) Self.Speed:+Self.Acceleration * Time_mod
      If KeyDown(KEY_DOWN) Self.Speed:-Self.Acceleration * Time_mod
            
      Self.X:+ Sin(Self.Rotation)*Self.Speed
      Self.Y:- Cos(Self.Rotation)*Self.Speed - GAME_FLIGHTSPEED
      
      'Kollisionen mit dem Rand
      If Self.X > GFX_X-48 Or Self.X < 48
         Self.Rotation = 360-Self.Rotation
      EndIf
      
      If Self.Y < 0
         Self.Speed = 2*GAME_FLIGHTSPEED - Self.Speed
      ElseIf Self.Y > GFX_Y
         GAME_OVER = 1
      EndIf      
   End Method
End Type

Type TBackground
   Field Image:TImage
   Field X:Float
   Field Y:Float
   Field Xspeed:Float
   Field Yspeed:Float
   
   Method Init(Imagepath:String,Xspeed:Float=0,Yspeed:Float=0)
      Self.Image = LoadImage(Imagepath)
      Self.Xspeed = Xspeed
      Self.Yspeed = Yspeed
   End Method
   
   Method SetSpeed(Xspeed:Float,Yspeed:Float)
      Self.Xspeed = Xspeed
      Self.Yspeed = Yspeed
   End Method
   
   Method Draw()
      SetBlend(ALPHABLEND)
      SetScale 1,1
      SetColor 255,255,255
      SetRotation 0
      
      Self.X:+ Self.Xspeed * Time_mod
      Self.Y:+ Self.Yspeed * Time_mod
      TileImage Self.Image,Self.X,Self.Y
   End Method
End Type

Type TStar
   Global StarList:TList
   Global StarImages:TImage[3]
   Global StarSpeed:Float
   Global StarNumber:Int

   Field Art:Byte
   Field R:Byte,G:Byte,B:Byte
   Field Size:Float
   Field X:Float,Y:Float
   Field Speed:Float
   Field Rotation:Float
   Field _link:TLink
   
   Function Init()
      StarSpeed = 5
      StarNumber = 30
      
      For Local i=1 To StarNumber
         Local S:TStar = TStar.Create()
         S.Y = Rand(0,GFX_Y)
      Next
   End Function
      
   
   Function Update()
      If CountList(StarList)<StarNumber
         TStar.Create()
      EndIf
      TStar.Draw
   End Function
   
   Function Create:TStar()
         If StarList:TList = Null
            StarList:TList = New TList
            AutoMidHandle 1
            StarImages[0] = LoadImage("Star1.png")
            StarImages[1] = LoadImage("Star2.png")
            StarImages[2] = LoadImage("Star3.png")
            AutoMidHandle 0
         EndIf
   
         Local S:TStar = New TStar
         S.Art = Rand(0,2)
         S.R = Rand(150,255)
         S.G = Rand(150,255)
         S.B = Rand(150,255)
         S.Size = Rnd(0.5,1.5)
         S.X = Rand (0,GFX_X)
         S.Speed = Rnd(20,50)
         S.Rotation = Rnd(0,360)
         S._link = StarList.Addlast(S)
         Return S
   End Function
   
   Function Draw()
      SetBlend (LIGHTBLEND)
      For Local S:TStar = EachIn StarList
         S.Y:+S.Speed * TIME_mod * StarSpeed
         If S.Y > GFX_Y+50 S.Kill()
         SetColor S.R,S.G,S.B
         SetRotation S.Rotation
         SetScale S.Size,S.Size
         
         DrawImage StarImages[S.Art],S.X,S.Y
      Next
      
      SetBlend(ALPHABLEND)
      SetScale 1,1
      SetColor 255,255,255
      SetRotation 0
   End Function
   
   Method Kill()
      RemoveLink(Self._link)
   End Method
      
End Type
   

GAME_FLIGHTSPEED = 10

Global Player:TRocket = New TRocket
Global Background:TBackground = New TBackground
Background.Init("BG1.png",0,10)
TStar.Init()

Global RandR:TImage = LoadImage("RRand.bmp")
Global RandL:TImage = LoadImage("LRand.bmp")
Global RandY:Float = 0

Time_LastUpdate = MilliSecs()



Repeat
Cls

   Time_Now = MilliSecs()
   Time_MS = Time_Now - Time_LastUpdate
   Time_mod = Time_MS / 1000.0
   Time_LastUpdate = Time_Now
   
   Background.Draw()
   TStar.Update()
   
   RandY = (RandY + GAME_FLIGHTSPEED * TIME_mod * 10) Mod 86
   For Local i= -1 To 12
      DrawImage RandL,0,i * 86 + RandY
      DrawImage RandR,GFX_X-48,i * 86 + RandY
   Next
   
   Player.Steering()
   Player.Draw()

   DrawText Time_mod,10,10
Flip
Until KeyHit(KEY_ESCAPE) Or GAME_OVER

If GAME_OVER
   Cls
   SetColor 255,255,255
   DrawText "GAME OVER",GFX_X,GFX_Y
   Flip
   WaitKey()
EndIf

End