auswahl=0
repeat
  cls
  mx=mousex()
  my=mousey()
  if rectsoverlap(100,100,imagewidth(start),imageheight(start),mx,my,1,1) and mousedown(1) then auswahl=1
  if rectsoverlap(100,400,imagewidth(ende),imageheight(ende),mx,my,1,1) and mousedown(1) then auswahl=2
  drawimage start,100,100
  drawimage ende,100,400
  flip
until auswahl <> 0

SuperStrict

Type TButton

   Global Buttons:TList

   Global PointerDown:Int
   Global PointerClick:Int
   Global PointerRelease:Int

   Field Text:String
   Field X:Int
   Field Y:Int
   Field Width:Int
   Field Height:Int

   Field Hover:Int
   Field Click:Int

   Function Initialize()

      Self.Buttons = CreateList()

   End Function

   Function Create:TButton(Text:String,X:Int,Y:Int,Width:Int,Height:Int)

      Local NewButton:TButton

      NewButton = New TButton
      NewButton.Text = Text
      NewButton.X = X
      NewButton.Y = Y
      NewButton.Width = Width
      NewButton.Height = Height

      Self.Buttons.AddLast(NewButton)
      Return NewButton

   End Function

   Function UpdateAll()

      Local CurrentButton:TButton

      Self.PointerClick = False
      Self.PointerRelease = False
      If MouseDown(1) And Not Self.PointerDown Then
         Self.PointerClick = True
      Else If Not MouseDown(1) And Self.PointerDown Then
         Self.PointerRelease = True
      End If
      Self.PointerDown = MouseDown(1)

      For CurrentButton = EachIn Self.Buttons
         CurrentButton.Update()
      Next

   End Function

   Method Update()

      If MouseX() >= Self.X And MouseX() < Self.X+Self.Width And MouseY() >= Self.Y And MouseY() < Self.Y+Self.Height Then
         Self.Hover = True
      Else
         Self.Hover = False
      End If

      If Self.PointerClick And Self.Hover Then
         Self.Click = True
      Else If Self.PointerRelease Then
         Self.Click = False
         If Self.Hover Then
            PostEvent(CreateEvent(EVENT_GADGETACTION,Self))
         End If
      End If

      ' Draw
      Self.Draw()

   End Method

   Method Draw()

      If Self.Hover Or Self.Click Then
         SetColor(127,127,127)
      Else
         SetColor(63,63,63)
      End If
      DrawRect(Self.X,Self.Y,Self.Width,Self.Height)
      SetColor(255,255,255)
      DrawText(Self.Text,Self.X,Self.Y)

   End Method

   Function DestroyAll()

      Local CurrentButton:TButton

      For CurrentButton = EachIn Self.Buttons
         CurrentButton.Destroy()
         CurrentButton = Null
      Next

   End Function

   Method Destroy()

      Self.Buttons.Remove(Self)

   End Method

End Type

' Beispiel

Graphics(800,600)

TButton.Initialize()

Local BtnStart:TButton = TButton.Create("Start",10,10,200,50)
Local BtnExit:TButton = TButton.Create("Ende",10,70,200,50)

While Not KeyHit(KEY_ESCAPE) And Not AppTerminate()

   Cls

   TButton.UpdateAll()

   Select PollEvent()
      Case EVENT_GADGETACTION
         Select EventSource()
            Case BtnStart
               Notify("Start")
            Case BtnExit
               End
         End Select
   End Select

   Flip

Wend