Graphics3D 800,600,0,1
SetBuffer BackBuffer()

Global Camera=CreateCamera()
MoveEntity Camera,0,40,0
EntityRadius Camera,4
EntityType Camera,1

;CameraFogMode Camera,True
;CameraFogRange Camera,0,150
;CameraFogColor Camera,50,60,70
CameraClsColor Camera,50,60,70

TerrainLoad(32,"highmap.png","colormap.png","detailmap.png")

Collisions 1,2,2,2




While Not KeyHit(1)
   x=x-MouseXSpeed()
   y=y+MouseYSpeed()
   MoveMouse 400,300
   RotateEntity Camera,y,x,0
   If MouseDown(1) Then MoveEntity Camera,0,0,-.1
   If MouseDown(2) Then MoveEntity Camera,0,0,+.1
   If KeyDown(30) Then TranslateEntity Camera,0,+.25,0 Else TranslateEntity Camera,0,-.025,0
   UpdateWorld
   RenderWorld
   Text 20,20,TrisRendered()+" triangles rendered"
   Text 20,40,fps+" FPS":msc=MilliSecs()
   If msc>mts Then mts=msc+1001:fps=frm:frm=0 Else frm=frm+1
   Flip 0
Wend
End




Function TerrainLoad(FTile#=32,FHMap$,FCMap$,FDMap$)
   Local HMap%=LoadTexture(FHMap,1+256)
   Local CMap%=LoadTexture(FCMap,1+256)
   Local DMap%=LoadTexture(FDMap,2+256)
   ScaleTexture DMap,1.0/8.0,1.0/8.0
   If TextureWidth(HMap)<>TextureHeight(HMap) Then RuntimeError "Heighmap hat ungleiche Größe"
   If TextureWidth(CMap)<>TextureHeight(CMap) Then RuntimeError "Colorhmap hat ungleiche Größe"
   If TextureWidth(HMap)<FTile Then RuntimeError "Heighmap ist kleiner als Anzahl Tiles"
   Local H#=TextureWidth(HMap)/FTile
   Local C#=TextureWidth(CMap)/FTile
   
   For zz#=0 To H-1
      For xx#=0 To H-1
         
         Local mesh=CreateMesh()
         Local face=CreateSurface(mesh)
         
         PositionEntity Camera,0,H*12,(xx+zz*H)*(32/H)-((H*FTile)*0.85)
         RotateEntity Camera,60,0,0
         RenderWorld
         UpdateWorld
         Rect 20,40,760,20,0
         Rect 22,42,(1+xx+zz*H/H*H)/(H*H)*756,16,1
         Text 20,20,"create terrain tile: "+Int(1+xx+zz*H)+"/"+Int(H*H)  +"    "+H
         Flip 0:Cls
         
         For z#=0 To FTile
            For x#=0 To FTile
               y#=(ReadPixel(x+xx*FTile,FTile+zz*FTile-z,TextureBuffer(HMap)) And $FF0000)/$10000
               AddVertex(face,x,y/(128/H),-z, xx/H+x/FTile/H,zz/H+1/H-z/FTile/H,0)
            Next
         Next
         
         For z=0 To FTile-1
            For x=0 To FTile-1
               AddTriangle(face,x+z*(FTile+1),x+1+z*(FTile+1),x+1+(z+1)*(FTile+1))
               AddTriangle(face,x+1+(z+1)*(FTile+1),x+(z+1)*(FTile+1),x+z*(FTile+1))
            Next
         Next
         
         MoveEntity mesh,-(FTile*H/2)+xx*FTile,0,FTile-(FTile*H/2)+zz*FTile
;         EntityAutoFade mesh,100,200
         EntityTexture mesh,CMap,0,0
;         EntityTexture mesh,DMap,0,1
;         TextureBlend DMap,5
         UpdateNormals mesh
         EntityType mesh,2
         EntityFX mesh,1
         Collisions 1,2,2,2
      Next
   Next
End Function