;Logo()
SetGfx()

Type GfxMode
   Field width,height,depth
End Type

Function Logo()
   Graphics3D 640,480
   SetBuffer BackBuffer()
   image=LoadImage( "b3dlogo.jpg" )
   If image=0 image=LoadImage( "../b3dlogo.jpg" )
   MidHandle image
   Color 255,0,0
   SetFont LoadFont( "helvetica",16 )
   t=MilliSecs()
   txt1$="(C)opyright Blitz Research Limited"
   txt2$="Published by Guildhall Leisure Services"
   txt3$="Find out more at www.blitz-3d.com"
   yy=320
   Repeat
      Cls
      DrawBlock image,320,yy-120
      Color 0,0,192
      Text 0,480-FontHeight()*2,txt1$
      Text 0,480-FontHeight()*1,txt2$
      Color 0,255,0
      Text 640-StringWidth(txt3$),480-FontHeight()*1,txt3$
      Color 255,0,0
      Text 320,yy+FontHeight()*0,info1$,True,True
      Text 320,yy+FontHeight()*1,info2$,True,True
      Text 320,yy+FontHeight()*2,info3$,True,True
      Text 320,yy+FontHeight()*3,info4$,True,True
      d=MilliSecs()-t
      If d>5000
         If tick=0
            tick=127
            FlushKeys
         Else
            tick=tick-1
            If tick=0 tick=127
         EndIf
         If tick And 64
            Color 255,255,255
            Text 320,yy+FontHeight()*5,"Press any key",True,True
         EndIf
         If GetKey() Then Exit
      EndIf
      Flip
   Forever
   For k=1 To 2
      Cls:Flip
   Next
   FreeImage image
   FlushKeys
End Function

Function SetGfx()
   Print info1$:Print info2$:Print info3$:Print info4$:Print
   If Windowed3D()
      yn$=Input$( "Use windowed mode?" )
      If Left$( Lower$( yn$ ),1 )="y"
         HidePointer
         Graphics3D 640,480,0,2
         SetBuffer BackBuffer()
         Return
      EndIf
   EndIf
   
   Print ""
   Print "Display drivers:"
   Print "----------------"
   For k=1 To CountGfxDrivers()
      Print k+":"+GfxDriverName$(k)
   Next
   
   Print ""
   
   If CountGfxDrivers()>1
      Repeat
         driver=Input$( "Display driver (1-"+CountGfxDrivers()+"):" )
      Until driver>=1 And driver<=CountGfxDrivers()
      SetGfxDriver driver
   EndIf
   
   Print ""
   Print "Display modes:"
   Print "--------------"
   cnt=0
   For k=1 To CountGfxModes()
      If GfxMode3D(k)
         t.GfxMode=New GfxMode
         t\width=GfxModeWidth(k)
         t\height=GfxModeHeight(k)
         t\depth=GfxModeDepth(k)
         cnt=cnt+1
         Print cnt+":"+t\width+","+t\height+","+t\depth
      EndIf
   Next
   
   If Not cnt
      Print "No 3D Graphics modes available!"
      Print "Press any key..."
      WaitKey
      End
   EndIf
   
   Repeat
      mode=Input$( "Display Mode (1-"+cnt+"):" )
   Until mode>=1 And mode<=cnt
   
   t.GfxMode=First GfxMode
   
   While mode>1
      t=After t
      mode=mode-1
   Wend
   
   Graphics3D t\width,t\height,t\depth,1
   SetBuffer BackBuffer()
   
   Delete Each GfxMode

;
; WATERY TERRAIN V1.00
; --------------------
; Creating and modifying terrain entities to create water (err, something that sort
; of resembles water,.. sort of :)). Mainly just to show how to modify terrain to
; create such effects. You could do crashing waves, or water ripples. (Might
; have a crack at that later :))
;
; Written by Rob Hutchinson 2001 for Blitz 3D
; Textures by Rob Hutchinson. Email: loki.sd@cableinet.co.uk / ICQ: 27181384
;
; Created with BB3D Beta 1.57
; Last Modified: 10/08/2001
;

; Modify these if you like :)
Const  WATER_GRID_SIZE = 16
Global WATER_HEIGHT# = 8.2

; Setup the water grid values
Dim WaterY(WATER_GRID_SIZE+1,WATER_GRID_SIZE+1)
For q = 0 To WATER_GRID_SIZE
   For j = 0 To WATER_GRID_SIZE
      WaterY(q,j) = Rnd(0,360)
   Next
Next

; Setup the screen
Include "start.bb"

; Setup the camera
campiv = CreatePivot()
camera = CreateCamera(campiv)
CameraFogMode camera,1
CameraFogRange camera,1,100
MoveEntity campiv,0,5,0
MoveEntity camera,0,1,-10

; Create some terrain and load the water texture onto it
water = CreateTerrain(WATER_GRID_SIZE)
watert = LoadTexture("water.bmp")
ScaleTexture watert,2,2
EntityTexture water,watert
EntityAlpha water,.4

; Create a floor plane and texture it
bed  = CreatePlane()
bedt = LoadTexture("oceanfloor.bmp")
ScaleTexture bedt,15,15
EntityTexture bed,bedt
MoveEntity bed,0,-8,0

; Modify the detail of the terrain
TerrainShading water,True
Global curdetail = 2000
TerrainDetail water,curdetail,True

; Resize and position the water
MoveEntity water,-60,-10,-60
ScaleEntity water,8,WATER_HEIGHT#,8

; Some ambient lighting
AmbientLight 200,200,200

Repeat
   ; Allow the user to switch to wireframe mode.
   If KeyHit(17) Then wire = Not wire
   WireFrame wire

   ; Move the camera around
   RotateEntity campiv,Sin(ll#)*10,ll#,0
   ll# = ll# + 0.2
   PointEntity camera,campiv

   ; Terrain Detail level
   If KeyDown(26) Then curdetail = curdetail - 10
   If KeyDown(27) Then curdetail = curdetail + 10   
   TerrainDetail water,curdetail,True

   ; Here we itterate through all the cells on the terrain grid (switch wireframe on to
   ; see them) and then make them simply bounce up and down.
   For z = 0 To WATER_GRID_SIZE-1
      For x = 0 To WATER_GRID_SIZE-1
         hite# = Sin(WaterY(z,x))
         ModifyTerrain water,x,z,Abs(hite#/2)+.5,False
         WaterY(z,x) = WaterY(z,x) + 1
      Next
   Next

   ; Update the world stuff
   UpdateWorld
   RenderWorld
   
   ; Print some simple details on screen.
   Text 0,0,"W = Wireframe Toggle"
   Text 0,12,"LOD = [ and ]  (" + curdetail + ")"
   
   ; Flip display
   Flip
Until KeyDown(1)

; Terminate.
End