Global g_s,g_frames
Global aktx,akty
Global i,j
;image=kreisani(Frame-Seitenlänge,Frames,Farbe1-Rot,Farbe1-Grün,Farbe1-Blau,Farbe2-Rot-Farbe2-Grün,Farbe2-Blau)
;frames nur Quadrate!! Also 4,9,16,25,36,...
Local img=kreisani(70,49,0,0,0,200,0,0)

;Präsentation des erzeugten Images
Local istep=1
AppTitle("ESC=Beenden")
i=0
Repeat
   i=(i+istep)
   If i>g_frames-2 Or i<1 Then istep=-istep
   For j=0 To g_frames-1
      aktx=(j Mod Ceil(Sqr(g_frames)))*g_s
      akty=Floor(j/Ceil(Sqr(g_frames)))*g_s
      DrawBlockRect(img,aktx,akty,(i Mod Ceil(Sqr(g_frames)))*g_s,Floor(i/Ceil(Sqr(g_frames)))*g_s,g_s,g_s)
   Next
   Flip 0 : Cls
   Delay (1000/(g_frames*4)) ;Wartezeit auf Frames anpassen
Until KeyHit(1)
End

Function kreisani(s,frames,col1_r,col1_g,col1_b,col2_r,col2_g,col2_b)
   ;Initialisierung
   g_frames=frames : g_s=s
   AppTitle "ESC=Abbrechen"
   Local wh=Ceil(Sqr(frames))*s
   Local col,img
   Local aktr
   Local range=2
   Local faktor=(range*2+1)^2
   Local y,x,r,g,b,dx,dy
   Graphics wh,wh,0,2
   SetBuffer BackBuffer()
   ;Hintergrund
   Color col2_r,col2_g,col2_b
   Rect 0,0,wh,wh
   
   For j=0 To frames-1
      ;Für den aktuellen Frame vorbereiten
      aktx=(j Mod Ceil(Sqr(frames)))*s
      akty=Floor(j/Ceil(Sqr(frames)))*s
      Viewport(aktx,akty,s,s)
      aktr=(Float(s)/frames)*(j+1)
      DebugLog aktr
      
      ;Kreismuster erzeugen (5 sich überschneidende Kreise)
      If radial(aktx+s/2,akty+s/2,aktr/2,col1_r,col1_g,col1_b,col2_r,col2_g,col2_b)=1 Then Goto ende
      If radial(aktx,akty,aktr/2,col1_r,col1_g,col1_b,col2_r,col2_g,col2_b)=1 Then Goto ende
      If radial(aktx+s,akty,aktr/2,col1_r,col1_g,col1_b,col2_r,col2_g,col2_b)=1 Then Goto ende
      If radial(aktx,akty+s,aktr/2,col1_r,col1_g,col1_b,col2_r,col2_g,col2_b)=1 Then Goto ende
      If radial(aktx+s,akty+s,aktr/2,col1_r,col1_g,col1_b,col2_r,col2_g,col2_b)=1 Then Goto ende
      
      ;Blur nur wenn:
      ;Radius über 45, oder Radius im mittleren Bereich der Animation
      If aktr>(s/3)*2 Or aktr<(s/3) Or aktr>45 Then
         For y=akty+range To akty-range+s-1
            LockBuffer
            For x=aktx+range To aktx-range+s-1
               r=0:g=0:b=0
               If KeyHit(1) Then Goto ende
               For dx=-range To range
                  For dy=-range To range
                     col=ReadPixelFast(x+dx,y+dy)
                     r=r+((col Shr 16) And 255)
                     g=g+((col Shr 8) And 255)
                     b=b+(col And 255)
                  Next
               Next
               WritePixelFast x,y,r/faktor Shl 16+g/faktor Shl 8+b/faktor
            Next
            UnlockBuffer
            Flip 0
         Next
      EndIf
   Next
   
   .ende
   ;Image erzeugen, Benutzereingabe
   img=CreateImage(wh,wh)
   CopyRect(0,0,wh,wh,0,0,BackBuffer(),ImageBuffer(img))
   AppTitle "ESC=Animation, Leertaste=Speichern"
   FlushKeys()
   Repeat
      If KeyHit(57) Then
         SaveBuffer(FrontBuffer(),"animation.bmp")
         AppTitle "ESC=Animation"
      EndIf
      Delay 20
   Until KeyHit(1)
   SetBuffer BackBuffer()
   Return img
End Function

Function radial(sx,sy,r,col1_r,col1_g,col1_b,col2_r,col2_g,col2_b)
   ;Radial-Farbverlauf
   Local winkel,tmpr,tmpg,tmpb
   For i=0 To r-1
      If KeyHit(1) Then Return 1
      tmpr=col1_r+i*Float(col2_r-col1_r)/r
      tmpg=col1_g+i*Float(col2_g-col1_g)/r
      tmpb=col1_b+i*Float(col2_b-col1_b)/r
      For winkel=0 To 359
         ;Kein WritePixelFast, weil dieser Befehl den Viewport ignoriert!
         WritePixel sx+Cos(winkel)*i,sy+Sin(winkel)*i,tmpr Shl 16+tmpg Shl 8+tmpb
      Next
      Flip 0
   Next
End Function