Import irrlicht.simpleirr

InitIrrlicht
Graphics3D 1024, 768, 32

' PAK hinzufügen
AddZip("pack.pak")

' BSP Map laden
bspnode   = LoadBSP("maps/shadowtest.bsp", True)

' Kamera erstellen
cam = CreateFPSCamera()
PositionEntity(cam, 0.0, 130, 320)

' Licht erstellen
l = CreateLight(LIGHT_POINT)
PositionEntity(l, 0.0, 152.0, -64)
LightRange(l, 320)

' Spinne laden
beast = LoadAnimMesh("beast.b3d", True)

EntityTexture(beast, LoadTexture("beast1.jpg"), 0)
EntityTexture(beast, LoadTexture("spec_beast.jpg"), 1)


PositionEntity(beast, -56.0, -56.0, 128.0)
SetAnimSpeed(beast, 20.0)
SetFrameLoop(beast, 332, 380)

PointEntity(cam, beast)

SetShadowColor(90, 0, 0, 0)
SetFog(True)
ClsColor(120, 190, 255)


rem
   ==========================================================
   Noch ein bissl OOP für die Sachen die noch nicht
   implementiert sind. Über die globale Variable "simpleirr"
   kommt man auch in prozedualen Programmen noch an die
   verschiedenen Treiber.
   ==========================================================
endrem

' Licht-Billboard
Local bb:IBillboardSceneNode = simpleirr.irr_scene.addBillboardSceneNode(Null, _DIMENSION2DF(50, 50), _VECTOR3DF(0.0, 152.0, -64.0))
bb.setMaterialFlag(EMF_LIGHTING, False)
bb.setMaterialType(EMT_TRANSPARENT_ADD_COLOR)
bb.setMaterialTexture(0, simpleirr.irr_video.getTexture("particlewhite.bmp"))

' Logo
Local logo_pos:Position2di = Position2di.Create()
logo_pos.setX(simpleirr.screensize.getWidth()-275)
logo_pos.setY(simpleirr.screensize.getHeight()-84)

Local logo:IGUIImage = simpleirr.irr_gui.addImageFromTexture(simpleirr.irr_video.getTexture("sirr.png"), logo_pos)

' ein bisschen Text
Local skin:IGUISkin = simpleirr.irr_gui.getSkin()
Local fnt:IGUIFont = simpleirr.irr_gui.getFont("fontlucida.png")
If fnt Then skin.setFont(fnt) Else DebugLog "no font"

Local info:IGUIStaticText = simpleirr.irr_gui.addStaticText("FPS: ", _RECTI(2, 2, 300, 50))
info.setOverrideColor(_SCOLOR(255, 255, 255, 255))



lastFPS = -1
Repeat   
   RenderWorld()
   
   If isKeyDown(KEY_SPACE) Then SetFrameLoop(beast, 122, 150)

   cf = GetCurrentFrame(beast)
   If cf >=149 And cf <= 150 Then SetFrameLoop(beast, 332, 380)
   
   fps = getFPS()
   If fps <> lastFPS
      info.setText("FPS: " + String(fps))
      lastFPS = fps
   EndIf
Until isKeyDown(KEY_ESCAPE)

dropIrrlicht()
End

SuperStrict

Framework irrlicht.simpleirr

Local irr:TIrrlicht = TIrrlicht.Init(EDT_OPENGL)
irr.Graphics3D(1024, 768, 32)

' PAK hinzufügen
irr.AddZip("pack.pak")

' BSP Map laden
Local bspnode:TBSPLevel   = TBSPLevel.LoadBSP("maps/shadowtest.bsp", True)

' Kamera erstellen
Local cam:TCamera = TCamera.CreateFPS()
cam.Position(0.0, 130, 320)

' Licht erstellen
Local l:TLight = TLight.Create(LIGHT_POINT)
l.Position(0.0, 152.0, -64)
l.SetRange(320)

' Spinne laden
Local beast:TAnimMesh = TAnimMesh.LoadAnimMesh("beast.b3d", True)

beast.SetTexture(TTexture.Load("beast1.jpg"), 0)
beast.SetTexture(TTexture.Load("spec_beast.jpg"), 1)

beast.Position(-56.0, -56.0, 128.0)
beast.SetAnimSpeed(20.0)
beast.SetFrameLoop(332, 380)

cam.Point(beast)

irr.ShadowColor(90, 0, 0, 0)
irr.SetFog(True)
irr.ClsColor(120, 190, 255)


rem
   ==========================================================
   Hier kommen noch ein paar Sachen die ich noch nicht
   vereinfacht habe. Aber dank irr:TTIrrlicht kommen wir
   ja an alle Details von irrlicht.core heran.
   ==========================================================
endrem
' Sprites sind noch nicht implementiert
Local bb:IBillboardSceneNode = irr.irr_scene.addBillboardSceneNode(Null, _DIMENSION2DF(50, 50), _VECTOR3DF(0.0, 152.0, -64.0))
bb.setMaterialFlag(EMF_LIGHTING, False)
bb.setMaterialType(EMT_TRANSPARENT_ADD_COLOR)
bb.setMaterialTexture(0, irr.irr_video.getTexture("particlewhite.bmp"))

' GUI ist noch nicht implementiert
Local logo_pos:Position2di = Position2di.Create()
logo_pos.setX(irr.screensize.getWidth()-275)
logo_pos.setY(irr.screensize.getHeight()-84)

Local logo:IGUIImage = irr.irr_gui.addImageFromTexture(irr.irr_video.getTexture("sirr.png"), logo_pos)

Local skin:IGUISkin = irr.irr_gui.getSkin()
Local fnt:IGUIFont = irr.irr_gui.getFont("fontlucida.png")
If fnt Then skin.setFont(fnt) Else DebugLog "no font"

Local info:IGUIStaticText = irr.irr_gui.addStaticText("FPS: ", _RECTI(2, 2, 300, 50))
info.setOverrideColor(_SCOLOR(255, 255, 255, 255))



Local lastFPS:Int = -1
Repeat   
   irr.RenderWorld()
   
   If irr.isKeyDown(KEY_SPACE)
      beast.SetFrameLoop(122, 150)
   End If
   Local cf:Int = beast.CurrentFrame()
   If cf >=149 And cf <= 150 Then beast.SetFrameLoop(332, 380)
   
   Local fps:Int = irr.getFPS()
   If fps <> lastFPS
      info.setText("FPS: " + String(fps))
      lastFPS = fps
   EndIf
Until irr.isKeyDown(KEY_ESCAPE)
irr.dropIrrlicht()
End