SuperStrict
rem
		Test um ein Bild zur Laufzeit zu erstellen...
endrem

Graphics(800, 600, 0, 60)
SetBlend(ALPHABLEND)
AutoMidHandle(True)

Local Bild:TImage = CreateImage(64, 64)
Cls
SetColor(255, 0, 0)
DrawOval(16, 16, 32, 32)
SetColor(255, 255, 255)
DrawLine(0, 0, 0, 63)
DrawLine(0, 63, 63, 63)
DrawLine(63, 63, 63, 0)
DrawLine(63, 0, 0, 0)
GrabImage(Bild, 0, 0)
rem 
		Breite und Höhe des erstellten Bildes werden ab der Position von
		Grabimage vom Backbuffer eingelesen.
endrem
DrawText("Bild erstellt, bitte Taste drücken!", 300, 300)
Flip
WaitKey()

'* Testschleife:
Local w:Int, a:Float

Repeat
	
	'*** Testrechteck ob Alpha tatsächlich da ist, oder nur schwarz:
	SetRotation(0) ;SetAlpha(1)
	DrawRect(400, 300, 50, 50)

	'*** Das Gegrabte Bild:
	w = (w + 1) Mod 360 ; SetRotation(w)
	a = (a + 0.005) Mod 1 ; SetAlpha(a)
	DrawImage(Bild, 400, 300)
	
	Flip
	Cls
Until KeyHit(KEY_ESCAPE) Or AppTerminate()

'http://www.blitzbasic.com/Community/posts.php?topic=77549#867760

SuperStrict


Type TNPCs
	Global list:TList = CreateList()
	
	Field x:Int, y:Int, Leben:Int, Mana:Int
	
	Method New()
		list.AddLast(Self)
	End Method
	
	Function DrawList()
		Print("- - - - - - -")
		For Local npc:TNPCs = EachIn TNPCs.list
			Print(npc.y)
		Next
	End Function
	
	Function SortY:Int(o1:Object, o2:Object)
		Local n1:TNPCs = TNPCs(o1)
		Local n2:TNPCs = TNPCs(o2)
		Return n1.y - n2.y
	End Function
	
End Type

For Local i:Int = 0 To 20
	Local npc:TNPCs = New TNPCs
	npc.x = Rand(0, 800)
	npc.y = Rand(0, 600)
	npc.leben = Rand(10, 100)
	npc.Mana = Rand(10, 100)
Next

Local Start:Float = MilliSecs()
TNPCs.DrawList()
TNPCs.list.Sort(True, TNPCs.SortY)
TNPCs.DrawList()
TNPCs.list.Sort(False, TNPCs.SortY)
TNPCs.DrawList()
Local Dauer:Float = (MilliSecs() - Start)
Print("2 mal sortiert in " + Dauer + " ms")

'* THighScore
Type THighScore
	Field name:String, points:Int
	Global list:TList = CreateList()
	
	Method New()
		rem
			werden neue einträge vorne angehangen, werden bei gleichem Punktwert neue
			Einträge oben eingefügt - gibt dem Spieler ein größeres Erfolgserlebnis.
		endrem
		list.AddFirst(Self)
	End Method
	
	Method Compare:Int(H2:Object)
		rem
			Überladung der Compare-Methode erlaubt das Sortieren der Liste mit Sort()
			Sortierung erfolgt natürlich nach Punkten.
		endrem
		Return THighScore(H2).points - Self.points
	End Method
	
	Function Load()
		If FileType("H.score") = 0 Then
			'* Neuer Highscore / erster Start
			For Local i:Int = 0 Until 10
				THighScore.Add("Xeres", Rand(0, 9))
			Next
		Else
			'* Alten Highscore lesen.
			Local f:TStream = OpenFile("H.score")
			For Local i:Int = 0 Until 10
				Local l:Int = f.ReadInt()
				Local n:String = f.ReadString(l)
				Local p:Int = f.ReadInt()
				THighScore.Add(n, p)
			Next
			CloseFile(f)
		EndIf
	End Function
	
	Function Save()
		THighScore.list.Sort()
		Local f:TStream = WriteFile("H.score")
		'* Nur die ersten 10 Plätze werden gespeichert.
		For Local i:Int = 0 Until 10
			Local H:THighScore = THighScore(THighScore.list.ValueAtIndex(i))
			f.WriteInt(H.name.Length)
			f.WriteString(H.name)
			f.WriteInt(H.points)
		Next
		CloseFile(f)
	End Function
	
	Function Add(_name:String, _points:Int)
		Local H:THighScore = New THighScore
		H.name = _name
		H.points = _points
	End Function
	
End Type