Local func:Int() 'Das ist eine Deklaration für einen Funktionszeiger
func=func1 'Die Wertzuweisung funktioniert wie bei anderen Variablen.
'Man kann die Funktion, auf die der Funktionszeiger zeigt, dann wie gewohnt aufrufen:
Print func() 'gibt "1" aus

func=func2
Print func() 'gibt "42" aus

Function func1:Int()
   Return 1
EndFunction
Function func2:Int()
   Return 42
EndFunction

Type TButton
   Field OnPressed(button:TButton)
   Method Update()
      'If 'Der Button wurde betätigt.
         If OnPressed 'wurde eine Funktion zugewiesen?
            OnPressed(Self)
         EndIf
      'EndIf
   EndMethod
EndType

Local button:TButton=New TButton
button.OnPressed=Test

button.Update()

Function Test(button:TButton)
   Print "Der Button wurde gedrückt!"
EndFunction

Function FindNearest:Int[](points:Int[][],base:Int[],distance:Float(point1:Int[],point2:Int[]))
   Local nearest:Int[]
   Local minDist:Float
   For Local i:Int=0 Until points.length
      Local newDist:Float=distance(points[i],base)
      If newDist<minDist Or nearest=Null
         nearest=points[i]
         minDist=newDist
      EndIf
   Next
   Return nearest
EndFunction

Function Manhattan:Float(point1:Int[],point2:Int[])
   Local dist:Float=0.0
   For Local d:Int=0 Until point1.length
      dist:+Abs(point1[d]-point2[d])
   Next
   Return dist
EndFunction
Function Euklid:Float(point1:Int[],point2:Int[])
   Local dist:Float=0.0
   For Local d:Int=0 Until point1.length
      dist:+(point1[d]-point2[d])^2
   Next
   Return dist
EndFunction

'Test
Local points:Int[][]=[ [3,0],[2,2] ]
Local nearest:Int[]=FindNearest(points,[0,0],Manhattan)
Print nearest[0]+","+nearest[1] '3,0
nearest=FindNearest(points,[0,0],Euklid)
Print nearest[0]+","+nearest[1] '2,2