;BB3Ds Terrain Interpolation Bug (tested version: BB3D V1.106)
;-----------------------------------------------------------

;> feel free to change the 'random_mode'
;and 'invert' vars to get some different
;terrain types...

;> use the steps-parameter for the step size
;of the 'grid'...

;> You should notice how some calculated
;interpolated y-coordinates of the terrain
;are lying under the surface while some other
;calculated coords are lying above of it...

;(note the grid-cubes or move with the red
;sphere over terrain)

;(the wrong interpolation can be critical even
;for a quite smooth terrain, e.g. if you want
;to set some small items on terrain which won't
;be visible in some cases...)

Global random_mode=2 ;valid: 0,1,2
Global invert=1 ;valid: 0,1
Global steps=4

;-----------------------------------------------------------

SeedRnd MilliSecs()

Global set_scrx=800
Global set_scry=600

;### Graphics
Graphics3D set_scrx,set_scry,32,2
SetBuffer BackBuffer()

;### Terrain
Global ter_size=8
Global x_scale=100
Global y_scale=200
Global z_scale=100
Global ter=CreateTerrain(ter_size)
ScaleEntity ter,x_scale,y_scale,z_scale
TerrainDetail ter,10000,1
TerrainShading ter,1
EntityPickMode ter,2

;texture
If FileType("mossyground.bmp") Then
   EntityTexture ter,LoadTexture("mossyground.bmp")
Else
   EntityColor ter,0,64,0
EndIf

If invert Then
   For x=0 To ter_size
      For z=0 To ter_size
         ModifyTerrain(ter,x,z,1.)
      Next
   Next
EndIf

Select random_mode
   Case 0 ;random distort
      For x=0 To ter_size
         For z=0 To ter_size
            ModifyTerrain(ter,x,z,Rnd(0.,1.))
         Next
      Next
   Case 1 ;big hill/valley
      For xp=ter_size/2-1 To ter_size/2+1
         For zp=ter_size/2-1 To ter_size/2+1
            ModifyTerrain(ter,xp,zp,0.5)
         Next
      Next
   Case 2 ;random hills/valleys
      For i=1 To 10
         xp=Rand(0,ter_size)
         zp=Rand(0,ter_size)
         ModifyTerrain(ter,xp,zp,0.5)
      Next
End Select

;'grid'
If steps>0 Then
   For x=0 To ter_size*steps
      For z=0 To ter_size*steps
         cube=CreateCube()
         ScaleEntity cube,2,2,2
         xp=x*x_scale/steps
         zp=z*z_scale/steps
         PositionEntity cube,xp,TerrainY(ter,xp,0,zp),zp
      Next
   Next
EndIf

;### Scene
Global cam=CreateCamera()
PositionEntity cam,ter_size/2*x_scale,200,ter_size/2*z_scale
CameraRange cam,1,5000

Global light=CreateLight()
RotateEntity light,45,0,0

sphere=CreateSphere()
ScaleEntity sphere,2,2,2
EntityColor sphere,255,0,0

HidePointer

;### update stuff
While Not KeyDown( 1 )

   ;### CAMERA MOVEMENT
   ;L-Shift
   If KeyDown(42) Then
      dist=10
   Else
      dist=2
   EndIf
   mxs#=MouseXSpeed()
   mys#=MouseYSpeed()
   ;right MB
   If MouseDown(2) Then
      MoveMouse set_scrx/2,set_scry/2
      If mxs#<>0. Then camyaw#=camyaw#-mxs#*0.2
      If mys#<>0. Then campitch#=campitch#+mys#*0.2
      RotateEntity cam,campitch#,camyaw#,0.
   EndIf
   ;W,A,S,D
   If KeyDown(17) Then MoveEntity cam,0,0,dist
   If KeyDown(30) Then MoveEntity cam,-dist,0,0
   If KeyDown(31) Then MoveEntity cam,0,0,-dist
   If KeyDown(32) Then MoveEntity cam,dist,0,0

   ;### PICK TERRAIN
   CameraPick(cam,MouseX(),MouseY())
   in_pe=PickedEntity()
   If in_pe=ter Then
      in_px#=PickedX()
      in_py#=PickedY()
      in_pz#=PickedZ()
      PositionEntity sphere,in_px#,TerrainY(ter,in_px#,0,in_pz#),in_pz#
   EndIf

   If KeyHit(57) Then
      wf=1-wf
      WireFrame wf
   EndIf

   ;### RENDER WORLD
   RenderWorld

   ;### INFO STUFF
;   Text 0,0,"M - switch mode (current: "+mode+")"
   Text 0,16,"W,A,S,D - Camera Movement (L-SHIFT for faster movement)"
   Text 0,32,"Right Mouse Button + Drag to rotate Cam"
   Text 0,48,"SPACEBAR - wireframe on/off"

   Flip

Wend

Gridx=32
Gridz=32

Gridx=320
Gridz=320

Read track

track=Rand(1,8)