Graphics3D 200,240,0,2
AppTitle "Tetris ©Darth"

Const xfeld=20 , yfeld=20

Dim feld(15,27)
 For x=0 To 15 : feld(x,24)=1 : Next
 For y=0 To 25 : feld(2,y)=1 : feld(13,y)=1 : Next
;steine deklarieren
Dim steintyp(6,3,3)
 steintyp(0,1,1)=1 : steintyp(0,2,1)=1 : steintyp(0,1,2)=1 : steintyp(0,2,2)=1
 steintyp(1,2,0)=1 : steintyp(1,2,1)=1 : steintyp(1,2,2)=1 : steintyp(1,2,3)=1
 steintyp(2,2,1)=1 : steintyp(2,1,2)=1 : steintyp(2,2,2)=1 : steintyp(2,1,3)=1
 steintyp(3,1,1)=1 : steintyp(3,1,2)=1 : steintyp(3,2,2)=1 : steintyp(3,2,3)=1
 steintyp(4,1,1)=1 : steintyp(4,1,2)=1 : steintyp(4,1,3)=1 : steintyp(4,2,3)=1
 steintyp(5,2,1)=1 : steintyp(5,2,2)=1 : steintyp(5,1,3)=1 : steintyp(5,2,3)=1
 steintyp(6,0,1)=1 : steintyp(6,1,1)=1 : steintyp(6,2,1)=1 : steintyp(6,1,2)=1
Dim aktstein(3,3) : Dim tmpstein(3,3)

create=1 : SeedRnd(MilliSecs())
zeit=350 : tmpzeit=zeit : k=Rnd(0,5)

While Not KeyHit(1)

;GuI zeichnen
Color 125,125,125
 Rect xfeld-20,yfeld-20,140,240
 Rect xfeld+120,yfeld-20,60,20
 Rect xfeld+160,yfeld,20,40
 Rect xfeld+120,yfeld+40,60,180
Color 0,0,0
 Text xfeld+120,yfeld+60,"POINTS:"
 Text xfeld+130,yfeld+80,point
 Text xfeld+120,yfeld+120,"LEVEL:"
 Text xfeld+130,yfeld+140,Int(point/100)

;feld zeichnen
Color 255,255,255: Rect xfeld,yfeld,100,200
For x=0 To 10
 Color 0,0,0: Rect xfeld+x*10,yfeld,1,200
Next

;stein zeichnen
For x=0 To 3 : For y=0 To 3
 If aktstein(x,y)=1 Then
  If y*10+ykoo>(yfeld-10) Then
   Color 255,0,0 : Rect x*10+xkoo,y*10+ykoo,10,10
   Color 0,0,0 : Rect x*10+xkoo,y*10+ykoo,10,10,0
  EndIf
 EndIf
 ;nächster stein
 If steintyp(k,x,y)=1 Then
  Color 255,0,0
 Else
  Color 255,255,255
 EndIf
  Rect xfeld+120+x*10,yfeld+y*10,10,10
Next : Next

;felder zeichnen
For y=4 To 23 ;0 to 27
 linie=0
 For x=3 To 12 ;0 to 15
  If feld(x,y)=1 Then
   Color 0,150,0 : Rect xfeld-30+x*10,yfeld-40+y*10,10,10
   If x>2 And x<13 And y>2 And y<24 Then linie=linie+1
   ;If y=3 And x>2 And x<13 Then RuntimeError "YOU LOST!"
  EndIf
  If feld(x,3)=1 Then RuntimeError "YOU LOST!"
 Next
 ;linie löschen
 If linie=10 Then
  point=point+10
  If point Mod 100=0 Then zeit=zeit-5 : point=point+10
  For x1=3 To 12
   feld(x1,y)=0
  Next
  For x1=3 To 12 : For y1=(y-1) To 0 Step -1
   ;If feld(x1,y1)=1 Then feld(x1,y1+1)=1 : feld(x1,y1)=0
   feld(x1,y1+1)=feld(x1,y1) : feld(x1,y1)=0
  Next : Next
 EndIf
Next

If pause=0

 ;stein erstellen
 If create=1 Then
  zeit=tmpzeit
  xkoo=xfeld+30 : ykoo=yfeld-40
  For x=0 To 3 : For y=0 To 3
   aktstein(x,y)=steintyp(k,x,y)
   tmpstein(x,y)=aktstein(x,y)
  Next : Next
  create=0
  k=Rnd(0,6)
 EndIf

 If MilliSecs()-akttime>250 Then

  ;bewegung nach links
  If KeyDown(203) Then
   col=collide(xkoo-10,ykoo)
   If col=0 Then xkoo=xkoo-10
   akttime=MilliSecs()
  EndIf

  ;bewegung nach rechts
  If KeyDown(205) Then
   col=collide(xkoo+10,ykoo)
   If col=0 Then xkoo=xkoo+10
   akttime=MilliSecs()
  EndIf

  ;drehung uhrzeigersinn
  If KeyDown(200) Then
   For x=0 To 3 : For y=0 To 3
    aktstein(x,y)=tmpstein(y,3-x)
    ;aktstein(x,y)=tmpstein(3-y,x)
   Next : Next
   col=collide(xkoo,ykoo)
   For x=0 To 3 : For y=0 To 3
    If col=0 Then
     tmpstein(x,y)=aktstein(x,y)
    Else
     aktstein(x,y)=tmpstein(x,y)
    EndIf
   Next : Next
   akttime=MilliSecs()
  EndIf

 EndIf

 If KeyHit(208) Then tmpzeit=zeit : zeit=0
 ;If KeyDown(203)=0 And KeyDown(205)=0 And KeyDown(200)=0 Then akttime=0

 ;bewegung nach unten
 If MilliSecs()-downtime>zeit Then
  col=collide(xkoo,ykoo+10)
  If col=1 Then
   create=1
   For x=0 To 3 : For y=0 To 3
    If aktstein(x,y)=1 Then feld((xkoo-xfeld)/10+x+3,(ykoo-yfeld)/10+y+4)=1
   Next : Next
  EndIf
  ykoo=ykoo+10 : downtime=MilliSecs()
 EndIf

Else
 Color 0,0,150 : Text xfeld+10,yfeld+50,"P A U S E"
EndIf
If KeyHit(25) Then pause=1-pause

Flip 0 : Cls
Wend : End

Function collide(xk,yk)
 col=0
 For y=0 To 3 : For x=0 To 3
  If aktstein(x,y)=1 Then
   If feld((xk-xfeld)/10+x+3,(yk-yfeld)/10+y+4)=1 Then
    col=1
   EndIf
  EndIf
 Next : Next
 Return col
End Function