; Werte: Blender(Grafikhandle,xpos,ypos,ein/ausblenden,zeit_in_Millisecs)

img=LoadImage(\"gfx/1.bmp\")

Blender(img,170,190,0,3000)
Delay 1000
Blender(img,170,190,1,2000)

; Die eigentliche Function

Function Blender(Image, X, Y, Mode,Time)
	Source=ImageBuffer(Image)
	Dest  =FrontBuffer()
	MaxX  =ImageWidth(Image)-1
	MaxY  =ImageHeight(Image)-1
	Start =MilliSecs()
	Color 0,0,0
	If Mode=0 Then Rect X,Y,MaxX+1,MaxY+1
	If Mode=1 Then DrawBlock Image,X,Y
	LockBuffer Source
	LockBuffer Dest
	While MilliSecs()-Start<Time
		Count=(Count+1) Mod 4
		If Count=0 Then MinX=0: MinY=0
		If Count=1 Then MinX=1: MinY=1
		If Count=2 Then MinX=1: MinY=0
		If Count=3 Then MinX=0: MinY=1
		If Mode=0 Then Value=MilliSecs()-Start
		If Mode=1 Then Value=Time-MilliSecs()+Start
		For ii=MinY To MaxY Step 2
			For i=MinX To MaxX Step 2
				rgb=ReadPixelFast(i,ii,Source)
				rgb=(rgb And 16711680)/65536*Value/Time*65536+(rgb And 65280)/256*Value/Time*256+(rgb And 255)*Value/Time
				WritePixelFast X+i,Y+ii,rgb,Dest
			Next
		Next
	Wend
	UnlockBuffer Source
	UnlockBuffer Dest
	If Mode=0 Then DrawBlock Image,X,Y
	If Mode=1 Then Rect X,Y,MaxX+1,MaxY+1
End Function