;Beispiel / Benutzereingabe
Local in$
Repeat
	in$=Input("Eingabe: ")
	If in$="" Then Exit
	ProcessUPN(in$)
Forever
End

;Hauptfunktion
Function ProcessUPN(in$)
	;Vars
	Local space
	Local element$
	in$=Trim(in$)+" "
	
	stack_flush()
	;Start
	Repeat
		;linkestes Element heraus schneiden...
		space=Instr(in$," ")
		element$=Left(in$,space-1)
		;...und verarbeiten
		If element$=Int(element$) Or Instr(element$,".")>0 Then
			;Element ist eine Zahl
			stack_push(Float(element$))
		Else
			;Element ist ein Operator
			Calc(element$)
		EndIf
		
		in$=Right(in$,Len(in$)-space)
		If in$="" Then Exit
	Forever
	;Ausgabe
	PrintUPN()
End Function

;Führt die Berechnung je nach operation durch unter Verwendung des Stacks
;Erweiterungen wie zB Sin / Cos durch einfaches Ergänzen der Select-Case-Abfrage möglich
Function Calc(operator$)
	Local result#
	Local a#,b#
	Select operator$
		Case "+"
			;Elemente in umgekehrter Reihenfolge vom Stack holen
			b#=stack_pop()
			a#=stack_pop()
			;Ergebnis berechnen
			result#=a+b
		Case "-"
			b#=stack_pop()
			a#=stack_pop()
			result#=a-b
		Case "/"
			b#=stack_pop()
			a#=stack_pop()
			result#=a/b
		Case "*"
			b#=stack_pop()
			a#=stack_pop()
			result#=a*b
		Default
			;Wenn keine bekannte Operation angegeben wird
			RuntimeError(operator$+" ist keine gültige Operation")
	End Select
	;Ergebnis auf Stack schreiben
	stack_push(result#)
End Function

;Inhalt des UPN-Stacks ausgeben (Achtung, Stack wird dabei geleert - nur für Endergebnis gedacht!)
Function PrintUPN()
	While Not stack_empty
		Print stack_pop#()
	Wend
End Function

;Minimal-Implementierung eines (Float-)Stacks
Type stack
	Field val#
End Type
Global stack_empty=True

Function stack_push(var#)
	Local stack.stack=New stack
	stack\val#=var#
	stack_empty=False
End Function

Function stack_pop#()
	Local stack.stack=Last stack
	If stack=Null Then
		RuntimeError("Keine Elemente mehr auf Stack")
	EndIf
	Local ret#=stack\val#
	Delete stack
	If First stack=Null Then
		stack_empty=True
	EndIf
	Return ret#
End Function

Function stack_flush()
	Delete Each stack
	stack_empty=True
End Function