Global ResX = 1024
Global ResY = 768

Graphics ResX, ResY, 16, 2
SetBuffer BackBuffer()

SeedRnd MilliSecs()

Type Car
 Field x,y,s#,w#,acceleration#, maxspeed#, id
End Type

Global CountCar, minspeed#=100, maxspeed#, Debug

For w = 20 To 360 Step 20
 CreateCar(w)
Next


Repeat
 Cls

  Text 0,0, "Minspeed: " + minspeed*100 + "km/h"
  Text 0,10,"Maxspeed: " + maxspeed*100 + "km/h"

  Text 0,25,"Press s to slow down the creen car or press f to drive faster"
  Text 0,35,"Press d to show/hide speed" : If KeyHit(32) Then Debug = Debug Xor 1
 
  DrawCar()
  UpdateCar()
  ControlCar()

 Flip
Until KeyHit(1)
End


Function ControlCar()
 c.car = First car
 If KeyDown(31) Then c\s = c\s -0.01
 If KeyDown(33) Then c\s = c\s +0.01
 If c\s < 0 Then c\s = 0
End Function

Function CreateCar(w)
 c.car = New car
 c\w = w
 c\x = ResX / 2 + Cos(c\w) * 293
 c\y = ResY / 2 + Sin(c\w) * 293
 c\s = Rnd(1, 1)
 c\acceleration = Rnd(0.001,0.002)
 c\maxspeed = 1
End Function

Function DrawCar()
 For c.car = Each car
  Color 128,0,0:Oval c\x-5, c\y-5, 10, 10
  If Debug Then Text c\x, c\y, Int(c\s*100) + "km/h"
 Next
 c.car = First car
  Color 0,128,0:Oval c\x-5, c\y-5, 10, 10
End Function

Function UpdateCar()
 CountCar = 0

 For c.car = Each car
  CountCar = CountCar + 1

  c\id = CountCar
  c\w = c\w + c\s

  If c\s > maxspeed Then maxspeed = c\s
  If c\s < minspeed Then minspeed = c\s

  c\s = c\s + c\acceleration

  If c\s > c\maxspeed Then c\s = c\maxspeed
  If c\s < 0 Then c\s = c\s *-1
 
  If c\w > 360 Then c\w = c\w - 360
  c\x = ResX / 2 + Cos(c\w) * 293
  c\y = ResY / 2 + Sin(c\w) * 293
 
  For cc.car = Each car
   If cc <> c

    If Abs(c\w - cc\w) =< 21 Then ; Softbreak
     If cc\s > c\s And c\w > cc\w Then 
      cc\s = cc\s -.035
     EndIf
    EndIf

    If Abs(c\w - cc\w) =< 5 Then ; Notbremse
     If cc\w =< c\w Then 
      cc\s = c\s: cc\w = c\w-5
     EndIf
    EndIf

   EndIf
  Next

 Next

End Function