ReadFile

Function getPNGLastModified$(file$)
  If FileType(file) <> 1 Then RuntimeError file+" is not a file"
  Local stream = ReadFile(file)
  SeekFile stream, 8  ;skip Signature (hope the file to be PNG)
  While Not Eof(stream)
    Local chunkLength = getInt(stream)
    Local chunkName$ = Chr(ReadByte(stream))+Chr(ReadByte(stream))+Chr(ReadByte(stream))+Chr(ReadByte(stream))
    ;natürlich auf einer Zeile
    If Lower(chunkName) = "time" Then   ;chunk found! parse it
      Local year    = getShort(stream)
      Local month   = ReadByte(stream)
      Local day     = ReadByte(stream)
      Local hour    = ReadByte(stream)
      Local minute  = ReadByte(stream)
      Local secound = ReadByte(stream)
      Return day+"."+month+"."+year+" "+hour+":"+minute
    EndIf
    For i=1 To chunkLength;skip chunk
      ReadByte stream
    Next
    ReadInt stream  ;skip CRC (hope that everything is OK)
  Wend
  Return ""
End Function

Function getInt(stream)   ;Blitz' Ints are else then PNG's
  Return ReadByte(stream)*2^24+ReadByte(stream)*2^16+ReadByte(stream)*2^8+ReadByte(stream)
End Function

Function getShort(stream)   ;Shorts also
  Return ReadByte(stream)*2^8+ReadByte(stream)
End Function



; and a test
Local time$ = getPNGLastModified("test.png")

Print time

Local timer = CreateTimer(1)

For i=1 To 3 ;wait 3 secounds
  WaitTimer timer
Next

End