Const toleranz=20;toleranzbereich der farben - er ist etwa zwischen 15 und 30
Global font=LoadAnimImage("font.bmp",8,13,0,10);hier habe ich den gelben font ohne antialistöne gespeichert
MaskImage font, 255,0,255
Global dat=LoadImage("data.bmp");unbedingt bmp nehmen, mit jpg gehts fast gar nicht
Dim img(8,13);hier lese ich das zu behandelnde zeichen später ein

txt$="Stärke: "

For x=104 To 170 Step 10;hier stehen die stärkepunkte. der step ist bei dem gelben font immer 10.
	character=GetChar(x,5)
	If character<>-1 txt=txt+character;-1 wird zurückgegeben, wenn er nichts findet. ansonsten addiern
						 ;wir den wert schön immer an die nächste stelle.
Next

txt=txt+", Verteidigung: "

For x=361 To 400 Step 10;verteidigung
	character=GetChar(x,5)
	If character<>-1 txt=txt+character
Next

Print txt
WaitKey
End






Function GetChar(x,y)

ziffer=CreateImage(8,13)
CopyRect x,y,8,13,0,0,ImageBuffer(dat),ImageBuffer(ziffer);zeichen in bild ziffer extrahieren

sicher=CopyImage(ziffer);kopieren, damit ich immer wieder auf das ursprungsbild zurück komme

SetBuffer ImageBuffer(ziffer)
LockBuffer ImageBuffer(ziffer)

For y=0 To 13
	For x=0 To 8
		img(x,y)=ReadPixelFast(x,y);die ziffer ins dim-feld einlesen
	Next
Next

SetBuffer ImageBuffer(ziffer)

For frame=0 To 9;brute force ^^ (wir nehmen einfach jedes zeichen und fummeln es drauf)
	DrawImage sicher,0,0;auf das ursprungsbild zurücksetzen
	
	UnlockBuffer ImageBuffer(ziffer)
	DrawImage font,0,0,frame;wir fummeln das zeichen drauf
	
	
	
	For y=0 To 13;wir gehen das gesamte bild durch, wenns nötig ist
		For x=0 To 8
			save=img(x,y);rgb-wert des eingelesenen bildes
			reed=ReadPixelFast(x,y,ImageBuffer(ziffer));read ist ein befehl, also heists jetzt reed... wir lesen das bild mit
														;draufgefummelten buchstaben ein
			
			r1=(reed And $FF0000)/$10000;farbanteile des neuen bilds berechnen
			g1=(reed And $FF00)/$100
			b1=reed And $FF
			
			r2=(save And $FF0000)/$10000;farbanteile des ursprungsbildes berechnen
			g2=(save And $FF00)/$100
			b2=save And $FF
			
			rgb1=r1+g1+b1;wir addieren die rgb-werte. damit ist der toleranzbereich viel einfacher zu realisieren.
						 ;der toleranzbereich ist für alle drei farben auf einmal definiert, insgesamt dürfen die farben um
						 ;die konstante toleranz (oben) abweichen.
			rgb2=r2+g2+b2
			If rgb2-rgb1<>0;wenn sich die farbwerte des ursprünglichen und des neuen bildes unterscheiden
				If (rgb2-rgb1>toleranz And rgb2-rgb1>0) Or (rgb1-rgb2>toleranz And rgb1-rgb2>0);und der unterschied außerhalb des
																								;toleranzbereiches liegt,
					nicht=1;dann ist es nicht die ziffer, die wir ausprobiert haben.
					Exit;wir verlassen also die x-schleife
				EndIf
			EndIf
		
		Next
		If nicht=1 Then Exit;wenn es nicht übereinstimmt gehen wir auch aus der y-schleife
	Next
	If nicht=0;wenn es nicht nicht richtig war (-> es hat übereingestimmt), so ist unser ergebnis diesderzeitige
				;framenummer
		Exit;verlassen wir also die brute-force-schleife
	EndIf

	If nicht=1 Then nicht=0;wenn wirs nicht gefunden haben, wird der wert wieder resettet und die brute-force-schleife
							;macht weiter
	
Next
If frame=10 Then frame=-1;frame 10 kommt raus, wenn es keine übereinstimmung gab. setzen wir der übersichtlichkeit
						 ;halber -1...
Return frame
End Function