Function CreateBuild(menuID, x#, y#, z#)

   For m.TMenu = Each TMenu

      If (menuID = m\id) Then
      
         b.TBuild = New TBuild
            b\id = CountBuilds()
            b\name$ = m\name$
            
            b\obj = CopyEntity(m\obj)
               EntityColor b\obj, 192, 192, 192
               
            b\px# = x#
            b\py# = y#
            b\pz# = z#
            PositionEntity b\obj, b\px#, b\py#, b\pz#
            
            b\sell = (m\cost * .5)
            
            b\off = m\off
            b\def = m\def
            b\out = m\out
            b\time = m\time
            b\diff = MilliSecs()
            
            b\nrg_in = m\nrg_in
            b\nrg_out = m\nrg_out
      EndIf
   Next
End Function

Function BuildUnit(id%, oil)

   Local match$
   Local res%

   b.TBuild = Object.TBuild(id%)
   
   Local px# = b\px
   Local py# = b\py
   Local pz# = b\pz

   Select b\name
      Case "garage"
         match$ = "car"
      Case "armory"
         match$ = "tank"
      Case "airfield"
         match$ = "air"
   End Select
   
   For p.TPreview = Each TPreview
      If (p\typ = match$) And (oil >= p\oil) Then
         u.TUnit = New TUnit
            u\id = CountUnits()
            u\parent = b\parent
            u\name = p\name
            u\typ = p\typ
            u\obj = CopyEntity(p\obj)
               EntityType u\obj, COLL_SPH
            u\px# = px
            u\py# = py
            u\pz# = pz
               PositionEntity u\obj, u\px, u\py, u\pz
            u\rx# = 0 : u\ry# = 0 : u\rz# = 0
            u\off = p\off
            u\def = p\def
            u\speed# = p\speed#
            u\range = p\range
            For i = 0 To 3
               u\child[i] = p\child[i]
               u\child_rot[i] = p\child_rot[i]
            Next
            
            res = p\oil
      EndIf
   Next
   
   Return res
         
End Function

Function UpdateUnits(pivot, d3dFont, d3dSX, d3dSY)
   
   Local yaw#
   Local dist#
   
   For u.TUnit = Each TUnit
      If u\target = 0 Then
         yaw# = DeltaYaw(u\obj, pivot)
         dist# = EntityDistance(u\obj, pivot)
         If dist# > 2 Then
            Text3D(d3dFont, d3dSX+10, d3dSY-(150+index*20), "Y:"+yaw#+"|D:"+dist#)
            If yaw# <> 0 Then
               If Abs(yaw#) < 1 Then
                  yaw# = 0
                  MoveEntity u\obj, 0, 0, u\speed#
               EndIf
               
               If (yaw < 0) Then
                  TurnEntity u\obj, 0, -1, 0
               ElseIf (yaw > 0) Then
                  TurnEntity u\obj, 0, +1, 0
               EndIf
            EndIf
         EndIf
      EndIf
      index = index + 1
   Next
End Function

Type TUnit
   Field id%
   Field parent%
   Field name$
   Field typ$
   Field obj%
   Field child%[3]
   Field child_rot$[3]
   Field px#, py#, pz#, rx#, ry#, rz#
   Field def%
   Field off%
   Field speed#
   Field range%
   Field target%
End Type

Type TBuild
   Field id%
   Field name$
   Field parent%
   Field obj%
   Field sell%
   Field px#, py#, pz#
   Field off%, def%
   Field out%, time%, diff%
   Field nrg_in%, nrg_out%
End Type